pcerraxpy()

subroutine pcerraxpy	(	real	errbnd,
		complex	psclr,
		complex	x,
		complex	y,
		real	prec
	)

Definition at line 3777 of file pcblas1tst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      REAL               ERRBND, PREC
      COMPLEX            PSCLR, X, Y
*     ..
*
*  Purpose
*  =======
*
*  PCERRAXPY  serially computes Y := Y + PSCLR * X and returns a scaled
*  relative acceptable error bound on the result.
*
*  Arguments
*  =========
*
*  ERRBND  (global output) REAL
*          On exit, ERRBND  specifies the scaled relative acceptable er-
*          ror bound.
*
*  PSCLR   (global input) COMPLEX
*          On entry, PSCLR specifies the scale factor.
*
*  X       (global input) COMPLEX
*          On entry, X  specifies the scalar to be scaled.
*
*  Y       (global input/global output) COMPLEX
*          On entry, Y specifies the scalar to be added. On exit, Y con-
*          tains the resulting scalar.
*
*  PREC    (global input) REAL
*          On entry, PREC specifies the machine precision.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, TWO, ZERO
      parameter( one = 1.0e+0, two = 2.0e+0,
     $                   zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      REAL               ADDBND, FACT, SUMINEG, SUMIPOS, SUMRNEG,
     $                   SUMRPOS
      COMPLEX            TMP
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          aimag, max, real
*     ..
*     .. Executable Statements ..
*
      sumipos = zero
      sumineg = zero
      sumrpos = zero
      sumrneg = zero
      fact = one + two * prec
      addbnd = two * two * two * prec
*
      tmp = psclr * x
      IF( real( tmp ).GE.zero ) THEN
         sumrpos = sumrpos + real( tmp ) * fact
      ELSE
         sumrneg = sumrneg - real( tmp ) * fact
      END IF
      IF( aimag( tmp ).GE.zero ) THEN
         sumipos = sumipos + aimag( tmp ) * fact
      ELSE
         sumineg = sumineg - aimag( tmp ) * fact
      END IF
*
      tmp = y
      IF( real( tmp ).GE.zero ) THEN
         sumrpos = sumrpos + real( tmp )
      ELSE
         sumrneg = sumrneg - real( tmp )
      END IF
      IF( aimag( tmp ).GE.zero ) THEN
         sumipos = sumipos + aimag( tmp )
      ELSE
         sumineg = sumineg - aimag( tmp )
      END IF
*
      y = y + ( psclr * x )
*
      errbnd = addbnd * max( max( sumrpos, sumrneg ),
     $                       max( sumipos, sumineg ) )
*
      RETURN
*
*     End of PCERRAXPY
*

Here is the caller graph for this function: