pcerrdotu()

subroutine pcerrdotu	(	real	errbnd,
		integer	n,
		complex	sclr,
		complex, dimension( * )	x,
		integer	incx,
		complex, dimension( * )	y,
		integer	incy,
		real	prec
	)

Definition at line 3137 of file pcblas1tst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            INCX, INCY, N
      REAL               ERRBND, PREC
      COMPLEX            SCLR
*     ..
*     .. Array Arguments ..
      COMPLEX            X( * ), Y( * )
*     ..
*
*  Purpose
*  =======
*
*  PCERRDOTU serially  computes  the  dot product X**T * Y and returns a
*  scaled relative acceptable error bound on the result.
*
*  Notes
*  =====
*
*  If dot1 = SCLR and  dot2 are two different computed results, and dot1
*  is being assumed to be correct, we require
*
*     abs( dot1 - dot2 ) <= ERRBND = ERRFACT * abs( dot1 ),
*
*  where ERRFACT is computed as the maximum of the positive and negative
*  partial  sums  multiplied  by  a constant proportional to the machine
*  precision.
*
*  Arguments
*  =========
*
*  ERRBND  (global output) REAL
*          On exit, ERRBND  specifies the scaled relative acceptable er-
*          ror bound.
*
*  N       (global input) INTEGER
*          On entry, N specifies the length of the vector operands.
*
*  SCLR    (global output) COMPLEX
*          On exit,  SCLR  specifies  the dot product of the two vectors
*          X and Y.
*
*  X       (global input) COMPLEX array
*          On   entry,   X   is   an   array   of   dimension  at  least
*          ( 1 + ( n - 1 )*abs( INCX ) ).  Before  entry,  the incremen-
*          ted array X must contain the vector x.
*
*  INCX    (global input) INTEGER.
*          On entry, INCX specifies the increment for the elements of X.
*          INCX must not be zero.
*
*  Y       (global input) COMPLEX array
*          On   entry,   Y   is   an   array   of   dimension  at  least
*          ( 1 + ( n - 1 )*abs( INCY ) ).  Before  entry,  the incremen-
*          ted array Y must contain the vector y.
*
*  INCY    (global input) INTEGER.
*          On entry, INCY specifies the increment for the elements of Y.
*          INCY must not be zero.
*
*  PREC    (global input) REAL
*          On entry, PREC specifies the machine precision.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, TWO, ZERO
      parameter( one = 1.0e+0, two = 2.0e+0,
     $                   zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IX, IY
      REAL               ADDBND, FACT, SUMINEG, SUMIPOS, SUMRNEG,
     $                   SUMRPOS, TMP
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, real
*     ..
*     .. Executable Statements ..
*
      ix = 1
      iy = 1
      sclr = zero
      sumipos = zero
      sumineg = zero
      sumrpos = zero
      sumrneg = zero
      fact = two * ( one + prec )
      addbnd = two * two * two * prec
*
      DO 10 i = 1, n
*
         sclr = sclr + x( ix ) * y( iy )
*
         tmp = real( x( ix ) ) * real( y( iy ) )
         IF( tmp.GE.zero ) THEN
            sumrpos = sumrpos + tmp * fact
         ELSE
            sumrneg = sumrneg - tmp * fact
         END IF
*
         tmp = - aimag( x( ix ) ) * aimag( y( iy ) )
         IF( tmp.GE.zero ) THEN
            sumrpos = sumrpos + tmp * fact
         ELSE
            sumrneg = sumrneg - tmp * fact
         END IF
*
         tmp = aimag( x( ix ) ) * real( y( iy ) )
         IF( tmp.GE.zero ) THEN
            sumipos = sumipos + tmp * fact
         ELSE
            sumineg = sumineg - tmp * fact
         END IF
*
         tmp = real( x( ix ) ) * aimag( y( iy ) )
         IF( tmp.GE.zero ) THEN
            sumipos = sumipos + tmp * fact
         ELSE
            sumineg = sumineg - tmp * fact
         END IF
*
         ix = ix + incx
         iy = iy + incy
*
   10 CONTINUE
*
      errbnd = addbnd * max( max( sumrpos, sumrneg ),
     $                       max( sumipos, sumineg ) )
*
      RETURN
*
*     End of PCERRDOTU
*

Here is the caller graph for this function: