pzerrdotc()

subroutine pzerrdotc	(	double precision	errbnd,
		integer	n,
		complex*16	sclr,
		complex*16, dimension( * )	x,
		integer	incx,
		complex*16, dimension( * )	y,
		integer	incy,
		double precision	prec
	)

Definition at line 3280 of file pzblas1tst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            INCX, INCY, N
      DOUBLE PRECISION   ERRBND, PREC
      COMPLEX*16         SCLR
*     ..
*     .. Array Arguments ..
      COMPLEX*16         X( * ), Y( * )
*     ..
*
*  Purpose
*  =======
*
*  PZERRDOTC serially  computes  the  dot product X**H * Y and returns a
*  scaled relative acceptable error bound on the result.
*
*  Notes
*  =====
*
*  If dot1 = SCLR and  dot2 are two different computed results, and dot1
*  is being assumed to be correct, we require
*
*     abs( dot1 - dot2 ) <= ERRBND = ERRFACT * abs( dot1 ),
*
*  where ERRFACT is computed as the maximum of the positive and negative
*  partial  sums  multiplied  by  a constant proportional to the machine
*  precision.
*
*  Arguments
*  =========
*
*  ERRBND  (global output) DOUBLE PRECISION
*          On exit, ERRBND  specifies the scaled relative acceptable er-
*          ror bound.
*
*  N       (global input) INTEGER
*          On entry, N specifies the length of the vector operands.
*
*  SCLR    (global output) COMPLEX*16
*          On exit,  SCLR  specifies  the dot product of the two vectors
*          X and Y.
*
*  X       (global input) COMPLEX*16 array
*          On   entry,   X   is   an   array   of   dimension  at  least
*          ( 1 + ( n - 1 )*abs( INCX ) ).  Before  entry,  the incremen-
*          ted array X must contain the vector x.
*
*  INCX    (global input) INTEGER.
*          On entry, INCX specifies the increment for the elements of X.
*          INCX must not be zero.
*
*  Y       (global input) COMPLEX*16 array
*          On   entry,   Y   is   an   array   of   dimension  at  least
*          ( 1 + ( n - 1 )*abs( INCY ) ).  Before  entry,  the incremen-
*          ted array Y must contain the vector y.
*
*  INCY    (global input) INTEGER.
*          On entry, INCY specifies the increment for the elements of Y.
*          INCY must not be zero.
*
*  PREC    (global input) DOUBLE PRECISION
*          On entry, PREC specifies the machine precision.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, TWO, ZERO
      parameter( one = 1.0d+0, two = 2.0d+0,
     $                   zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IX, IY
      DOUBLE PRECISION   ADDBND, FACT, SUMINEG, SUMIPOS, SUMRNEG,
     $                   SUMRPOS, TMP
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dconjg, dimag, max
*     ..
*     .. Executable Statements ..
*
      ix = 1
      iy = 1
      sclr = zero
      sumipos = zero
      sumineg = zero
      sumrpos = zero
      sumrneg = zero
      fact = two * ( one + prec )
      addbnd = two * two * two * prec
*
      DO 10 i = 1, n
*
         sclr = sclr + dconjg( x( ix ) ) * y( iy )
*
         tmp = dble( x( ix ) ) * dble( y( iy ) )
         IF( tmp.GE.zero ) THEN
            sumrpos = sumrpos + tmp * fact
         ELSE
            sumrneg = sumrneg - tmp * fact
         END IF
*
         tmp = dimag( x( ix ) ) * dimag( y( iy ) )
         IF( tmp.GE.zero ) THEN
            sumrpos = sumrpos + tmp * fact
         ELSE
            sumrneg = sumrneg - tmp * fact
         END IF
*
         tmp = - dimag( x( ix ) ) * dble( y( iy ) )
         IF( tmp.GE.zero ) THEN
            sumipos = sumipos + tmp * fact
         ELSE
            sumineg = sumineg - tmp * fact
         END IF
*
         tmp = dble( x( ix ) ) * dimag( y( iy ) )
         IF( tmp.GE.zero ) THEN
            sumipos = sumipos + tmp * fact
         ELSE
            sumineg = sumineg - tmp * fact
         END IF
*
         ix = ix + incx
         iy = iy + incy
*
   10 CONTINUE
*
      errbnd = addbnd * max( max( sumrpos, sumrneg ),
     $                       max( sumipos, sumineg ) )
*
      RETURN
*
*     End of PZERRDOTC
*

Here is the caller graph for this function: