pzerraxpy()

subroutine pzerraxpy	(	double precision	errbnd,
		complex*16	psclr,
		complex*16	x,
		complex*16	y,
		double precision	prec
	)

Definition at line 3776 of file pzblas1tst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION   ERRBND, PREC
      COMPLEX*16         PSCLR, X, Y
*     ..
*
*  Purpose
*  =======
*
*  PZERRAXPY  serially computes Y := Y + PSCLR * X and returns a scaled
*  relative acceptable error bound on the result.
*
*  Arguments
*  =========
*
*  ERRBND  (global output) DOUBLE PRECISION
*          On exit, ERRBND  specifies the scaled relative acceptable er-
*          ror bound.
*
*  PSCLR   (global input) COMPLEX*16
*          On entry, PSCLR specifies the scale factor.
*
*  X       (global input) COMPLEX*16
*          On entry, X  specifies the scalar to be scaled.
*
*  Y       (global input/global output) COMPLEX*16
*          On entry, Y specifies the scalar to be added. On exit, Y con-
*          tains the resulting scalar.
*
*  PREC    (global input) DOUBLE PRECISION
*          On entry, PREC specifies the machine precision.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, TWO, ZERO
      parameter( one = 1.0d+0, two = 2.0d+0,
     $                   zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   ADDBND, FACT, SUMINEG, SUMIPOS, SUMRNEG,
     $                   SUMRPOS
      COMPLEX*16         TMP
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dimag, max
*     ..
*     .. Executable Statements ..
*
      sumipos = zero
      sumineg = zero
      sumrpos = zero
      sumrneg = zero
      fact = one + two * prec
      addbnd = two * two * two * prec
*
      tmp = psclr * x
      IF( dble( tmp ).GE.zero ) THEN
         sumrpos = sumrpos + dble( tmp ) * fact
      ELSE
         sumrneg = sumrneg - dble( tmp ) * fact
      END IF
      IF( dimag( tmp ).GE.zero ) THEN
         sumipos = sumipos + dimag( tmp ) * fact
      ELSE
         sumineg = sumineg - dimag( tmp ) * fact
      END IF
*
      tmp = y
      IF( dble( tmp ).GE.zero ) THEN
         sumrpos = sumrpos + dble( tmp )
      ELSE
         sumrneg = sumrneg - dble( tmp )
      END IF
      IF( dimag( tmp ).GE.zero ) THEN
         sumipos = sumipos + dimag( tmp )
      ELSE
         sumineg = sumineg - dimag( tmp )
      END IF
*
      y = y + ( psclr * x )
*
      errbnd = addbnd * max( max( sumrpos, sumrneg ),
     $                       max( sumipos, sumineg ) )
*
      RETURN
*
*     End of PZERRAXPY
*

Here is the caller graph for this function: