pb_locinfo()

subroutine pb_locinfo	(	integer	i,
		integer	inb,
		integer	nb,
		integer	myroc,
		integer	srcproc,
		integer	nprocs,
		integer	ilocblk,
		integer	ilocoff,
		integer	mydist
	)

Definition at line 4503 of file pblastim.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            I, ILOCBLK, ILOCOFF, INB, MYDIST, MYROC, NB,
     $                   NPROCS, SRCPROC
*     ..
*
*  Purpose
*  =======
*
*  PB_LOCINFO  computes  local information about the beginning of a sub-
*  matrix starting at the global index I.
*
*  Arguments
*  =========
*
*  I       (global input) INTEGER
*          On entry,  I  specifies  the global starting index in the ma-
*          trix. I must be at least one.
*
*  INB     (global input) INTEGER
*          On entry,  INB  specifies the size of the first block of rows
*          or columns of the matrix. INB must be at least one.
*
*  NB      (global input) INTEGER
*          On entry, NB  specifies the size of the blocks of rows or co-
*          lumns of the matrix is partitioned into.  NB must be at least
*          one.
*
*  MYROC   (local input) INTEGER
*          On entry, MYROC is the  coordinate of the process whose local
*          information  is  determined.  MYROC  is  at  least  zero  and
*          strictly less than NPROCS.
*
*  SRCPROC (global input) INTEGER
*          On entry,  SRCPROC  specifies  the coordinate of the  process
*          that possesses the  first row or column  of the matrix.  When
*          SRCPROC = -1, the data  is not  distributed  but  replicated,
*          otherwise  SRCPROC  must be at least zero and  strictly  less
*          than NPROCS.
*
*  NPROCS  (global input) INTEGER
*          On entry, NPROCS  specifies  the total number of process rows
*          or  columns  over  which the submatrix is distributed. NPROCS
*          must be at least one.
*
*  ILOCBLK (local output) INTEGER
*          On exit, ILOCBLK  specifies  the  local  row  or column block
*          coordinate  corresponding  to  the row or column I of the ma-
*          trix. ILOCBLK must be at least zero.
*
*  ILOCOFF (local output) INTEGER
*          On exit, ILOCOFF  specifies the local row offset in the block
*          of local coordinate  ILOCBLK  corresponding to the row or co-
*          lumn I of the matrix. ILOCOFF must at least zero.
*
*  MYDIST  (local output) INTEGER
*          On exit, MYDIST  specifies the relative process coordinate of
*          the process specified by MYROC to the process owning the  row
*          or column I. MYDIST  is at  least zero and strictly less than
*          NPROCS.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            ITMP, NBLOCKS, PROC
*     ..
*     .. Executable Statements ..
*
      ilocoff = 0
*
      IF( srcproc.LT.0 ) THEN
*
         mydist = 0
*
         IF( i.LE.inb ) THEN
*
            ilocblk = 0
            ilocoff = i - 1
*
         ELSE
*
            itmp    = i - inb
            nblocks = ( itmp - 1 ) / nb + 1
            ilocblk = nblocks
            ilocoff = itmp - 1 - ( nblocks - 1 ) * nb
*
         END IF
*
      ELSE
*
         proc   = srcproc
         mydist = myroc - proc
         IF( mydist.LT.0 )
     $      mydist = mydist + nprocs
*
         IF( i.LE.inb ) THEN
*
            ilocblk = 0
            IF( myroc.EQ.proc )
     $         ilocoff = i - 1
*
         ELSE
*
            itmp    = i - inb
            nblocks = ( itmp - 1 ) / nb + 1
            proc    = proc + nblocks
            proc    = proc - ( proc / nprocs ) * nprocs
            ilocblk = nblocks / nprocs
*
            IF( ( ilocblk*nprocs ).LT.( mydist-nblocks ) )
     $         ilocblk = ilocblk + 1
*
            IF( myroc.EQ.proc )
     $         ilocoff = itmp - 1 - ( nblocks - 1 ) * nb
*
         END IF
*
      END IF
*
      RETURN
*
*     End of PB_LOCINFO
*