zgeesx()

subroutine zgeesx	(	character	jobvs,
		character	sort,
		external	select,
		character	sense,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		integer	sdim,
		complex*16, dimension( * )	w,
		complex*16, dimension( ldvs, * )	vs,
		integer	ldvs,
		double precision	rconde,
		double precision	rcondv,
		complex*16, dimension( * )	work,
		integer	lwork,
		double precision, dimension( * )	rwork,
		logical, dimension( * )	bwork,
		integer	info )

ZGEESX computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE matrices

Download ZGEESX + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZGEESX computes for an N-by-N complex nonsymmetric matrix A, the
!> eigenvalues, the Schur form T, and, optionally, the matrix of Schur
!> vectors Z.  This gives the Schur factorization A = Z*T*(Z**H).
!>
!> Optionally, it also orders the eigenvalues on the diagonal of the
!> Schur form so that selected eigenvalues are at the top left;
!> computes a reciprocal condition number for the average of the
!> selected eigenvalues (RCONDE); and computes a reciprocal condition
!> number for the right invariant subspace corresponding to the
!> selected eigenvalues (RCONDV).  The leading columns of Z form an
!> orthonormal basis for this invariant subspace.
!>
!> For further explanation of the reciprocal condition numbers RCONDE
!> and RCONDV, see Section 4.10 of the LAPACK Users' Guide (where
!> these quantities are called s and sep respectively).
!>
!> A complex matrix is in Schur form if it is upper triangular.
!> 

Parameters

[in]	JOBVS	!> JOBVS is CHARACTER*1 !> = 'N': Schur vectors are not computed; !> = 'V': Schur vectors are computed. !>
[in]	SORT	!> SORT is CHARACTER*1 !> Specifies whether or not to order the eigenvalues on the !> diagonal of the Schur form. !> = 'N': Eigenvalues are not ordered; !> = 'S': Eigenvalues are ordered (see SELECT). !>
[in]	SELECT	!> SELECT is a LOGICAL FUNCTION of one COMPLEX*16 argument !> SELECT must be declared EXTERNAL in the calling subroutine. !> If SORT = 'S', SELECT is used to select eigenvalues to order !> to the top left of the Schur form. !> If SORT = 'N', SELECT is not referenced. !> An eigenvalue W(j) is selected if SELECT(W(j)) is true. !>
[in]	SENSE	!> SENSE is CHARACTER*1 !> Determines which reciprocal condition numbers are computed. !> = 'N': None are computed; !> = 'E': Computed for average of selected eigenvalues only; !> = 'V': Computed for selected right invariant subspace only; !> = 'B': Computed for both. !> If SENSE = 'E', 'V' or 'B', SORT must equal 'S'. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA, N) !> On entry, the N-by-N matrix A. !> On exit, A is overwritten by its Schur form T. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	SDIM	!> SDIM is INTEGER !> If SORT = 'N', SDIM = 0. !> If SORT = 'S', SDIM = number of eigenvalues for which !> SELECT is true. !>
[out]	W	!> W is COMPLEX*16 array, dimension (N) !> W contains the computed eigenvalues, in the same order !> that they appear on the diagonal of the output Schur form T. !>
[out]	VS	!> VS is COMPLEX*16 array, dimension (LDVS,N) !> If JOBVS = 'V', VS contains the unitary matrix Z of Schur !> vectors. !> If JOBVS = 'N', VS is not referenced. !>
[in]	LDVS	!> LDVS is INTEGER !> The leading dimension of the array VS. LDVS >= 1, and if !> JOBVS = 'V', LDVS >= N. !>
[out]	RCONDE	!> RCONDE is DOUBLE PRECISION !> If SENSE = 'E' or 'B', RCONDE contains the reciprocal !> condition number for the average of the selected eigenvalues. !> Not referenced if SENSE = 'N' or 'V'. !>
[out]	RCONDV	!> RCONDV is DOUBLE PRECISION !> If SENSE = 'V' or 'B', RCONDV contains the reciprocal !> condition number for the selected right invariant subspace. !> Not referenced if SENSE = 'N' or 'E'. !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= max(1,2*N). !> Also, if SENSE = 'E' or 'V' or 'B', LWORK >= 2*SDIM*(N-SDIM), !> where SDIM is the number of selected eigenvalues computed by !> this routine. Note that 2*SDIM*(N-SDIM) <= N*N/2. Note also !> that an error is only returned if LWORK < max(1,2*N), but if !> SENSE = 'E' or 'V' or 'B' this may not be large enough. !> For good performance, LWORK must generally be larger. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates upper bound on the optimal size of the !> array WORK, returns this value as the first entry of the WORK !> array, and no error message related to LWORK is issued by !> XERBLA. !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[out]	BWORK	!> BWORK is LOGICAL array, dimension (N) !> Not referenced if SORT = 'N'. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: if INFO = i, and i is !> <= N: the QR algorithm failed to compute all the !> eigenvalues; elements 1:ILO-1 and i+1:N of W !> contain those eigenvalues which have converged; if !> JOBVS = 'V', VS contains the transformation which !> reduces A to its partially converged Schur form. !> = N+1: the eigenvalues could not be reordered because some !> eigenvalues were too close to separate (the problem !> is very ill-conditioned); !> = N+2: after reordering, roundoff changed values of some !> complex eigenvalues so that leading eigenvalues in !> the Schur form no longer satisfy SELECT=.TRUE. This !> could also be caused by underflow due to scaling. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 234 of file zgeesx.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBVS, SENSE, SORT
      INTEGER            INFO, LDA, LDVS, LWORK, N, SDIM
      DOUBLE PRECISION   RCONDE, RCONDV
*     ..
*     .. Array Arguments ..
      LOGICAL            BWORK( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( LDA, * ), VS( LDVS, * ), W( * ), WORK( * )
*     ..
*     .. Function Arguments ..
      LOGICAL            SELECT
      EXTERNAL           SELECT
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, SCALEA, WANTSB, WANTSE, WANTSN, WANTST,
     $                   WANTSV, WANTVS
      INTEGER            HSWORK, I, IBAL, ICOND, IERR, IEVAL, IHI, ILO,
     $                   ITAU, IWRK, LWRK, MAXWRK, MINWRK
      DOUBLE PRECISION   ANRM, BIGNUM, CSCALE, EPS, SMLNUM
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   DUM( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlascl, xerbla, zcopy, zgebak, zgebal,
     $                   zgehrd,
     $                   zhseqr, zlacpy, zlascl, ztrsen, zunghr
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      DOUBLE PRECISION   DLAMCH, ZLANGE
      EXTERNAL           lsame, ilaenv, dlamch, zlange
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      wantvs = lsame( jobvs, 'V' )
      wantst = lsame( sort, 'S' )
      wantsn = lsame( sense, 'N' )
      wantse = lsame( sense, 'E' )
      wantsv = lsame( sense, 'V' )
      wantsb = lsame( sense, 'B' )
      lquery = ( lwork.EQ.-1 )
*
      IF( ( .NOT.wantvs ) .AND. ( .NOT.lsame( jobvs, 'N' ) ) ) THEN
         info = -1
      ELSE IF( ( .NOT.wantst ) .AND.
     $         ( .NOT.lsame( sort, 'N' ) ) ) THEN
         info = -2
      ELSE IF( .NOT.( wantsn .OR. wantse .OR. wantsv .OR. wantsb ) .OR.
     $         ( .NOT.wantst .AND. .NOT.wantsn ) ) THEN
         info = -4
      ELSE IF( n.LT.0 ) THEN
         info = -5
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -7
      ELSE IF( ldvs.LT.1 .OR. ( wantvs .AND. ldvs.LT.n ) ) THEN
         info = -11
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of real workspace needed at that point in the
*       code, as well as the preferred amount for good performance.
*       CWorkspace refers to complex workspace, and RWorkspace to real
*       workspace. NB refers to the optimal block size for the
*       immediately following subroutine, as returned by ILAENV.
*       HSWORK refers to the workspace preferred by ZHSEQR, as
*       calculated below. HSWORK is computed assuming ILO=1 and IHI=N,
*       the worst case.
*       If SENSE = 'E', 'V' or 'B', then the amount of workspace needed
*       depends on SDIM, which is computed by the routine ZTRSEN later
*       in the code.)
*
      IF( info.EQ.0 ) THEN
         IF( n.EQ.0 ) THEN
            minwrk = 1
            lwrk = 1
         ELSE
            maxwrk = n + n*ilaenv( 1, 'ZGEHRD', ' ', n, 1, n, 0 )
            minwrk = 2*n
*
            CALL zhseqr( 'S', jobvs, n, 1, n, a, lda, w, vs, ldvs,
     $             work, -1, ieval )
            hswork = int( work( 1 ) )
*
            IF( .NOT.wantvs ) THEN
               maxwrk = max( maxwrk, hswork )
            ELSE
               maxwrk = max( maxwrk, n + ( n - 1 )*ilaenv( 1,
     $                       'ZUNGHR',
     $                       ' ', n, 1, n, -1 ) )
               maxwrk = max( maxwrk, hswork )
            END IF
            lwrk = maxwrk
            IF( .NOT.wantsn )
     $         lwrk = max( lwrk, ( n*n )/2 )
         END IF
         work( 1 ) = lwrk
*
         IF( lwork.LT.minwrk .AND. .NOT.lquery ) THEN
            info = -15
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGEESX', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         sdim = 0
         RETURN
      END IF
*
*     Get machine constants
*
      eps = dlamch( 'P' )
      smlnum = dlamch( 'S' )
      bignum = one / smlnum
      smlnum = sqrt( smlnum ) / eps
      bignum = one / smlnum
*
*     Scale A if max element outside range [SMLNUM,BIGNUM]
*
      anrm = zlange( 'M', n, n, a, lda, dum )
      scalea = .false.
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
         scalea = .true.
         cscale = smlnum
      ELSE IF( anrm.GT.bignum ) THEN
         scalea = .true.
         cscale = bignum
      END IF
      IF( scalea )
     $   CALL zlascl( 'G', 0, 0, anrm, cscale, n, n, a, lda, ierr )
*
*
*     Permute the matrix to make it more nearly triangular
*     (CWorkspace: none)
*     (RWorkspace: need N)
*
      ibal = 1
      CALL zgebal( 'P', n, a, lda, ilo, ihi, rwork( ibal ), ierr )
*
*     Reduce to upper Hessenberg form
*     (CWorkspace: need 2*N, prefer N+N*NB)
*     (RWorkspace: none)
*
      itau = 1
      iwrk = n + itau
      CALL zgehrd( n, ilo, ihi, a, lda, work( itau ), work( iwrk ),
     $             lwork-iwrk+1, ierr )
*
      IF( wantvs ) THEN
*
*        Copy Householder vectors to VS
*
         CALL zlacpy( 'L', n, n, a, lda, vs, ldvs )
*
*        Generate unitary matrix in VS
*        (CWorkspace: need 2*N-1, prefer N+(N-1)*NB)
*        (RWorkspace: none)
*
         CALL zunghr( n, ilo, ihi, vs, ldvs, work( itau ),
     $                work( iwrk ),
     $                lwork-iwrk+1, ierr )
      END IF
*
      sdim = 0
*
*     Perform QR iteration, accumulating Schur vectors in VS if desired
*     (CWorkspace: need 1, prefer HSWORK (see comments) )
*     (RWorkspace: none)
*
      iwrk = itau
      CALL zhseqr( 'S', jobvs, n, ilo, ihi, a, lda, w, vs, ldvs,
     $             work( iwrk ), lwork-iwrk+1, ieval )
      IF( ieval.GT.0 )
     $   info = ieval
*
*     Sort eigenvalues if desired
*
      IF( wantst .AND. info.EQ.0 ) THEN
         IF( scalea )
     $      CALL zlascl( 'G', 0, 0, cscale, anrm, n, 1, w, n, ierr )
         DO 10 i = 1, n
            bwork( i ) = SELECT( w( i ) )
   10    CONTINUE
*
*        Reorder eigenvalues, transform Schur vectors, and compute
*        reciprocal condition numbers
*        (CWorkspace: if SENSE is not 'N', need 2*SDIM*(N-SDIM)
*                     otherwise, need none )
*        (RWorkspace: none)
*
         CALL ztrsen( sense, jobvs, bwork, n, a, lda, vs, ldvs, w,
     $                sdim,
     $                rconde, rcondv, work( iwrk ), lwork-iwrk+1,
     $                icond )
         IF( .NOT.wantsn )
     $      maxwrk = max( maxwrk, 2*sdim*( n-sdim ) )
         IF( icond.EQ.-14 ) THEN
*
*           Not enough complex workspace
*
            info = -15
         END IF
      END IF
*
      IF( wantvs ) THEN
*
*        Undo balancing
*        (CWorkspace: none)
*        (RWorkspace: need N)
*
         CALL zgebak( 'P', 'R', n, ilo, ihi, rwork( ibal ), n, vs,
     $                ldvs,
     $                ierr )
      END IF
*
      IF( scalea ) THEN
*
*        Undo scaling for the Schur form of A
*
         CALL zlascl( 'U', 0, 0, cscale, anrm, n, n, a, lda, ierr )
         CALL zcopy( n, a, lda+1, w, 1 )
         IF( ( wantsv .OR. wantsb ) .AND. info.EQ.0 ) THEN
            dum( 1 ) = rcondv
            CALL dlascl( 'G', 0, 0, cscale, anrm, 1, 1, dum, 1,
     $                   ierr )
            rcondv = dum( 1 )
         END IF
      END IF
*
      work( 1 ) = maxwrk
      RETURN
*
*     End of ZGEESX
*

Here is the call graph for this function:

Here is the caller graph for this function: