LAPACK  3.8.0 LAPACK: Linear Algebra PACKage

## ◆ zlatrd()

 subroutine zlatrd ( character UPLO, integer N, integer NB, complex*16, dimension( lda, * ) A, integer LDA, double precision, dimension( * ) E, complex*16, dimension( * ) TAU, complex*16, dimension( ldw, * ) W, integer LDW )

ZLATRD reduces the first nb rows and columns of a symmetric/Hermitian matrix A to real tridiagonal form by an unitary similarity transformation.

Purpose:
``` ZLATRD reduces NB rows and columns of a complex Hermitian matrix A to
Hermitian tridiagonal form by a unitary similarity
transformation Q**H * A * Q, and returns the matrices V and W which are
needed to apply the transformation to the unreduced part of A.

If UPLO = 'U', ZLATRD reduces the last NB rows and columns of a
matrix, of which the upper triangle is supplied;
if UPLO = 'L', ZLATRD reduces the first NB rows and columns of a
matrix, of which the lower triangle is supplied.

This is an auxiliary routine called by ZHETRD.```
Parameters
 [in] UPLO ``` UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the Hermitian matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular``` [in] N ``` N is INTEGER The order of the matrix A.``` [in] NB ``` NB is INTEGER The number of rows and columns to be reduced.``` [in,out] A ``` A is COMPLEX*16 array, dimension (LDA,N) On entry, the Hermitian matrix A. If UPLO = 'U', the leading n-by-n upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading n-by-n lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit: if UPLO = 'U', the last NB columns have been reduced to tridiagonal form, with the diagonal elements overwriting the diagonal elements of A; the elements above the diagonal with the array TAU, represent the unitary matrix Q as a product of elementary reflectors; if UPLO = 'L', the first NB columns have been reduced to tridiagonal form, with the diagonal elements overwriting the diagonal elements of A; the elements below the diagonal with the array TAU, represent the unitary matrix Q as a product of elementary reflectors. See Further Details.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).``` [out] E ``` E is DOUBLE PRECISION array, dimension (N-1) If UPLO = 'U', E(n-nb:n-1) contains the superdiagonal elements of the last NB columns of the reduced matrix; if UPLO = 'L', E(1:nb) contains the subdiagonal elements of the first NB columns of the reduced matrix.``` [out] TAU ``` TAU is COMPLEX*16 array, dimension (N-1) The scalar factors of the elementary reflectors, stored in TAU(n-nb:n-1) if UPLO = 'U', and in TAU(1:nb) if UPLO = 'L'. See Further Details.``` [out] W ``` W is COMPLEX*16 array, dimension (LDW,NB) The n-by-nb matrix W required to update the unreduced part of A.``` [in] LDW ``` LDW is INTEGER The leading dimension of the array W. LDW >= max(1,N).```
Date
December 2016
Further Details:
```  If UPLO = 'U', the matrix Q is represented as a product of elementary
reflectors

Q = H(n) H(n-1) . . . H(n-nb+1).

Each H(i) has the form

H(i) = I - tau * v * v**H

where tau is a complex scalar, and v is a complex vector with
v(i:n) = 0 and v(i-1) = 1; v(1:i-1) is stored on exit in A(1:i-1,i),
and tau in TAU(i-1).

If UPLO = 'L', the matrix Q is represented as a product of elementary
reflectors

Q = H(1) H(2) . . . H(nb).

Each H(i) has the form

H(i) = I - tau * v * v**H

where tau is a complex scalar, and v is a complex vector with
v(1:i) = 0 and v(i+1) = 1; v(i+1:n) is stored on exit in A(i+1:n,i),
and tau in TAU(i).

The elements of the vectors v together form the n-by-nb matrix V
which is needed, with W, to apply the transformation to the unreduced
part of the matrix, using a Hermitian rank-2k update of the form:
A := A - V*W**H - W*V**H.

The contents of A on exit are illustrated by the following examples
with n = 5 and nb = 2:

if UPLO = 'U':                       if UPLO = 'L':

(  a   a   a   v4  v5 )              (  d                  )
(      a   a   v4  v5 )              (  1   d              )
(          a   1   v5 )              (  v1  1   a          )
(              d   1  )              (  v1  v2  a   a      )
(                  d  )              (  v1  v2  a   a   a  )

where d denotes a diagonal element of the reduced matrix, a denotes
an element of the original matrix that is unchanged, and vi denotes
an element of the vector defining H(i).```

Definition at line 201 of file zlatrd.f.

201 *
202 * -- LAPACK auxiliary routine (version 3.7.0) --
203 * -- LAPACK is a software package provided by Univ. of Tennessee, --
204 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
205 * December 2016
206 *
207 * .. Scalar Arguments ..
208  CHARACTER uplo
209  INTEGER lda, ldw, n, nb
210 * ..
211 * .. Array Arguments ..
212  DOUBLE PRECISION e( * )
213  COMPLEX*16 a( lda, * ), tau( * ), w( ldw, * )
214 * ..
215 *
216 * =====================================================================
217 *
218 * .. Parameters ..
219  COMPLEX*16 zero, one, half
220  parameter( zero = ( 0.0d+0, 0.0d+0 ),
221  \$ one = ( 1.0d+0, 0.0d+0 ),
222  \$ half = ( 0.5d+0, 0.0d+0 ) )
223 * ..
224 * .. Local Scalars ..
225  INTEGER i, iw
226  COMPLEX*16 alpha
227 * ..
228 * .. External Subroutines ..
229  EXTERNAL zaxpy, zgemv, zhemv, zlacgv, zlarfg, zscal
230 * ..
231 * .. External Functions ..
232  LOGICAL lsame
233  COMPLEX*16 zdotc
234  EXTERNAL lsame, zdotc
235 * ..
236 * .. Intrinsic Functions ..
237  INTRINSIC dble, min
238 * ..
239 * .. Executable Statements ..
240 *
241 * Quick return if possible
242 *
243  IF( n.LE.0 )
244  \$ RETURN
245 *
246  IF( lsame( uplo, 'U' ) ) THEN
247 *
248 * Reduce last NB columns of upper triangle
249 *
250  DO 10 i = n, n - nb + 1, -1
251  iw = i - n + nb
252  IF( i.LT.n ) THEN
253 *
254 * Update A(1:i,i)
255 *
256  a( i, i ) = dble( a( i, i ) )
257  CALL zlacgv( n-i, w( i, iw+1 ), ldw )
258  CALL zgemv( 'No transpose', i, n-i, -one, a( 1, i+1 ),
259  \$ lda, w( i, iw+1 ), ldw, one, a( 1, i ), 1 )
260  CALL zlacgv( n-i, w( i, iw+1 ), ldw )
261  CALL zlacgv( n-i, a( i, i+1 ), lda )
262  CALL zgemv( 'No transpose', i, n-i, -one, w( 1, iw+1 ),
263  \$ ldw, a( i, i+1 ), lda, one, a( 1, i ), 1 )
264  CALL zlacgv( n-i, a( i, i+1 ), lda )
265  a( i, i ) = dble( a( i, i ) )
266  END IF
267  IF( i.GT.1 ) THEN
268 *
269 * Generate elementary reflector H(i) to annihilate
270 * A(1:i-2,i)
271 *
272  alpha = a( i-1, i )
273  CALL zlarfg( i-1, alpha, a( 1, i ), 1, tau( i-1 ) )
274  e( i-1 ) = alpha
275  a( i-1, i ) = one
276 *
277 * Compute W(1:i-1,i)
278 *
279  CALL zhemv( 'Upper', i-1, one, a, lda, a( 1, i ), 1,
280  \$ zero, w( 1, iw ), 1 )
281  IF( i.LT.n ) THEN
282  CALL zgemv( 'Conjugate transpose', i-1, n-i, one,
283  \$ w( 1, iw+1 ), ldw, a( 1, i ), 1, zero,
284  \$ w( i+1, iw ), 1 )
285  CALL zgemv( 'No transpose', i-1, n-i, -one,
286  \$ a( 1, i+1 ), lda, w( i+1, iw ), 1, one,
287  \$ w( 1, iw ), 1 )
288  CALL zgemv( 'Conjugate transpose', i-1, n-i, one,
289  \$ a( 1, i+1 ), lda, a( 1, i ), 1, zero,
290  \$ w( i+1, iw ), 1 )
291  CALL zgemv( 'No transpose', i-1, n-i, -one,
292  \$ w( 1, iw+1 ), ldw, w( i+1, iw ), 1, one,
293  \$ w( 1, iw ), 1 )
294  END IF
295  CALL zscal( i-1, tau( i-1 ), w( 1, iw ), 1 )
296  alpha = -half*tau( i-1 )*zdotc( i-1, w( 1, iw ), 1,
297  \$ a( 1, i ), 1 )
298  CALL zaxpy( i-1, alpha, a( 1, i ), 1, w( 1, iw ), 1 )
299  END IF
300 *
301  10 CONTINUE
302  ELSE
303 *
304 * Reduce first NB columns of lower triangle
305 *
306  DO 20 i = 1, nb
307 *
308 * Update A(i:n,i)
309 *
310  a( i, i ) = dble( a( i, i ) )
311  CALL zlacgv( i-1, w( i, 1 ), ldw )
312  CALL zgemv( 'No transpose', n-i+1, i-1, -one, a( i, 1 ),
313  \$ lda, w( i, 1 ), ldw, one, a( i, i ), 1 )
314  CALL zlacgv( i-1, w( i, 1 ), ldw )
315  CALL zlacgv( i-1, a( i, 1 ), lda )
316  CALL zgemv( 'No transpose', n-i+1, i-1, -one, w( i, 1 ),
317  \$ ldw, a( i, 1 ), lda, one, a( i, i ), 1 )
318  CALL zlacgv( i-1, a( i, 1 ), lda )
319  a( i, i ) = dble( a( i, i ) )
320  IF( i.LT.n ) THEN
321 *
322 * Generate elementary reflector H(i) to annihilate
323 * A(i+2:n,i)
324 *
325  alpha = a( i+1, i )
326  CALL zlarfg( n-i, alpha, a( min( i+2, n ), i ), 1,
327  \$ tau( i ) )
328  e( i ) = alpha
329  a( i+1, i ) = one
330 *
331 * Compute W(i+1:n,i)
332 *
333  CALL zhemv( 'Lower', n-i, one, a( i+1, i+1 ), lda,
334  \$ a( i+1, i ), 1, zero, w( i+1, i ), 1 )
335  CALL zgemv( 'Conjugate transpose', n-i, i-1, one,
336  \$ w( i+1, 1 ), ldw, a( i+1, i ), 1, zero,
337  \$ w( 1, i ), 1 )
338  CALL zgemv( 'No transpose', n-i, i-1, -one, a( i+1, 1 ),
339  \$ lda, w( 1, i ), 1, one, w( i+1, i ), 1 )
340  CALL zgemv( 'Conjugate transpose', n-i, i-1, one,
341  \$ a( i+1, 1 ), lda, a( i+1, i ), 1, zero,
342  \$ w( 1, i ), 1 )
343  CALL zgemv( 'No transpose', n-i, i-1, -one, w( i+1, 1 ),
344  \$ ldw, w( 1, i ), 1, one, w( i+1, i ), 1 )
345  CALL zscal( n-i, tau( i ), w( i+1, i ), 1 )
346  alpha = -half*tau( i )*zdotc( n-i, w( i+1, i ), 1,
347  \$ a( i+1, i ), 1 )
348  CALL zaxpy( n-i, alpha, a( i+1, i ), 1, w( i+1, i ), 1 )
349  END IF
350 *
351  20 CONTINUE
352  END IF
353 *
354  RETURN
355 *
356 * End of ZLATRD
357 *
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:76
subroutine zaxpy(N, ZA, ZX, INCX, ZY, INCY)
ZAXPY
Definition: zaxpy.f:90
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
complex *16 function zdotc(N, ZX, INCX, ZY, INCY)
ZDOTC
Definition: zdotc.f:85
subroutine zscal(N, ZA, ZX, INCX)
ZSCAL
Definition: zscal.f:80
subroutine zgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZGEMV
Definition: zgemv.f:160
subroutine zlarfg(N, ALPHA, X, INCX, TAU)
ZLARFG generates an elementary reflector (Householder matrix).
Definition: zlarfg.f:108
subroutine zhemv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZHEMV
Definition: zhemv.f:156
Here is the call graph for this function:
Here is the caller graph for this function: