LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ dggsvp()

subroutine dggsvp ( character jobu,
character jobv,
character jobq,
integer m,
integer p,
integer n,
double precision, dimension( lda, * ) a,
integer lda,
double precision, dimension( ldb, * ) b,
integer ldb,
double precision tola,
double precision tolb,
integer k,
integer l,
double precision, dimension( ldu, * ) u,
integer ldu,
double precision, dimension( ldv, * ) v,
integer ldv,
double precision, dimension( ldq, * ) q,
integer ldq,
integer, dimension( * ) iwork,
double precision, dimension( * ) tau,
double precision, dimension( * ) work,
integer info )

DGGSVP

Download DGGSVP + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> This routine is deprecated and has been replaced by routine DGGSVP3.
!>
!> DGGSVP computes orthogonal matrices U, V and Q such that
!>
!>                    N-K-L  K    L
!>  U**T*A*Q =     K ( 0    A12  A13 )  if M-K-L >= 0;
!>                 L ( 0     0   A23 )
!>             M-K-L ( 0     0    0  )
!>
!>                  N-K-L  K    L
!>         =     K ( 0    A12  A13 )  if M-K-L < 0;
!>             M-K ( 0     0   A23 )
!>
!>                  N-K-L  K    L
!>  V**T*B*Q =   L ( 0     0   B13 )
!>             P-L ( 0     0    0  )
!>
!> where the K-by-K matrix A12 and L-by-L matrix B13 are nonsingular
!> upper triangular; A23 is L-by-L upper triangular if M-K-L >= 0,
!> otherwise A23 is (M-K)-by-L upper trapezoidal.  K+L = the effective
!> numerical rank of the (M+P)-by-N matrix (A**T,B**T)**T.
!>
!> This decomposition is the preprocessing step for computing the
!> Generalized Singular Value Decomposition (GSVD), see subroutine
!> DGGSVD.
!>
Parameters
[in]JOBU
!>          JOBU is CHARACTER*1
!>          = 'U':  Orthogonal matrix U is computed;
!>          = 'N':  U is not computed.
!>
[in]JOBV
!>          JOBV is CHARACTER*1
!>          = 'V':  Orthogonal matrix V is computed;
!>          = 'N':  V is not computed.
!>
[in]JOBQ
!>          JOBQ is CHARACTER*1
!>          = 'Q':  Orthogonal matrix Q is computed;
!>          = 'N':  Q is not computed.
!>
[in]M
!>          M is INTEGER
!>          The number of rows of the matrix A.  M >= 0.
!>
[in]P
!>          P is INTEGER
!>          The number of rows of the matrix B.  P >= 0.
!>
[in]N
!>          N is INTEGER
!>          The number of columns of the matrices A and B.  N >= 0.
!>
[in,out]A
!>          A is DOUBLE PRECISION array, dimension (LDA,N)
!>          On entry, the M-by-N matrix A.
!>          On exit, A contains the triangular (or trapezoidal) matrix
!>          described in the Purpose section.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A. LDA >= max(1,M).
!>
[in,out]B
!>          B is DOUBLE PRECISION array, dimension (LDB,N)
!>          On entry, the P-by-N matrix B.
!>          On exit, B contains the triangular matrix described in
!>          the Purpose section.
!>
[in]LDB
!>          LDB is INTEGER
!>          The leading dimension of the array B. LDB >= max(1,P).
!>
[in]TOLA
!>          TOLA is DOUBLE PRECISION
!>
[in]TOLB
!>          TOLB is DOUBLE PRECISION
!>
!>          TOLA and TOLB are the thresholds to determine the effective
!>          numerical rank of matrix B and a subblock of A. Generally,
!>          they are set to
!>             TOLA = MAX(M,N)*norm(A)*MACHEPS,
!>             TOLB = MAX(P,N)*norm(B)*MACHEPS.
!>          The size of TOLA and TOLB may affect the size of backward
!>          errors of the decomposition.
!>
[out]K
!>          K is INTEGER
!>
[out]L
!>          L is INTEGER
!>
!>          On exit, K and L specify the dimension of the subblocks
!>          described in Purpose section.
!>          K + L = effective numerical rank of (A**T,B**T)**T.
!>
[out]U
!>          U is DOUBLE PRECISION array, dimension (LDU,M)
!>          If JOBU = 'U', U contains the orthogonal matrix U.
!>          If JOBU = 'N', U is not referenced.
!>
[in]LDU
!>          LDU is INTEGER
!>          The leading dimension of the array U. LDU >= max(1,M) if
!>          JOBU = 'U'; LDU >= 1 otherwise.
!>
[out]V
!>          V is DOUBLE PRECISION array, dimension (LDV,P)
!>          If JOBV = 'V', V contains the orthogonal matrix V.
!>          If JOBV = 'N', V is not referenced.
!>
[in]LDV
!>          LDV is INTEGER
!>          The leading dimension of the array V. LDV >= max(1,P) if
!>          JOBV = 'V'; LDV >= 1 otherwise.
!>
[out]Q
!>          Q is DOUBLE PRECISION array, dimension (LDQ,N)
!>          If JOBQ = 'Q', Q contains the orthogonal matrix Q.
!>          If JOBQ = 'N', Q is not referenced.
!>
[in]LDQ
!>          LDQ is INTEGER
!>          The leading dimension of the array Q. LDQ >= max(1,N) if
!>          JOBQ = 'Q'; LDQ >= 1 otherwise.
!>
[out]IWORK
!>          IWORK is INTEGER array, dimension (N)
!>
[out]TAU
!>          TAU is DOUBLE PRECISION array, dimension (N)
!>
[out]WORK
!>          WORK is DOUBLE PRECISION array, dimension (max(3*N,M,P))
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
The subroutine uses LAPACK subroutine DGEQPF for the QR factorization with column pivoting to detect the effective numerical rank of the a matrix. It may be replaced by a better rank determination strategy.

Definition at line 251 of file dggsvp.f.

254*
255* -- LAPACK computational routine --
256* -- LAPACK is a software package provided by Univ. of Tennessee, --
257* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
258*
259* .. Scalar Arguments ..
260 CHARACTER JOBQ, JOBU, JOBV
261 INTEGER INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N, P
262 DOUBLE PRECISION TOLA, TOLB
263* ..
264* .. Array Arguments ..
265 INTEGER IWORK( * )
266 DOUBLE PRECISION A( LDA, * ), B( LDB, * ), Q( LDQ, * ),
267 $ TAU( * ), U( LDU, * ), V( LDV, * ), WORK( * )
268* ..
269*
270* =====================================================================
271*
272* .. Parameters ..
273 DOUBLE PRECISION ZERO, ONE
274 parameter( zero = 0.0d+0, one = 1.0d+0 )
275* ..
276* .. Local Scalars ..
277 LOGICAL FORWRD, WANTQ, WANTU, WANTV
278 INTEGER I, J
279* ..
280* .. External Functions ..
281 LOGICAL LSAME
282 EXTERNAL lsame
283* ..
284* .. External Subroutines ..
285 EXTERNAL dgeqpf, dgeqr2, dgerq2, dlacpy, dlapmt, dlaset,
286 $ dorg2r, dorm2r, dormr2, xerbla
287* ..
288* .. Intrinsic Functions ..
289 INTRINSIC abs, max, min
290* ..
291* .. Executable Statements ..
292*
293* Test the input parameters
294*
295 wantu = lsame( jobu, 'U' )
296 wantv = lsame( jobv, 'V' )
297 wantq = lsame( jobq, 'Q' )
298 forwrd = .true.
299*
300 info = 0
301 IF( .NOT.( wantu .OR. lsame( jobu, 'N' ) ) ) THEN
302 info = -1
303 ELSE IF( .NOT.( wantv .OR. lsame( jobv, 'N' ) ) ) THEN
304 info = -2
305 ELSE IF( .NOT.( wantq .OR. lsame( jobq, 'N' ) ) ) THEN
306 info = -3
307 ELSE IF( m.LT.0 ) THEN
308 info = -4
309 ELSE IF( p.LT.0 ) THEN
310 info = -5
311 ELSE IF( n.LT.0 ) THEN
312 info = -6
313 ELSE IF( lda.LT.max( 1, m ) ) THEN
314 info = -8
315 ELSE IF( ldb.LT.max( 1, p ) ) THEN
316 info = -10
317 ELSE IF( ldu.LT.1 .OR. ( wantu .AND. ldu.LT.m ) ) THEN
318 info = -16
319 ELSE IF( ldv.LT.1 .OR. ( wantv .AND. ldv.LT.p ) ) THEN
320 info = -18
321 ELSE IF( ldq.LT.1 .OR. ( wantq .AND. ldq.LT.n ) ) THEN
322 info = -20
323 END IF
324 IF( info.NE.0 ) THEN
325 CALL xerbla( 'DGGSVP', -info )
326 RETURN
327 END IF
328*
329* QR with column pivoting of B: B*P = V*( S11 S12 )
330* ( 0 0 )
331*
332 DO 10 i = 1, n
333 iwork( i ) = 0
334 10 CONTINUE
335 CALL dgeqpf( p, n, b, ldb, iwork, tau, work, info )
336*
337* Update A := A*P
338*
339 CALL dlapmt( forwrd, m, n, a, lda, iwork )
340*
341* Determine the effective rank of matrix B.
342*
343 l = 0
344 DO 20 i = 1, min( p, n )
345 IF( abs( b( i, i ) ).GT.tolb )
346 $ l = l + 1
347 20 CONTINUE
348*
349 IF( wantv ) THEN
350*
351* Copy the details of V, and form V.
352*
353 CALL dlaset( 'Full', p, p, zero, zero, v, ldv )
354 IF( p.GT.1 )
355 $ CALL dlacpy( 'Lower', p-1, n, b( 2, 1 ), ldb, v( 2, 1 ),
356 $ ldv )
357 CALL dorg2r( p, p, min( p, n ), v, ldv, tau, work, info )
358 END IF
359*
360* Clean up B
361*
362 DO 40 j = 1, l - 1
363 DO 30 i = j + 1, l
364 b( i, j ) = zero
365 30 CONTINUE
366 40 CONTINUE
367 IF( p.GT.l )
368 $ CALL dlaset( 'Full', p-l, n, zero, zero, b( l+1, 1 ), ldb )
369*
370 IF( wantq ) THEN
371*
372* Set Q = I and Update Q := Q*P
373*
374 CALL dlaset( 'Full', n, n, zero, one, q, ldq )
375 CALL dlapmt( forwrd, n, n, q, ldq, iwork )
376 END IF
377*
378 IF( p.GE.l .AND. n.NE.l ) THEN
379*
380* RQ factorization of (S11 S12): ( S11 S12 ) = ( 0 S12 )*Z
381*
382 CALL dgerq2( l, n, b, ldb, tau, work, info )
383*
384* Update A := A*Z**T
385*
386 CALL dormr2( 'Right', 'Transpose', m, n, l, b, ldb, tau, a,
387 $ lda, work, info )
388*
389 IF( wantq ) THEN
390*
391* Update Q := Q*Z**T
392*
393 CALL dormr2( 'Right', 'Transpose', n, n, l, b, ldb, tau,
394 $ q, ldq, work, info )
395 END IF
396*
397* Clean up B
398*
399 CALL dlaset( 'Full', l, n-l, zero, zero, b, ldb )
400 DO 60 j = n - l + 1, n
401 DO 50 i = j - n + l + 1, l
402 b( i, j ) = zero
403 50 CONTINUE
404 60 CONTINUE
405*
406 END IF
407*
408* Let N-L L
409* A = ( A11 A12 ) M,
410*
411* then the following does the complete QR decomposition of A11:
412*
413* A11 = U*( 0 T12 )*P1**T
414* ( 0 0 )
415*
416 DO 70 i = 1, n - l
417 iwork( i ) = 0
418 70 CONTINUE
419 CALL dgeqpf( m, n-l, a, lda, iwork, tau, work, info )
420*
421* Determine the effective rank of A11
422*
423 k = 0
424 DO 80 i = 1, min( m, n-l )
425 IF( abs( a( i, i ) ).GT.tola )
426 $ k = k + 1
427 80 CONTINUE
428*
429* Update A12 := U**T*A12, where A12 = A( 1:M, N-L+1:N )
430*
431 CALL dorm2r( 'Left', 'Transpose', m, l, min( m, n-l ), a, lda,
432 $ tau, a( 1, n-l+1 ), lda, work, info )
433*
434 IF( wantu ) THEN
435*
436* Copy the details of U, and form U
437*
438 CALL dlaset( 'Full', m, m, zero, zero, u, ldu )
439 IF( m.GT.1 )
440 $ CALL dlacpy( 'Lower', m-1, n-l, a( 2, 1 ), lda,
441 $ u( 2, 1 ), ldu )
442 CALL dorg2r( m, m, min( m, n-l ), u, ldu, tau, work,
443 $ info )
444 END IF
445*
446 IF( wantq ) THEN
447*
448* Update Q( 1:N, 1:N-L ) = Q( 1:N, 1:N-L )*P1
449*
450 CALL dlapmt( forwrd, n, n-l, q, ldq, iwork )
451 END IF
452*
453* Clean up A: set the strictly lower triangular part of
454* A(1:K, 1:K) = 0, and A( K+1:M, 1:N-L ) = 0.
455*
456 DO 100 j = 1, k - 1
457 DO 90 i = j + 1, k
458 a( i, j ) = zero
459 90 CONTINUE
460 100 CONTINUE
461 IF( m.GT.k )
462 $ CALL dlaset( 'Full', m-k, n-l, zero, zero, a( k+1, 1 ),
463 $ lda )
464*
465 IF( n-l.GT.k ) THEN
466*
467* RQ factorization of ( T11 T12 ) = ( 0 T12 )*Z1
468*
469 CALL dgerq2( k, n-l, a, lda, tau, work, info )
470*
471 IF( wantq ) THEN
472*
473* Update Q( 1:N,1:N-L ) = Q( 1:N,1:N-L )*Z1**T
474*
475 CALL dormr2( 'Right', 'Transpose', n, n-l, k, a, lda,
476 $ tau, q, ldq, work, info )
477 END IF
478*
479* Clean up A
480*
481 CALL dlaset( 'Full', k, n-l-k, zero, zero, a, lda )
482 DO 120 j = n - l - k + 1, n - l
483 DO 110 i = j - n + l + k + 1, k
484 a( i, j ) = zero
485 110 CONTINUE
486 120 CONTINUE
487*
488 END IF
489*
490 IF( m.GT.k ) THEN
491*
492* QR factorization of A( K+1:M,N-L+1:N )
493*
494 CALL dgeqr2( m-k, l, a( k+1, n-l+1 ), lda, tau, work, info )
495*
496 IF( wantu ) THEN
497*
498* Update U(:,K+1:M) := U(:,K+1:M)*U1
499*
500 CALL dorm2r( 'Right', 'No transpose', m, m-k,
501 $ min( m-k, l ), a( k+1, n-l+1 ), lda, tau,
502 $ u( 1, k+1 ), ldu, work, info )
503 END IF
504*
505* Clean up
506*
507 DO 140 j = n - l + 1, n
508 DO 130 i = j - n + k + l + 1, m
509 a( i, j ) = zero
510 130 CONTINUE
511 140 CONTINUE
512*
513 END IF
514*
515 RETURN
516*
517* End of DGGSVP
518*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
dgeqpf
subroutine dgeqpf(m, n, a, lda, jpvt, tau, work, info)
DGEQPF
Definition dgeqpf.f:140
dgeqr2
subroutine dgeqr2(m, n, a, lda, tau, work, info)
DGEQR2 computes the QR factorization of a general rectangular matrix using an unblocked algorithm.
Definition dgeqr2.f:128
dgerq2
subroutine dgerq2(m, n, a, lda, tau, work, info)
DGERQ2 computes the RQ factorization of a general rectangular matrix using an unblocked algorithm.
Definition dgerq2.f:121
dlacpy
subroutine dlacpy(uplo, m, n, a, lda, b, ldb)
DLACPY copies all or part of one two-dimensional array to another.
Definition dlacpy.f:101
dlapmt
subroutine dlapmt(forwrd, m, n, x, ldx, k)
DLAPMT performs a forward or backward permutation of the columns of a matrix.
Definition dlapmt.f:102
dlaset
subroutine dlaset(uplo, m, n, alpha, beta, a, lda)
DLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition dlaset.f:108
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
dorg2r
subroutine dorg2r(m, n, k, a, lda, tau, work, info)
DORG2R generates all or part of the orthogonal matrix Q from a QR factorization determined by sgeqrf ...
Definition dorg2r.f:112
dorm2r
subroutine dorm2r(side, trans, m, n, k, a, lda, tau, c, ldc, work, info)
DORM2R multiplies a general matrix by the orthogonal matrix from a QR factorization determined by sge...
Definition dorm2r.f:156
dormr2
subroutine dormr2(side, trans, m, n, k, a, lda, tau, c, ldc, work, info)
DORMR2 multiplies a general matrix by the orthogonal matrix from a RQ factorization determined by sge...
Definition dormr2.f:157
Here is the call graph for this function:
Here is the caller graph for this function: