zhetd2()

subroutine zhetd2	(	character	uplo,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		complex*16, dimension( * )	tau,
		integer	info )

ZHETD2 reduces a Hermitian matrix to real symmetric tridiagonal form by an unitary similarity transformation (unblocked algorithm).

Download ZHETD2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZHETD2 reduces a complex Hermitian matrix A to real symmetric
!> tridiagonal form T by a unitary similarity transformation:
!> Q**H * A * Q = T.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> Hermitian matrix A is stored: !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the Hermitian matrix A. If UPLO = 'U', the leading !> n-by-n upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading n-by-n lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. !> On exit, if UPLO = 'U', the diagonal and first superdiagonal !> of A are overwritten by the corresponding elements of the !> tridiagonal matrix T, and the elements above the first !> superdiagonal, with the array TAU, represent the unitary !> matrix Q as a product of elementary reflectors; if UPLO !> = 'L', the diagonal and first subdiagonal of A are over- !> written by the corresponding elements of the tridiagonal !> matrix T, and the elements below the first subdiagonal, with !> the array TAU, represent the unitary matrix Q as a product !> of elementary reflectors. See Further Details. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	D	!> D is DOUBLE PRECISION array, dimension (N) !> The diagonal elements of the tridiagonal matrix T: !> D(i) = A(i,i). !>
[out]	E	!> E is DOUBLE PRECISION array, dimension (N-1) !> The off-diagonal elements of the tridiagonal matrix T: !> E(i) = A(i,i+1) if UPLO = 'U', E(i) = A(i+1,i) if UPLO = 'L'. !>
[out]	TAU	!> TAU is COMPLEX*16 array, dimension (N-1) !> The scalar factors of the elementary reflectors (see Further !> Details). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  If UPLO = 'U', the matrix Q is represented as a product of elementary
!>  reflectors
!>
!>     Q = H(n-1) . . . H(2) H(1).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - tau * v * v**H
!>
!>  where tau is a complex scalar, and v is a complex vector with
!>  v(i+1:n) = 0 and v(i) = 1; v(1:i-1) is stored on exit in
!>  A(1:i-1,i+1), and tau in TAU(i).
!>
!>  If UPLO = 'L', the matrix Q is represented as a product of elementary
!>  reflectors
!>
!>     Q = H(1) H(2) . . . H(n-1).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - tau * v * v**H
!>
!>  where tau is a complex scalar, and v is a complex vector with
!>  v(1:i) = 0 and v(i+1) = 1; v(i+2:n) is stored on exit in A(i+2:n,i),
!>  and tau in TAU(i).
!>
!>  The contents of A on exit are illustrated by the following examples
!>  with n = 5:
!>
!>  if UPLO = 'U':                       if UPLO = 'L':
!>
!>    (  d   e   v2  v3  v4 )              (  d                  )
!>    (      d   e   v3  v4 )              (  e   d              )
!>    (          d   e   v4 )              (  v1  e   d          )
!>    (              d   e  )              (  v1  v2  e   d      )
!>    (                  d  )              (  v1  v2  v3  e   d  )
!>
!>  where d and e denote diagonal and off-diagonal elements of T, and vi
!>  denotes an element of the vector defining H(i).
!> 

Definition at line 172 of file zhetd2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * ), E( * )
      COMPLEX*16         A( LDA, * ), TAU( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ONE, ZERO, HALF
      parameter( one = ( 1.0d+0, 0.0d+0 ),
     $                   zero = ( 0.0d+0, 0.0d+0 ),
     $                   half = ( 0.5d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I
      COMPLEX*16         ALPHA, TAUI
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zaxpy, zhemv, zher2, zlarfg
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      COMPLEX*16         ZDOTC
      EXTERNAL           lsame, zdotc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      upper = lsame( uplo, 'U')
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZHETD2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Reduce the upper triangle of A
*
         a( n, n ) = dble( a( n, n ) )
         DO 10 i = n - 1, 1, -1
*
*           Generate elementary reflector H(i) = I - tau * v * v**H
*           to annihilate A(1:i-1,i+1)
*
            alpha = a( i, i+1 )
            CALL zlarfg( i, alpha, a( 1, i+1 ), 1, taui )
            e( i ) = dble( alpha )
*
            IF( taui.NE.zero ) THEN
*
*              Apply H(i) from both sides to A(1:i,1:i)
*
               a( i, i+1 ) = one
*
*              Compute  x := tau * A * v  storing x in TAU(1:i)
*
               CALL zhemv( uplo, i, taui, a, lda, a( 1, i+1 ), 1,
     $                     zero,
     $                     tau, 1 )
*
*              Compute  w := x - 1/2 * tau * (x**H * v) * v
*
               alpha = -half*taui*zdotc( i, tau, 1, a( 1, i+1 ), 1 )
               CALL zaxpy( i, alpha, a( 1, i+1 ), 1, tau, 1 )
*
*              Apply the transformation as a rank-2 update:
*                 A := A - v * w**H - w * v**H
*
               CALL zher2( uplo, i, -one, a( 1, i+1 ), 1, tau, 1, a,
     $                     lda )
*
            ELSE
               a( i, i ) = dble( a( i, i ) )
            END IF
            a( i, i+1 ) = e( i )
            d( i+1 ) = dble( a( i+1, i+1 ) )
            tau( i ) = taui
   10    CONTINUE
         d( 1 ) = dble( a( 1, 1 ) )
      ELSE
*
*        Reduce the lower triangle of A
*
         a( 1, 1 ) = dble( a( 1, 1 ) )
         DO 20 i = 1, n - 1
*
*           Generate elementary reflector H(i) = I - tau * v * v**H
*           to annihilate A(i+2:n,i)
*
            alpha = a( i+1, i )
            CALL zlarfg( n-i, alpha, a( min( i+2, n ), i ), 1, taui )
            e( i ) = dble( alpha )
*
            IF( taui.NE.zero ) THEN
*
*              Apply H(i) from both sides to A(i+1:n,i+1:n)
*
               a( i+1, i ) = one
*
*              Compute  x := tau * A * v  storing y in TAU(i:n-1)
*
               CALL zhemv( uplo, n-i, taui, a( i+1, i+1 ), lda,
     $                     a( i+1, i ), 1, zero, tau( i ), 1 )
*
*              Compute  w := x - 1/2 * tau * (x**H * v) * v
*
               alpha = -half*taui*zdotc( n-i, tau( i ), 1, a( i+1,
     $                                   i ),
     $                 1 )
               CALL zaxpy( n-i, alpha, a( i+1, i ), 1, tau( i ), 1 )
*
*              Apply the transformation as a rank-2 update:
*                 A := A - v * w**H - w * v**H
*
               CALL zher2( uplo, n-i, -one, a( i+1, i ), 1, tau( i ),
     $                     1,
     $                     a( i+1, i+1 ), lda )
*
            ELSE
               a( i+1, i+1 ) = dble( a( i+1, i+1 ) )
            END IF
            a( i+1, i ) = e( i )
            d( i ) = dble( a( i, i ) )
            tau( i ) = taui
   20    CONTINUE
         d( n ) = dble( a( n, n ) )
      END IF
*
      RETURN
*
*     End of ZHETD2
*

Here is the call graph for this function:

Here is the caller graph for this function: