LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
slasr.f
Go to the documentation of this file.
1 *> \brief \b SLASR applies a sequence of plane rotations to a general rectangular matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download SLASR + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slasr.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slasr.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slasr.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SLASR( SIDE, PIVOT, DIRECT, M, N, C, S, A, LDA )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER DIRECT, PIVOT, SIDE
25 * INTEGER LDA, M, N
26 * ..
27 * .. Array Arguments ..
28 * REAL A( LDA, * ), C( * ), S( * )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *> SLASR applies a sequence of plane rotations to a real matrix A,
38 *> from either the left or the right.
39 *>
40 *> When SIDE = 'L', the transformation takes the form
41 *>
42 *> A := P*A
43 *>
44 *> and when SIDE = 'R', the transformation takes the form
45 *>
46 *> A := A*P**T
47 *>
48 *> where P is an orthogonal matrix consisting of a sequence of z plane
49 *> rotations, with z = M when SIDE = 'L' and z = N when SIDE = 'R',
50 *> and P**T is the transpose of P.
51 *>
52 *> When DIRECT = 'F' (Forward sequence), then
53 *>
54 *> P = P(z-1) * ... * P(2) * P(1)
55 *>
56 *> and when DIRECT = 'B' (Backward sequence), then
57 *>
58 *> P = P(1) * P(2) * ... * P(z-1)
59 *>
60 *> where P(k) is a plane rotation matrix defined by the 2-by-2 rotation
61 *>
62 *> R(k) = ( c(k) s(k) )
63 *> = ( -s(k) c(k) ).
64 *>
65 *> When PIVOT = 'V' (Variable pivot), the rotation is performed
66 *> for the plane (k,k+1), i.e., P(k) has the form
67 *>
68 *> P(k) = ( 1 )
69 *> ( ... )
70 *> ( 1 )
71 *> ( c(k) s(k) )
72 *> ( -s(k) c(k) )
73 *> ( 1 )
74 *> ( ... )
75 *> ( 1 )
76 *>
77 *> where R(k) appears as a rank-2 modification to the identity matrix in
78 *> rows and columns k and k+1.
79 *>
80 *> When PIVOT = 'T' (Top pivot), the rotation is performed for the
81 *> plane (1,k+1), so P(k) has the form
82 *>
83 *> P(k) = ( c(k) s(k) )
84 *> ( 1 )
85 *> ( ... )
86 *> ( 1 )
87 *> ( -s(k) c(k) )
88 *> ( 1 )
89 *> ( ... )
90 *> ( 1 )
91 *>
92 *> where R(k) appears in rows and columns 1 and k+1.
93 *>
94 *> Similarly, when PIVOT = 'B' (Bottom pivot), the rotation is
95 *> performed for the plane (k,z), giving P(k) the form
96 *>
97 *> P(k) = ( 1 )
98 *> ( ... )
99 *> ( 1 )
100 *> ( c(k) s(k) )
101 *> ( 1 )
102 *> ( ... )
103 *> ( 1 )
104 *> ( -s(k) c(k) )
105 *>
106 *> where R(k) appears in rows and columns k and z. The rotations are
107 *> performed without ever forming P(k) explicitly.
108 *> \endverbatim
109 *
110 * Arguments:
111 * ==========
112 *
113 *> \param[in] SIDE
114 *> \verbatim
115 *> SIDE is CHARACTER*1
116 *> Specifies whether the plane rotation matrix P is applied to
117 *> A on the left or the right.
118 *> = 'L': Left, compute A := P*A
119 *> = 'R': Right, compute A:= A*P**T
120 *> \endverbatim
121 *>
122 *> \param[in] PIVOT
123 *> \verbatim
124 *> PIVOT is CHARACTER*1
125 *> Specifies the plane for which P(k) is a plane rotation
126 *> matrix.
127 *> = 'V': Variable pivot, the plane (k,k+1)
128 *> = 'T': Top pivot, the plane (1,k+1)
129 *> = 'B': Bottom pivot, the plane (k,z)
130 *> \endverbatim
131 *>
132 *> \param[in] DIRECT
133 *> \verbatim
134 *> DIRECT is CHARACTER*1
135 *> Specifies whether P is a forward or backward sequence of
136 *> plane rotations.
137 *> = 'F': Forward, P = P(z-1)*...*P(2)*P(1)
138 *> = 'B': Backward, P = P(1)*P(2)*...*P(z-1)
139 *> \endverbatim
140 *>
141 *> \param[in] M
142 *> \verbatim
143 *> M is INTEGER
144 *> The number of rows of the matrix A. If m <= 1, an immediate
145 *> return is effected.
146 *> \endverbatim
147 *>
148 *> \param[in] N
149 *> \verbatim
150 *> N is INTEGER
151 *> The number of columns of the matrix A. If n <= 1, an
152 *> immediate return is effected.
153 *> \endverbatim
154 *>
155 *> \param[in] C
156 *> \verbatim
157 *> C is REAL array, dimension
158 *> (M-1) if SIDE = 'L'
159 *> (N-1) if SIDE = 'R'
160 *> The cosines c(k) of the plane rotations.
161 *> \endverbatim
162 *>
163 *> \param[in] S
164 *> \verbatim
165 *> S is REAL array, dimension
166 *> (M-1) if SIDE = 'L'
167 *> (N-1) if SIDE = 'R'
168 *> The sines s(k) of the plane rotations. The 2-by-2 plane
169 *> rotation part of the matrix P(k), R(k), has the form
170 *> R(k) = ( c(k) s(k) )
171 *> ( -s(k) c(k) ).
172 *> \endverbatim
173 *>
174 *> \param[in,out] A
175 *> \verbatim
176 *> A is REAL array, dimension (LDA,N)
177 *> The M-by-N matrix A. On exit, A is overwritten by P*A if
178 *> SIDE = 'R' or by A*P**T if SIDE = 'L'.
179 *> \endverbatim
180 *>
181 *> \param[in] LDA
182 *> \verbatim
183 *> LDA is INTEGER
184 *> The leading dimension of the array A. LDA >= max(1,M).
185 *> \endverbatim
186 *
187 * Authors:
188 * ========
189 *
190 *> \author Univ. of Tennessee
191 *> \author Univ. of California Berkeley
192 *> \author Univ. of Colorado Denver
193 *> \author NAG Ltd.
194 *
195 *> \ingroup OTHERauxiliary
196 *
197 * =====================================================================
198  SUBROUTINE slasr( SIDE, PIVOT, DIRECT, M, N, C, S, A, LDA )
199 *
200 * -- LAPACK auxiliary routine --
201 * -- LAPACK is a software package provided by Univ. of Tennessee, --
202 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
203 *
204 * .. Scalar Arguments ..
205  CHARACTER DIRECT, PIVOT, SIDE
206  INTEGER LDA, M, N
207 * ..
208 * .. Array Arguments ..
209  REAL A( LDA, * ), C( * ), S( * )
210 * ..
211 *
212 * =====================================================================
213 *
214 * .. Parameters ..
215  REAL ONE, ZERO
216  parameter( one = 1.0e+0, zero = 0.0e+0 )
217 * ..
218 * .. Local Scalars ..
219  INTEGER I, INFO, J
220  REAL CTEMP, STEMP, TEMP
221 * ..
222 * .. External Functions ..
223  LOGICAL LSAME
224  EXTERNAL lsame
225 * ..
226 * .. External Subroutines ..
227  EXTERNAL xerbla
228 * ..
229 * .. Intrinsic Functions ..
230  INTRINSIC max
231 * ..
232 * .. Executable Statements ..
233 *
234 * Test the input parameters
235 *
236  info = 0
237  IF( .NOT.( lsame( side, 'L' ) .OR. lsame( side, 'R' ) ) ) THEN
238  info = 1
239  ELSE IF( .NOT.( lsame( pivot, 'V' ) .OR. lsame( pivot,
240  $ 'T' ) .OR. lsame( pivot, 'B' ) ) ) THEN
241  info = 2
242  ELSE IF( .NOT.( lsame( direct, 'F' ) .OR. lsame( direct, 'B' ) ) )
243  $ THEN
244  info = 3
245  ELSE IF( m.LT.0 ) THEN
246  info = 4
247  ELSE IF( n.LT.0 ) THEN
248  info = 5
249  ELSE IF( lda.LT.max( 1, m ) ) THEN
250  info = 9
251  END IF
252  IF( info.NE.0 ) THEN
253  CALL xerbla( 'SLASR ', info )
254  RETURN
255  END IF
256 *
257 * Quick return if possible
258 *
259  IF( ( m.EQ.0 ) .OR. ( n.EQ.0 ) )
260  $ RETURN
261  IF( lsame( side, 'L' ) ) THEN
262 *
263 * Form P * A
264 *
265  IF( lsame( pivot, 'V' ) ) THEN
266  IF( lsame( direct, 'F' ) ) THEN
267  DO 20 j = 1, m - 1
268  ctemp = c( j )
269  stemp = s( j )
270  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
271  DO 10 i = 1, n
272  temp = a( j+1, i )
273  a( j+1, i ) = ctemp*temp - stemp*a( j, i )
274  a( j, i ) = stemp*temp + ctemp*a( j, i )
275  10 CONTINUE
276  END IF
277  20 CONTINUE
278  ELSE IF( lsame( direct, 'B' ) ) THEN
279  DO 40 j = m - 1, 1, -1
280  ctemp = c( j )
281  stemp = s( j )
282  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
283  DO 30 i = 1, n
284  temp = a( j+1, i )
285  a( j+1, i ) = ctemp*temp - stemp*a( j, i )
286  a( j, i ) = stemp*temp + ctemp*a( j, i )
287  30 CONTINUE
288  END IF
289  40 CONTINUE
290  END IF
291  ELSE IF( lsame( pivot, 'T' ) ) THEN
292  IF( lsame( direct, 'F' ) ) THEN
293  DO 60 j = 2, m
294  ctemp = c( j-1 )
295  stemp = s( j-1 )
296  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
297  DO 50 i = 1, n
298  temp = a( j, i )
299  a( j, i ) = ctemp*temp - stemp*a( 1, i )
300  a( 1, i ) = stemp*temp + ctemp*a( 1, i )
301  50 CONTINUE
302  END IF
303  60 CONTINUE
304  ELSE IF( lsame( direct, 'B' ) ) THEN
305  DO 80 j = m, 2, -1
306  ctemp = c( j-1 )
307  stemp = s( j-1 )
308  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
309  DO 70 i = 1, n
310  temp = a( j, i )
311  a( j, i ) = ctemp*temp - stemp*a( 1, i )
312  a( 1, i ) = stemp*temp + ctemp*a( 1, i )
313  70 CONTINUE
314  END IF
315  80 CONTINUE
316  END IF
317  ELSE IF( lsame( pivot, 'B' ) ) THEN
318  IF( lsame( direct, 'F' ) ) THEN
319  DO 100 j = 1, m - 1
320  ctemp = c( j )
321  stemp = s( j )
322  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
323  DO 90 i = 1, n
324  temp = a( j, i )
325  a( j, i ) = stemp*a( m, i ) + ctemp*temp
326  a( m, i ) = ctemp*a( m, i ) - stemp*temp
327  90 CONTINUE
328  END IF
329  100 CONTINUE
330  ELSE IF( lsame( direct, 'B' ) ) THEN
331  DO 120 j = m - 1, 1, -1
332  ctemp = c( j )
333  stemp = s( j )
334  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
335  DO 110 i = 1, n
336  temp = a( j, i )
337  a( j, i ) = stemp*a( m, i ) + ctemp*temp
338  a( m, i ) = ctemp*a( m, i ) - stemp*temp
339  110 CONTINUE
340  END IF
341  120 CONTINUE
342  END IF
343  END IF
344  ELSE IF( lsame( side, 'R' ) ) THEN
345 *
346 * Form A * P**T
347 *
348  IF( lsame( pivot, 'V' ) ) THEN
349  IF( lsame( direct, 'F' ) ) THEN
350  DO 140 j = 1, n - 1
351  ctemp = c( j )
352  stemp = s( j )
353  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
354  DO 130 i = 1, m
355  temp = a( i, j+1 )
356  a( i, j+1 ) = ctemp*temp - stemp*a( i, j )
357  a( i, j ) = stemp*temp + ctemp*a( i, j )
358  130 CONTINUE
359  END IF
360  140 CONTINUE
361  ELSE IF( lsame( direct, 'B' ) ) THEN
362  DO 160 j = n - 1, 1, -1
363  ctemp = c( j )
364  stemp = s( j )
365  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
366  DO 150 i = 1, m
367  temp = a( i, j+1 )
368  a( i, j+1 ) = ctemp*temp - stemp*a( i, j )
369  a( i, j ) = stemp*temp + ctemp*a( i, j )
370  150 CONTINUE
371  END IF
372  160 CONTINUE
373  END IF
374  ELSE IF( lsame( pivot, 'T' ) ) THEN
375  IF( lsame( direct, 'F' ) ) THEN
376  DO 180 j = 2, n
377  ctemp = c( j-1 )
378  stemp = s( j-1 )
379  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
380  DO 170 i = 1, m
381  temp = a( i, j )
382  a( i, j ) = ctemp*temp - stemp*a( i, 1 )
383  a( i, 1 ) = stemp*temp + ctemp*a( i, 1 )
384  170 CONTINUE
385  END IF
386  180 CONTINUE
387  ELSE IF( lsame( direct, 'B' ) ) THEN
388  DO 200 j = n, 2, -1
389  ctemp = c( j-1 )
390  stemp = s( j-1 )
391  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
392  DO 190 i = 1, m
393  temp = a( i, j )
394  a( i, j ) = ctemp*temp - stemp*a( i, 1 )
395  a( i, 1 ) = stemp*temp + ctemp*a( i, 1 )
396  190 CONTINUE
397  END IF
398  200 CONTINUE
399  END IF
400  ELSE IF( lsame( pivot, 'B' ) ) THEN
401  IF( lsame( direct, 'F' ) ) THEN
402  DO 220 j = 1, n - 1
403  ctemp = c( j )
404  stemp = s( j )
405  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
406  DO 210 i = 1, m
407  temp = a( i, j )
408  a( i, j ) = stemp*a( i, n ) + ctemp*temp
409  a( i, n ) = ctemp*a( i, n ) - stemp*temp
410  210 CONTINUE
411  END IF
412  220 CONTINUE
413  ELSE IF( lsame( direct, 'B' ) ) THEN
414  DO 240 j = n - 1, 1, -1
415  ctemp = c( j )
416  stemp = s( j )
417  IF( ( ctemp.NE.one ) .OR. ( stemp.NE.zero ) ) THEN
418  DO 230 i = 1, m
419  temp = a( i, j )
420  a( i, j ) = stemp*a( i, n ) + ctemp*temp
421  a( i, n ) = ctemp*a( i, n ) - stemp*temp
422  230 CONTINUE
423  END IF
424  240 CONTINUE
425  END IF
426  END IF
427  END IF
428 *
429  RETURN
430 *
431 * End of SLASR
432 *
433  END
subroutine slasr(SIDE, PIVOT, DIRECT, M, N, C, S, A, LDA)
SLASR applies a sequence of plane rotations to a general rectangular matrix.
Definition: slasr.f:199
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60