LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ strt03()

subroutine strt03 ( character  UPLO,
character  TRANS,
character  DIAG,
integer  N,
integer  NRHS,
real, dimension( lda, * )  A,
integer  LDA,
real  SCALE,
real, dimension( * )  CNORM,
real  TSCAL,
real, dimension( ldx, * )  X,
integer  LDX,
real, dimension( ldb, * )  B,
integer  LDB,
real, dimension( * )  WORK,
real  RESID 
)

STRT03

Purpose:
 STRT03 computes the residual for the solution to a scaled triangular
 system of equations A*x = s*b  or  A'*x = s*b.
 Here A is a triangular matrix, A' is the transpose of A, s is a
 scalar, and x and b are N by NRHS matrices.  The test ratio is the
 maximum over the number of right hand sides of
    norm(s*b - op(A)*x) / ( norm(op(A)) * norm(x) * EPS ),
 where op(A) denotes A or A' and EPS is the machine epsilon.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the matrix A is upper or lower triangular.
          = 'U':  Upper triangular
          = 'L':  Lower triangular
[in]TRANS
          TRANS is CHARACTER*1
          Specifies the operation applied to A.
          = 'N':  A *x = s*b  (No transpose)
          = 'T':  A'*x = s*b  (Transpose)
          = 'C':  A'*x = s*b  (Conjugate transpose = Transpose)
[in]DIAG
          DIAG is CHARACTER*1
          Specifies whether or not the matrix A is unit triangular.
          = 'N':  Non-unit triangular
          = 'U':  Unit triangular
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrices X and B.  NRHS >= 0.
[in]A
          A is REAL array, dimension (LDA,N)
          The triangular matrix A.  If UPLO = 'U', the leading n by n
          upper triangular part of the array A contains the upper
          triangular matrix, and the strictly lower triangular part of
          A is not referenced.  If UPLO = 'L', the leading n by n lower
          triangular part of the array A contains the lower triangular
          matrix, and the strictly upper triangular part of A is not
          referenced.  If DIAG = 'U', the diagonal elements of A are
          also not referenced and are assumed to be 1.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in]SCALE
          SCALE is REAL
          The scaling factor s used in solving the triangular system.
[in]CNORM
          CNORM is REAL array, dimension (N)
          The 1-norms of the columns of A, not counting the diagonal.
[in]TSCAL
          TSCAL is REAL
          The scaling factor used in computing the 1-norms in CNORM.
          CNORM actually contains the column norms of TSCAL*A.
[in]X
          X is REAL array, dimension (LDX,NRHS)
          The computed solution vectors for the system of linear
          equations.
[in]LDX
          LDX is INTEGER
          The leading dimension of the array X.  LDX >= max(1,N).
[in]B
          B is REAL array, dimension (LDB,NRHS)
          The right hand side vectors for the system of linear
          equations.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]WORK
          WORK is REAL array, dimension (N)
[out]RESID
          RESID is REAL
          The maximum over the number of right hand sides of
          norm(op(A)*x - s*b) / ( norm(op(A)) * norm(x) * EPS ).
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 167 of file strt03.f.

169 *
170 * -- LAPACK test routine --
171 * -- LAPACK is a software package provided by Univ. of Tennessee, --
172 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
173 *
174 * .. Scalar Arguments ..
175  CHARACTER DIAG, TRANS, UPLO
176  INTEGER LDA, LDB, LDX, N, NRHS
177  REAL RESID, SCALE, TSCAL
178 * ..
179 * .. Array Arguments ..
180  REAL A( LDA, * ), B( LDB, * ), CNORM( * ),
181  $ WORK( * ), X( LDX, * )
182 * ..
183 *
184 * =====================================================================
185 *
186 * .. Parameters ..
187  REAL ONE, ZERO
188  parameter( one = 1.0e+0, zero = 0.0e+0 )
189 * ..
190 * .. Local Scalars ..
191  INTEGER IX, J
192  REAL BIGNUM, EPS, ERR, SMLNUM, TNORM, XNORM, XSCAL
193 * ..
194 * .. External Functions ..
195  LOGICAL LSAME
196  INTEGER ISAMAX
197  REAL SLAMCH
198  EXTERNAL lsame, isamax, slamch
199 * ..
200 * .. External Subroutines ..
201  EXTERNAL saxpy, scopy, slabad, sscal, strmv
202 * ..
203 * .. Intrinsic Functions ..
204  INTRINSIC abs, max, real
205 * ..
206 * .. Executable Statements ..
207 *
208 * Quick exit if N = 0
209 *
210  IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
211  resid = zero
212  RETURN
213  END IF
214  eps = slamch( 'Epsilon' )
215  smlnum = slamch( 'Safe minimum' )
216  bignum = one / smlnum
217  CALL slabad( smlnum, bignum )
218 *
219 * Compute the norm of the triangular matrix A using the column
220 * norms already computed by SLATRS.
221 *
222  tnorm = zero
223  IF( lsame( diag, 'N' ) ) THEN
224  DO 10 j = 1, n
225  tnorm = max( tnorm, tscal*abs( a( j, j ) )+cnorm( j ) )
226  10 CONTINUE
227  ELSE
228  DO 20 j = 1, n
229  tnorm = max( tnorm, tscal+cnorm( j ) )
230  20 CONTINUE
231  END IF
232 *
233 * Compute the maximum over the number of right hand sides of
234 * norm(op(A)*x - s*b) / ( norm(op(A)) * norm(x) * EPS ).
235 *
236  resid = zero
237  DO 30 j = 1, nrhs
238  CALL scopy( n, x( 1, j ), 1, work, 1 )
239  ix = isamax( n, work, 1 )
240  xnorm = max( one, abs( x( ix, j ) ) )
241  xscal = ( one / xnorm ) / real( n )
242  CALL sscal( n, xscal, work, 1 )
243  CALL strmv( uplo, trans, diag, n, a, lda, work, 1 )
244  CALL saxpy( n, -scale*xscal, b( 1, j ), 1, work, 1 )
245  ix = isamax( n, work, 1 )
246  err = tscal*abs( work( ix ) )
247  ix = isamax( n, x( 1, j ), 1 )
248  xnorm = abs( x( ix, j ) )
249  IF( err*smlnum.LE.xnorm ) THEN
250  IF( xnorm.GT.zero )
251  $ err = err / xnorm
252  ELSE
253  IF( err.GT.zero )
254  $ err = one / eps
255  END IF
256  IF( err*smlnum.LE.tnorm ) THEN
257  IF( tnorm.GT.zero )
258  $ err = err / tnorm
259  ELSE
260  IF( err.GT.zero )
261  $ err = one / eps
262  END IF
263  resid = max( resid, err )
264  30 CONTINUE
265 *
266  RETURN
267 *
268 * End of STRT03
269 *
subroutine slabad(SMALL, LARGE)
SLABAD
Definition: slabad.f:74
integer function isamax(N, SX, INCX)
ISAMAX
Definition: isamax.f:71
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine scopy(N, SX, INCX, SY, INCY)
SCOPY
Definition: scopy.f:82
subroutine sscal(N, SA, SX, INCX)
SSCAL
Definition: sscal.f:79
subroutine saxpy(N, SA, SX, INCX, SY, INCY)
SAXPY
Definition: saxpy.f:89
subroutine strmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
STRMV
Definition: strmv.f:147
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: