LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ sqrt01p()

subroutine sqrt01p ( integer  M,
integer  N,
real, dimension( lda, * )  A,
real, dimension( lda, * )  AF,
real, dimension( lda, * )  Q,
real, dimension( lda, * )  R,
integer  LDA,
real, dimension( * )  TAU,
real, dimension( lwork )  WORK,
integer  LWORK,
real, dimension( * )  RWORK,
real, dimension( * )  RESULT 
)

SQRT01P

Purpose:
 SQRT01P tests SGEQRFP, which computes the QR factorization of an m-by-n
 matrix A, and partially tests SORGQR which forms the m-by-m
 orthogonal matrix Q.

 SQRT01P compares R with Q'*A, and checks that Q is orthogonal.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.
[in]A
          A is REAL array, dimension (LDA,N)
          The m-by-n matrix A.
[out]AF
          AF is REAL array, dimension (LDA,N)
          Details of the QR factorization of A, as returned by SGEQRFP.
          See SGEQRFP for further details.
[out]Q
          Q is REAL array, dimension (LDA,M)
          The m-by-m orthogonal matrix Q.
[out]R
          R is REAL array, dimension (LDA,max(M,N))
[in]LDA
          LDA is INTEGER
          The leading dimension of the arrays A, AF, Q and R.
          LDA >= max(M,N).
[out]TAU
          TAU is REAL array, dimension (min(M,N))
          The scalar factors of the elementary reflectors, as returned
          by SGEQRFP.
[out]WORK
          WORK is REAL array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK.
[out]RWORK
          RWORK is REAL array, dimension (M)
[out]RESULT
          RESULT is REAL array, dimension (2)
          The test ratios:
          RESULT(1) = norm( R - Q'*A ) / ( M * norm(A) * EPS )
          RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 124 of file sqrt01p.f.

126 *
127 * -- LAPACK test routine --
128 * -- LAPACK is a software package provided by Univ. of Tennessee, --
129 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130 *
131 * .. Scalar Arguments ..
132  INTEGER LDA, LWORK, M, N
133 * ..
134 * .. Array Arguments ..
135  REAL A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
136  $ R( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
137  $ WORK( LWORK )
138 * ..
139 *
140 * =====================================================================
141 *
142 * .. Parameters ..
143  REAL ZERO, ONE
144  parameter( zero = 0.0e+0, one = 1.0e+0 )
145  REAL ROGUE
146  parameter( rogue = -1.0e+10 )
147 * ..
148 * .. Local Scalars ..
149  INTEGER INFO, MINMN
150  REAL ANORM, EPS, RESID
151 * ..
152 * .. External Functions ..
153  REAL SLAMCH, SLANGE, SLANSY
154  EXTERNAL slamch, slange, slansy
155 * ..
156 * .. External Subroutines ..
157  EXTERNAL sgemm, sgeqrfp, slacpy, slaset, sorgqr, ssyrk
158 * ..
159 * .. Intrinsic Functions ..
160  INTRINSIC max, min, real
161 * ..
162 * .. Scalars in Common ..
163  CHARACTER*32 SRNAMT
164 * ..
165 * .. Common blocks ..
166  COMMON / srnamc / srnamt
167 * ..
168 * .. Executable Statements ..
169 *
170  minmn = min( m, n )
171  eps = slamch( 'Epsilon' )
172 *
173 * Copy the matrix A to the array AF.
174 *
175  CALL slacpy( 'Full', m, n, a, lda, af, lda )
176 *
177 * Factorize the matrix A in the array AF.
178 *
179  srnamt = 'SGEQRFP'
180  CALL sgeqrfp( m, n, af, lda, tau, work, lwork, info )
181 *
182 * Copy details of Q
183 *
184  CALL slaset( 'Full', m, m, rogue, rogue, q, lda )
185  CALL slacpy( 'Lower', m-1, n, af( 2, 1 ), lda, q( 2, 1 ), lda )
186 *
187 * Generate the m-by-m matrix Q
188 *
189  srnamt = 'SORGQR'
190  CALL sorgqr( m, m, minmn, q, lda, tau, work, lwork, info )
191 *
192 * Copy R
193 *
194  CALL slaset( 'Full', m, n, zero, zero, r, lda )
195  CALL slacpy( 'Upper', m, n, af, lda, r, lda )
196 *
197 * Compute R - Q'*A
198 *
199  CALL sgemm( 'Transpose', 'No transpose', m, n, m, -one, q, lda, a,
200  $ lda, one, r, lda )
201 *
202 * Compute norm( R - Q'*A ) / ( M * norm(A) * EPS ) .
203 *
204  anorm = slange( '1', m, n, a, lda, rwork )
205  resid = slange( '1', m, n, r, lda, rwork )
206  IF( anorm.GT.zero ) THEN
207  result( 1 ) = ( ( resid / real( max( 1, m ) ) ) / anorm ) / eps
208  ELSE
209  result( 1 ) = zero
210  END IF
211 *
212 * Compute I - Q'*Q
213 *
214  CALL slaset( 'Full', m, m, zero, one, r, lda )
215  CALL ssyrk( 'Upper', 'Transpose', m, m, -one, q, lda, one, r,
216  $ lda )
217 *
218 * Compute norm( I - Q'*Q ) / ( M * EPS ) .
219 *
220  resid = slansy( '1', 'Upper', m, r, lda, rwork )
221 *
222  result( 2 ) = ( resid / real( max( 1, m ) ) ) / eps
223 *
224  RETURN
225 *
226 * End of SQRT01P
227 *
subroutine slaset(UPLO, M, N, ALPHA, BETA, A, LDA)
SLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: slaset.f:110
subroutine slacpy(UPLO, M, N, A, LDA, B, LDB)
SLACPY copies all or part of one two-dimensional array to another.
Definition: slacpy.f:103
real function slange(NORM, M, N, A, LDA, WORK)
SLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: slange.f:114
subroutine sgeqrfp(M, N, A, LDA, TAU, WORK, LWORK, INFO)
SGEQRFP
Definition: sgeqrfp.f:149
subroutine sorgqr(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
SORGQR
Definition: sorgqr.f:128
real function slansy(NORM, UPLO, N, A, LDA, WORK)
SLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: slansy.f:122
subroutine ssyrk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
SSYRK
Definition: ssyrk.f:169
subroutine sgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
SGEMM
Definition: sgemm.f:187
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: