LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
csyt01_3.f
Go to the documentation of this file.
1 *> \brief \b CSYT01_3
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 * Definition:
9 * ===========
10 *
11 * SUBROUTINE CSYT01_3( UPLO, N, A, LDA, AFAC, LDAFAC, E, IPIV, C,
12 * LDC, RWORK, RESID )
13 *
14 * .. Scalar Arguments ..
15 * CHARACTER UPLO
16 * INTEGER LDA, LDAFAC, LDC, N
17 * REAL RESID
18 * ..
19 * .. Array Arguments ..
20 * INTEGER IPIV( * )
21 * REAL RWORK( * )
22 * COMPLEX A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * ),
23 * E( * )
24 * ..
25 *
26 *
27 *> \par Purpose:
28 * =============
29 *>
30 *> \verbatim
31 *>
32 *> CSYT01_3 reconstructs a symmetric indefinite matrix A from its
33 *> block L*D*L' or U*D*U' factorization computed by CSYTRF_RK
34 *> (or CSYTRF_BK) and computes the residual
35 *> norm( C - A ) / ( N * norm(A) * EPS ),
36 *> where C is the reconstructed matrix and EPS is the machine epsilon.
37 *> \endverbatim
38 *
39 * Arguments:
40 * ==========
41 *
42 *> \param[in] UPLO
43 *> \verbatim
44 *> UPLO is CHARACTER*1
45 *> Specifies whether the upper or lower triangular part of the
46 *> symmetric matrix A is stored:
47 *> = 'U': Upper triangular
48 *> = 'L': Lower triangular
49 *> \endverbatim
50 *>
51 *> \param[in] N
52 *> \verbatim
53 *> N is INTEGER
54 *> The number of rows and columns of the matrix A. N >= 0.
55 *> \endverbatim
56 *>
57 *> \param[in] A
58 *> \verbatim
59 *> A is COMPLEX array, dimension (LDA,N)
60 *> The original symmetric matrix A.
61 *> \endverbatim
62 *>
63 *> \param[in] LDA
64 *> \verbatim
65 *> LDA is INTEGER
66 *> The leading dimension of the array A. LDA >= max(1,N)
67 *> \endverbatim
68 *>
69 *> \param[in] AFAC
70 *> \verbatim
71 *> AFAC is COMPLEX array, dimension (LDAFAC,N)
72 *> Diagonal of the block diagonal matrix D and factors U or L
73 *> as computed by CSYTRF_RK and CSYTRF_BK:
74 *> a) ONLY diagonal elements of the symmetric block diagonal
75 *> matrix D on the diagonal of A, i.e. D(k,k) = A(k,k);
76 *> (superdiagonal (or subdiagonal) elements of D
77 *> should be provided on entry in array E), and
78 *> b) If UPLO = 'U': factor U in the superdiagonal part of A.
79 *> If UPLO = 'L': factor L in the subdiagonal part of A.
80 *> \endverbatim
81 *>
82 *> \param[in] LDAFAC
83 *> \verbatim
84 *> LDAFAC is INTEGER
85 *> The leading dimension of the array AFAC.
86 *> LDAFAC >= max(1,N).
87 *> \endverbatim
88 *>
89 *> \param[in] E
90 *> \verbatim
91 *> E is COMPLEX array, dimension (N)
92 *> On entry, contains the superdiagonal (or subdiagonal)
93 *> elements of the symmetric block diagonal matrix D
94 *> with 1-by-1 or 2-by-2 diagonal blocks, where
95 *> If UPLO = 'U': E(i) = D(i-1,i),i=2:N, E(1) not referenced;
96 *> If UPLO = 'L': E(i) = D(i+1,i),i=1:N-1, E(N) not referenced.
97 *> \endverbatim
98 *>
99 *> \param[in] IPIV
100 *> \verbatim
101 *> IPIV is INTEGER array, dimension (N)
102 *> The pivot indices from CSYTRF_RK (or CSYTRF_BK).
103 *> \endverbatim
104 *>
105 *> \param[out] C
106 *> \verbatim
107 *> C is COMPLEX array, dimension (LDC,N)
108 *> \endverbatim
109 *>
110 *> \param[in] LDC
111 *> \verbatim
112 *> LDC is INTEGER
113 *> The leading dimension of the array C. LDC >= max(1,N).
114 *> \endverbatim
115 *>
116 *> \param[out] RWORK
117 *> \verbatim
118 *> RWORK is REAL array, dimension (N)
119 *> \endverbatim
120 *>
121 *> \param[out] RESID
122 *> \verbatim
123 *> RESID is REAL
124 *> If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS )
125 *> If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )
126 *> \endverbatim
127 *
128 * Authors:
129 * ========
130 *
131 *> \author Univ. of Tennessee
132 *> \author Univ. of California Berkeley
133 *> \author Univ. of Colorado Denver
134 *> \author NAG Ltd.
135 *
136 *> \ingroup complex_lin
137 *
138 * =====================================================================
139  SUBROUTINE csyt01_3( UPLO, N, A, LDA, AFAC, LDAFAC, E, IPIV, C,
140  $ LDC, RWORK, RESID )
141 *
142 * -- LAPACK test routine --
143 * -- LAPACK is a software package provided by Univ. of Tennessee, --
144 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
145 *
146 * .. Scalar Arguments ..
147  CHARACTER UPLO
148  INTEGER LDA, LDAFAC, LDC, N
149  REAL RESID
150 * ..
151 * .. Array Arguments ..
152  INTEGER IPIV( * )
153  REAL RWORK( * )
154  COMPLEX A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * ),
155  $ e( * )
156 * ..
157 *
158 * =====================================================================
159 *
160 * .. Parameters ..
161  REAL ZERO, ONE
162  parameter( zero = 0.0e+0, one = 1.0e+0 )
163  COMPLEX CZERO, CONE
164  parameter( czero = ( 0.0e+0, 0.0e+0 ),
165  $ cone = ( 1.0e+0, 0.0e+0 ) )
166 * ..
167 * .. Local Scalars ..
168  INTEGER I, INFO, J
169  REAL ANORM, EPS
170 * ..
171 * .. External Functions ..
172  LOGICAL LSAME
173  REAL SLAMCH, CLANSY
174  EXTERNAL lsame, slamch, clansy
175 * ..
176 * .. External Subroutines ..
177  EXTERNAL claset, clavsy_rook, csyconvf_rook
178 * ..
179 * .. Intrinsic Functions ..
180  INTRINSIC real
181 * ..
182 * .. Executable Statements ..
183 *
184 * Quick exit if N = 0.
185 *
186  IF( n.LE.0 ) THEN
187  resid = zero
188  RETURN
189  END IF
190 *
191 * a) Revert to multiplyers of L
192 *
193  CALL csyconvf_rook( uplo, 'R', n, afac, ldafac, e, ipiv, info )
194 *
195 * 1) Determine EPS and the norm of A.
196 *
197  eps = slamch( 'Epsilon' )
198  anorm = clansy( '1', uplo, n, a, lda, rwork )
199 *
200 * 2) Initialize C to the identity matrix.
201 *
202  CALL claset( 'Full', n, n, czero, cone, c, ldc )
203 *
204 * 3) Call ZLAVSY_ROOK to form the product D * U' (or D * L' ).
205 *
206  CALL clavsy_rook( uplo, 'Transpose', 'Non-unit', n, n, afac,
207  $ ldafac, ipiv, c, ldc, info )
208 *
209 * 4) Call ZLAVSY_ROOK again to multiply by U (or L ).
210 *
211  CALL clavsy_rook( uplo, 'No transpose', 'Unit', n, n, afac,
212  $ ldafac, ipiv, c, ldc, info )
213 *
214 * 5) Compute the difference C - A .
215 *
216  IF( lsame( uplo, 'U' ) ) THEN
217  DO j = 1, n
218  DO i = 1, j
219  c( i, j ) = c( i, j ) - a( i, j )
220  END DO
221  END DO
222  ELSE
223  DO j = 1, n
224  DO i = j, n
225  c( i, j ) = c( i, j ) - a( i, j )
226  END DO
227  END DO
228  END IF
229 *
230 * 6) Compute norm( C - A ) / ( N * norm(A) * EPS )
231 *
232  resid = clansy( '1', uplo, n, c, ldc, rwork )
233 *
234  IF( anorm.LE.zero ) THEN
235  IF( resid.NE.zero )
236  $ resid = one / eps
237  ELSE
238  resid = ( ( resid / real( n ) ) / anorm ) / eps
239  END IF
240 
241 *
242 * b) Convert to factor of L (or U)
243 *
244  CALL csyconvf_rook( uplo, 'C', n, afac, ldafac, e, ipiv, info )
245 *
246  RETURN
247 *
248 * End of CSYT01_3
249 *
250  END
subroutine csyt01_3(UPLO, N, A, LDA, AFAC, LDAFAC, E, IPIV, C, LDC, RWORK, RESID)
CSYT01_3
Definition: csyt01_3.f:141
subroutine clavsy_rook(UPLO, TRANS, DIAG, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
CLAVSY_ROOK
Definition: clavsy_rook.f:155
subroutine claset(UPLO, M, N, ALPHA, BETA, A, LDA)
CLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: claset.f:106
subroutine csyconvf_rook(UPLO, WAY, N, A, LDA, E, IPIV, INFO)
CSYCONVF_ROOK