LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ zsycon_3()

subroutine zsycon_3 ( character  UPLO,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( * )  E,
integer, dimension( * )  IPIV,
double precision  ANORM,
double precision  RCOND,
complex*16, dimension( * )  WORK,
integer  INFO 
)

ZSYCON_3

Download ZSYCON_3 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZSYCON_3 estimates the reciprocal of the condition number (in the
 1-norm) of a complex symmetric matrix A using the factorization
 computed by ZSYTRF_RK or ZSYTRF_BK:

    A = P*U*D*(U**T)*(P**T) or A = P*L*D*(L**T)*(P**T),

 where U (or L) is unit upper (or lower) triangular matrix,
 U**T (or L**T) is the transpose of U (or L), P is a permutation
 matrix, P**T is the transpose of P, and D is symmetric and block
 diagonal with 1-by-1 and 2-by-2 diagonal blocks.

 An estimate is obtained for norm(inv(A)), and the reciprocal of the
 condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
 This routine uses BLAS3 solver ZSYTRS_3.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the details of the factorization are
          stored as an upper or lower triangular matrix:
          = 'U':  Upper triangular, form is A = P*U*D*(U**T)*(P**T);
          = 'L':  Lower triangular, form is A = P*L*D*(L**T)*(P**T).
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
          Diagonal of the block diagonal matrix D and factors U or L
          as computed by ZSYTRF_RK and ZSYTRF_BK:
            a) ONLY diagonal elements of the symmetric block diagonal
               matrix D on the diagonal of A, i.e. D(k,k) = A(k,k);
               (superdiagonal (or subdiagonal) elements of D
                should be provided on entry in array E), and
            b) If UPLO = 'U': factor U in the superdiagonal part of A.
               If UPLO = 'L': factor L in the subdiagonal part of A.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in]E
          E is COMPLEX*16 array, dimension (N)
          On entry, contains the superdiagonal (or subdiagonal)
          elements of the symmetric block diagonal matrix D
          with 1-by-1 or 2-by-2 diagonal blocks, where
          If UPLO = 'U': E(i) = D(i-1,i),i=2:N, E(1) not referenced;
          If UPLO = 'L': E(i) = D(i+1,i),i=1:N-1, E(N) not referenced.

          NOTE: For 1-by-1 diagonal block D(k), where
          1 <= k <= N, the element E(k) is not referenced in both
          UPLO = 'U' or UPLO = 'L' cases.
[in]IPIV
          IPIV is INTEGER array, dimension (N)
          Details of the interchanges and the block structure of D
          as determined by ZSYTRF_RK or ZSYTRF_BK.
[in]ANORM
          ANORM is DOUBLE PRECISION
          The 1-norm of the original matrix A.
[out]RCOND
          RCOND is DOUBLE PRECISION
          The reciprocal of the condition number of the matrix A,
          computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
          estimate of the 1-norm of inv(A) computed in this routine.
[out]WORK
          WORK is COMPLEX*16 array, dimension (2*N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
  June 2017,  Igor Kozachenko,
                  Computer Science Division,
                  University of California, Berkeley

  September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
                  School of Mathematics,
                  University of Manchester

Definition at line 164 of file zsycon_3.f.

166 *
167 * -- LAPACK computational routine --
168 * -- LAPACK is a software package provided by Univ. of Tennessee, --
169 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
170 *
171 * .. Scalar Arguments ..
172  CHARACTER UPLO
173  INTEGER INFO, LDA, N
174  DOUBLE PRECISION ANORM, RCOND
175 * ..
176 * .. Array Arguments ..
177  INTEGER IPIV( * )
178  COMPLEX*16 A( LDA, * ), E( * ), WORK( * )
179 * ..
180 *
181 * =====================================================================
182 *
183 * .. Parameters ..
184  DOUBLE PRECISION ONE, ZERO
185  parameter( one = 1.0d+0, zero = 0.0d+0 )
186  COMPLEX*16 CZERO
187  parameter( czero = ( 0.0d+0, 0.0d+0 ) )
188 * ..
189 * .. Local Scalars ..
190  LOGICAL UPPER
191  INTEGER I, KASE
192  DOUBLE PRECISION AINVNM
193 * ..
194 * .. Local Arrays ..
195  INTEGER ISAVE( 3 )
196 * ..
197 * .. External Functions ..
198  LOGICAL LSAME
199  EXTERNAL lsame
200 * ..
201 * .. External Subroutines ..
202  EXTERNAL zlacn2, zsytrs_3, xerbla
203 * ..
204 * .. Intrinsic Functions ..
205  INTRINSIC max
206 * ..
207 * .. Executable Statements ..
208 *
209 * Test the input parameters.
210 *
211  info = 0
212  upper = lsame( uplo, 'U' )
213  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
214  info = -1
215  ELSE IF( n.LT.0 ) THEN
216  info = -2
217  ELSE IF( lda.LT.max( 1, n ) ) THEN
218  info = -4
219  ELSE IF( anorm.LT.zero ) THEN
220  info = -7
221  END IF
222  IF( info.NE.0 ) THEN
223  CALL xerbla( 'ZSYCON_3', -info )
224  RETURN
225  END IF
226 *
227 * Quick return if possible
228 *
229  rcond = zero
230  IF( n.EQ.0 ) THEN
231  rcond = one
232  RETURN
233  ELSE IF( anorm.LE.zero ) THEN
234  RETURN
235  END IF
236 *
237 * Check that the diagonal matrix D is nonsingular.
238 *
239  IF( upper ) THEN
240 *
241 * Upper triangular storage: examine D from bottom to top
242 *
243  DO i = n, 1, -1
244  IF( ipiv( i ).GT.0 .AND. a( i, i ).EQ.czero )
245  $ RETURN
246  END DO
247  ELSE
248 *
249 * Lower triangular storage: examine D from top to bottom.
250 *
251  DO i = 1, n
252  IF( ipiv( i ).GT.0 .AND. a( i, i ).EQ.czero )
253  $ RETURN
254  END DO
255  END IF
256 *
257 * Estimate the 1-norm of the inverse.
258 *
259  kase = 0
260  30 CONTINUE
261  CALL zlacn2( n, work( n+1 ), work, ainvnm, kase, isave )
262  IF( kase.NE.0 ) THEN
263 *
264 * Multiply by inv(L*D*L**T) or inv(U*D*U**T).
265 *
266  CALL zsytrs_3( uplo, n, 1, a, lda, e, ipiv, work, n, info )
267  GO TO 30
268  END IF
269 *
270 * Compute the estimate of the reciprocal condition number.
271 *
272  IF( ainvnm.NE.zero )
273  $ rcond = ( one / ainvnm ) / anorm
274 *
275  RETURN
276 *
277 * End of ZSYCON_3
278 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine zlacn2(N, V, X, EST, KASE, ISAVE)
ZLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: zlacn2.f:133
subroutine zsytrs_3(UPLO, N, NRHS, A, LDA, E, IPIV, B, LDB, INFO)
ZSYTRS_3
Definition: zsytrs_3.f:165
Here is the call graph for this function:
Here is the caller graph for this function: