cstt21.f

Go to the documentation of this file.

*> \brief \b CSTT21
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CSTT21( N, KBAND, AD, AE, SD, SE, U, LDU, WORK, RWORK,
*                          RESULT )
*
*       .. Scalar Arguments ..
*       INTEGER            KBAND, LDU, N
*       ..
*       .. Array Arguments ..
*       REAL               AD( * ), AE( * ), RESULT( 2 ), RWORK( * ),
*      $                   SD( * ), SE( * )
*       COMPLEX            U( LDU, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CSTT21  checks a decomposition of the form
*>
*>    A = U S U**H
*>
*> where **H means conjugate transpose, A is real symmetric tridiagonal,
*> U is unitary, and S is real and diagonal (if KBAND=0) or symmetric
*> tridiagonal (if KBAND=1).  Two tests are performed:
*>
*>    RESULT(1) = | A - U S U**H | / ( |A| n ulp )
*>
*>    RESULT(2) = | I - U U**H | / ( n ulp )
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The size of the matrix.  If it is zero, CSTT21 does nothing.
*>          It must be at least zero.
*> \endverbatim
*>
*> \param[in] KBAND
*> \verbatim
*>          KBAND is INTEGER
*>          The bandwidth of the matrix S.  It may only be zero or one.
*>          If zero, then S is diagonal, and SE is not referenced.  If
*>          one, then S is symmetric tri-diagonal.
*> \endverbatim
*>
*> \param[in] AD
*> \verbatim
*>          AD is REAL array, dimension (N)
*>          The diagonal of the original (unfactored) matrix A.  A is
*>          assumed to be real symmetric tridiagonal.
*> \endverbatim
*>
*> \param[in] AE
*> \verbatim
*>          AE is REAL array, dimension (N-1)
*>          The off-diagonal of the original (unfactored) matrix A.  A
*>          is assumed to be symmetric tridiagonal.  AE(1) is the (1,2)
*>          and (2,1) element, AE(2) is the (2,3) and (3,2) element, etc.
*> \endverbatim
*>
*> \param[in] SD
*> \verbatim
*>          SD is REAL array, dimension (N)
*>          The diagonal of the real (symmetric tri-) diagonal matrix S.
*> \endverbatim
*>
*> \param[in] SE
*> \verbatim
*>          SE is REAL array, dimension (N-1)
*>          The off-diagonal of the (symmetric tri-) diagonal matrix S.
*>          Not referenced if KBSND=0.  If KBAND=1, then AE(1) is the
*>          (1,2) and (2,1) element, SE(2) is the (2,3) and (3,2)
*>          element, etc.
*> \endverbatim
*>
*> \param[in] U
*> \verbatim
*>          U is COMPLEX array, dimension (LDU, N)
*>          The unitary matrix in the decomposition.
*> \endverbatim
*>
*> \param[in] LDU
*> \verbatim
*>          LDU is INTEGER
*>          The leading dimension of U.  LDU must be at least N.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (N**2)
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (N)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (2)
*>          The values computed by the two tests described above.  The
*>          values are currently limited to 1/ulp, to avoid overflow.
*>          RESULT(1) is always modified.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_eig
*
*  =====================================================================
      SUBROUTINE cstt21( N, KBAND, AD, AE, SD, SE, U, LDU, WORK, RWORK,
     $                   RESULT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            KBAND, LDU, N
*     ..
*     .. Array Arguments ..
      REAL               AD( * ), AE( * ), RESULT( 2 ), RWORK( * ),
     $                   sd( * ), se( * )
      COMPLEX            U( LDU, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            J
      REAL               ANORM, TEMP1, TEMP2, ULP, UNFL, WNORM
*     ..
*     .. External Functions ..
      REAL               CLANGE, CLANHE, SLAMCH
      EXTERNAL           clange, clanhe, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cher, cher2, claset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, cmplx, max, min, real
*     ..
*     .. Executable Statements ..
*
*     1)      Constants
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 )
     $   RETURN
*
      unfl = slamch( 'Safe minimum' )
      ulp = slamch( 'Precision' )
*
*     Do Test 1
*
*     Copy A & Compute its 1-Norm:
*
      CALL claset( 'Full', n, n, czero, czero, work, n )
*
      anorm = zero
      temp1 = zero
*
      DO 10 j = 1, n - 1
         work( ( n+1 )*( j-1 )+1 ) = ad( j )
         work( ( n+1 )*( j-1 )+2 ) = ae( j )
         temp2 = abs( ae( j ) )
         anorm = max( anorm, abs( ad( j ) )+temp1+temp2 )
         temp1 = temp2
   10 CONTINUE
*
      work( n**2 ) = ad( n )
      anorm = max( anorm, abs( ad( n ) )+temp1, unfl )
*
*     Norm of A - U S U**H
*
      DO 20 j = 1, n
         CALL cher( 'L', n, -sd( j ), u( 1, j ), 1, work, n )
   20 CONTINUE
*
      IF( n.GT.1 .AND. kband.EQ.1 ) THEN
         DO 30 j = 1, n - 1
            CALL cher2( 'L', n, -cmplx( se( j ) ), u( 1, j ), 1,
     $                  u( 1, j+1 ), 1, work, n )
   30    CONTINUE
      END IF
*
      wnorm = clanhe( '1', 'L', n, work, n, rwork )
*
      IF( anorm.GT.wnorm ) THEN
         result( 1 ) = ( wnorm / anorm ) / ( n*ulp )
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( wnorm, n*anorm ) / anorm ) / ( n*ulp )
         ELSE
            result( 1 ) = min( wnorm / anorm, real( n ) ) / ( n*ulp )
         END IF
      END IF
*
*     Do Test 2
*
*     Compute  U U**H - I
*
      CALL cgemm( 'N', 'C', n, n, n, cone, u, ldu, u, ldu, czero, work,
     $            n )
*
      DO 40 j = 1, n
         work( ( n+1 )*( j-1 )+1 ) = work( ( n+1 )*( j-1 )+1 ) - cone
   40 CONTINUE
*
      result( 2 ) = min( real( n ), clange( '1', n, n, work, n,
     $              rwork ) ) / ( n*ulp )
*
      RETURN
*
*     End of CSTT21
*
      END