LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
sgbsvx.f
Go to the documentation of this file.
1*> \brief <b> SGBSVX computes the solution to system of linear equations A * X = B for GB matrices</b>
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sgbsvx.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sgbsvx.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sgbsvx.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE SGBSVX( FACT, TRANS, N, KL, KU, NRHS, AB, LDAB, AFB,
22* LDAFB, IPIV, EQUED, R, C, B, LDB, X, LDX,
23* RCOND, FERR, BERR, WORK, IWORK, INFO )
24*
25* .. Scalar Arguments ..
26* CHARACTER EQUED, FACT, TRANS
27* INTEGER INFO, KL, KU, LDAB, LDAFB, LDB, LDX, N, NRHS
28* REAL RCOND
29* ..
30* .. Array Arguments ..
31* INTEGER IPIV( * ), IWORK( * )
32* REAL AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
33* \$ BERR( * ), C( * ), FERR( * ), R( * ),
34* \$ WORK( * ), X( LDX, * )
35* ..
36*
37*
38*> \par Purpose:
39* =============
40*>
41*> \verbatim
42*>
43*> SGBSVX uses the LU factorization to compute the solution to a real
44*> system of linear equations A * X = B, A**T * X = B, or A**H * X = B,
45*> where A is a band matrix of order N with KL subdiagonals and KU
46*> superdiagonals, and X and B are N-by-NRHS matrices.
47*>
48*> Error bounds on the solution and a condition estimate are also
49*> provided.
50*> \endverbatim
51*
52*> \par Description:
53* =================
54*>
55*> \verbatim
56*>
57*> The following steps are performed by this subroutine:
58*>
59*> 1. If FACT = 'E', real scaling factors are computed to equilibrate
60*> the system:
61*> TRANS = 'N': diag(R)*A*diag(C) *inv(diag(C))*X = diag(R)*B
62*> TRANS = 'T': (diag(R)*A*diag(C))**T *inv(diag(R))*X = diag(C)*B
63*> TRANS = 'C': (diag(R)*A*diag(C))**H *inv(diag(R))*X = diag(C)*B
64*> Whether or not the system will be equilibrated depends on the
65*> scaling of the matrix A, but if equilibration is used, A is
66*> overwritten by diag(R)*A*diag(C) and B by diag(R)*B (if TRANS='N')
67*> or diag(C)*B (if TRANS = 'T' or 'C').
68*>
69*> 2. If FACT = 'N' or 'E', the LU decomposition is used to factor the
70*> matrix A (after equilibration if FACT = 'E') as
71*> A = L * U,
72*> where L is a product of permutation and unit lower triangular
73*> matrices with KL subdiagonals, and U is upper triangular with
74*> KL+KU superdiagonals.
75*>
76*> 3. If some U(i,i)=0, so that U is exactly singular, then the routine
77*> returns with INFO = i. Otherwise, the factored form of A is used
78*> to estimate the condition number of the matrix A. If the
79*> reciprocal of the condition number is less than machine precision,
80*> INFO = N+1 is returned as a warning, but the routine still goes on
81*> to solve for X and compute error bounds as described below.
82*>
83*> 4. The system of equations is solved for X using the factored form
84*> of A.
85*>
86*> 5. Iterative refinement is applied to improve the computed solution
87*> matrix and calculate error bounds and backward error estimates
88*> for it.
89*>
90*> 6. If equilibration was used, the matrix X is premultiplied by
91*> diag(C) (if TRANS = 'N') or diag(R) (if TRANS = 'T' or 'C') so
92*> that it solves the original system before equilibration.
93*> \endverbatim
94*
95* Arguments:
96* ==========
97*
98*> \param[in] FACT
99*> \verbatim
100*> FACT is CHARACTER*1
101*> Specifies whether or not the factored form of the matrix A is
102*> supplied on entry, and if not, whether the matrix A should be
103*> equilibrated before it is factored.
104*> = 'F': On entry, AFB and IPIV contain the factored form of
105*> A. If EQUED is not 'N', the matrix A has been
106*> equilibrated with scaling factors given by R and C.
107*> AB, AFB, and IPIV are not modified.
108*> = 'N': The matrix A will be copied to AFB and factored.
109*> = 'E': The matrix A will be equilibrated if necessary, then
110*> copied to AFB and factored.
111*> \endverbatim
112*>
113*> \param[in] TRANS
114*> \verbatim
115*> TRANS is CHARACTER*1
116*> Specifies the form of the system of equations.
117*> = 'N': A * X = B (No transpose)
118*> = 'T': A**T * X = B (Transpose)
119*> = 'C': A**H * X = B (Transpose)
120*> \endverbatim
121*>
122*> \param[in] N
123*> \verbatim
124*> N is INTEGER
125*> The number of linear equations, i.e., the order of the
126*> matrix A. N >= 0.
127*> \endverbatim
128*>
129*> \param[in] KL
130*> \verbatim
131*> KL is INTEGER
132*> The number of subdiagonals within the band of A. KL >= 0.
133*> \endverbatim
134*>
135*> \param[in] KU
136*> \verbatim
137*> KU is INTEGER
138*> The number of superdiagonals within the band of A. KU >= 0.
139*> \endverbatim
140*>
141*> \param[in] NRHS
142*> \verbatim
143*> NRHS is INTEGER
144*> The number of right hand sides, i.e., the number of columns
145*> of the matrices B and X. NRHS >= 0.
146*> \endverbatim
147*>
148*> \param[in,out] AB
149*> \verbatim
150*> AB is REAL array, dimension (LDAB,N)
151*> On entry, the matrix A in band storage, in rows 1 to KL+KU+1.
152*> The j-th column of A is stored in the j-th column of the
153*> array AB as follows:
154*> AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)
155*>
156*> If FACT = 'F' and EQUED is not 'N', then A must have been
157*> equilibrated by the scaling factors in R and/or C. AB is not
158*> modified if FACT = 'F' or 'N', or if FACT = 'E' and
159*> EQUED = 'N' on exit.
160*>
161*> On exit, if EQUED .ne. 'N', A is scaled as follows:
162*> EQUED = 'R': A := diag(R) * A
163*> EQUED = 'C': A := A * diag(C)
164*> EQUED = 'B': A := diag(R) * A * diag(C).
165*> \endverbatim
166*>
167*> \param[in] LDAB
168*> \verbatim
169*> LDAB is INTEGER
170*> The leading dimension of the array AB. LDAB >= KL+KU+1.
171*> \endverbatim
172*>
173*> \param[in,out] AFB
174*> \verbatim
175*> AFB is REAL array, dimension (LDAFB,N)
176*> If FACT = 'F', then AFB is an input argument and on entry
177*> contains details of the LU factorization of the band matrix
178*> A, as computed by SGBTRF. U is stored as an upper triangular
179*> band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1,
180*> and the multipliers used during the factorization are stored
181*> in rows KL+KU+2 to 2*KL+KU+1. If EQUED .ne. 'N', then AFB is
182*> the factored form of the equilibrated matrix A.
183*>
184*> If FACT = 'N', then AFB is an output argument and on exit
185*> returns details of the LU factorization of A.
186*>
187*> If FACT = 'E', then AFB is an output argument and on exit
188*> returns details of the LU factorization of the equilibrated
189*> matrix A (see the description of AB for the form of the
190*> equilibrated matrix).
191*> \endverbatim
192*>
193*> \param[in] LDAFB
194*> \verbatim
195*> LDAFB is INTEGER
196*> The leading dimension of the array AFB. LDAFB >= 2*KL+KU+1.
197*> \endverbatim
198*>
199*> \param[in,out] IPIV
200*> \verbatim
201*> IPIV is INTEGER array, dimension (N)
202*> If FACT = 'F', then IPIV is an input argument and on entry
203*> contains the pivot indices from the factorization A = L*U
204*> as computed by SGBTRF; row i of the matrix was interchanged
205*> with row IPIV(i).
206*>
207*> If FACT = 'N', then IPIV is an output argument and on exit
208*> contains the pivot indices from the factorization A = L*U
209*> of the original matrix A.
210*>
211*> If FACT = 'E', then IPIV is an output argument and on exit
212*> contains the pivot indices from the factorization A = L*U
213*> of the equilibrated matrix A.
214*> \endverbatim
215*>
216*> \param[in,out] EQUED
217*> \verbatim
218*> EQUED is CHARACTER*1
219*> Specifies the form of equilibration that was done.
220*> = 'N': No equilibration (always true if FACT = 'N').
221*> = 'R': Row equilibration, i.e., A has been premultiplied by
222*> diag(R).
223*> = 'C': Column equilibration, i.e., A has been postmultiplied
224*> by diag(C).
225*> = 'B': Both row and column equilibration, i.e., A has been
226*> replaced by diag(R) * A * diag(C).
227*> EQUED is an input argument if FACT = 'F'; otherwise, it is an
228*> output argument.
229*> \endverbatim
230*>
231*> \param[in,out] R
232*> \verbatim
233*> R is REAL array, dimension (N)
234*> The row scale factors for A. If EQUED = 'R' or 'B', A is
235*> multiplied on the left by diag(R); if EQUED = 'N' or 'C', R
236*> is not accessed. R is an input argument if FACT = 'F';
237*> otherwise, R is an output argument. If FACT = 'F' and
238*> EQUED = 'R' or 'B', each element of R must be positive.
239*> \endverbatim
240*>
241*> \param[in,out] C
242*> \verbatim
243*> C is REAL array, dimension (N)
244*> The column scale factors for A. If EQUED = 'C' or 'B', A is
245*> multiplied on the right by diag(C); if EQUED = 'N' or 'R', C
246*> is not accessed. C is an input argument if FACT = 'F';
247*> otherwise, C is an output argument. If FACT = 'F' and
248*> EQUED = 'C' or 'B', each element of C must be positive.
249*> \endverbatim
250*>
251*> \param[in,out] B
252*> \verbatim
253*> B is REAL array, dimension (LDB,NRHS)
254*> On entry, the right hand side matrix B.
255*> On exit,
256*> if EQUED = 'N', B is not modified;
257*> if TRANS = 'N' and EQUED = 'R' or 'B', B is overwritten by
258*> diag(R)*B;
259*> if TRANS = 'T' or 'C' and EQUED = 'C' or 'B', B is
260*> overwritten by diag(C)*B.
261*> \endverbatim
262*>
263*> \param[in] LDB
264*> \verbatim
265*> LDB is INTEGER
266*> The leading dimension of the array B. LDB >= max(1,N).
267*> \endverbatim
268*>
269*> \param[out] X
270*> \verbatim
271*> X is REAL array, dimension (LDX,NRHS)
272*> If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X
273*> to the original system of equations. Note that A and B are
274*> modified on exit if EQUED .ne. 'N', and the solution to the
275*> equilibrated system is inv(diag(C))*X if TRANS = 'N' and
276*> EQUED = 'C' or 'B', or inv(diag(R))*X if TRANS = 'T' or 'C'
277*> and EQUED = 'R' or 'B'.
278*> \endverbatim
279*>
280*> \param[in] LDX
281*> \verbatim
282*> LDX is INTEGER
283*> The leading dimension of the array X. LDX >= max(1,N).
284*> \endverbatim
285*>
286*> \param[out] RCOND
287*> \verbatim
288*> RCOND is REAL
289*> The estimate of the reciprocal condition number of the matrix
290*> A after equilibration (if done). If RCOND is less than the
291*> machine precision (in particular, if RCOND = 0), the matrix
292*> is singular to working precision. This condition is
293*> indicated by a return code of INFO > 0.
294*> \endverbatim
295*>
296*> \param[out] FERR
297*> \verbatim
298*> FERR is REAL array, dimension (NRHS)
299*> The estimated forward error bound for each solution vector
300*> X(j) (the j-th column of the solution matrix X).
301*> If XTRUE is the true solution corresponding to X(j), FERR(j)
302*> is an estimated upper bound for the magnitude of the largest
303*> element in (X(j) - XTRUE) divided by the magnitude of the
304*> largest element in X(j). The estimate is as reliable as
305*> the estimate for RCOND, and is almost always a slight
306*> overestimate of the true error.
307*> \endverbatim
308*>
309*> \param[out] BERR
310*> \verbatim
311*> BERR is REAL array, dimension (NRHS)
312*> The componentwise relative backward error of each solution
313*> vector X(j) (i.e., the smallest relative change in
314*> any element of A or B that makes X(j) an exact solution).
315*> \endverbatim
316*>
317*> \param[out] WORK
318*> \verbatim
319*> WORK is REAL array, dimension (MAX(1,3*N))
320*> On exit, WORK(1) contains the reciprocal pivot growth
321*> factor norm(A)/norm(U). The "max absolute element" norm is
322*> used. If WORK(1) is much less than 1, then the stability
323*> of the LU factorization of the (equilibrated) matrix A
324*> could be poor. This also means that the solution X, condition
325*> estimator RCOND, and forward error bound FERR could be
326*> unreliable. If factorization fails with 0<INFO<=N, then
327*> WORK(1) contains the reciprocal pivot growth factor for the
328*> leading INFO columns of A.
329*> \endverbatim
330*>
331*> \param[out] IWORK
332*> \verbatim
333*> IWORK is INTEGER array, dimension (N)
334*> \endverbatim
335*>
336*> \param[out] INFO
337*> \verbatim
338*> INFO is INTEGER
339*> = 0: successful exit
340*> < 0: if INFO = -i, the i-th argument had an illegal value
341*> > 0: if INFO = i, and i is
342*> <= N: U(i,i) is exactly zero. The factorization
343*> has been completed, but the factor U is exactly
344*> singular, so the solution and error bounds
345*> could not be computed. RCOND = 0 is returned.
346*> = N+1: U is nonsingular, but RCOND is less than machine
347*> precision, meaning that the matrix is singular
348*> to working precision. Nevertheless, the
349*> solution and error bounds are computed because
350*> there are a number of situations where the
351*> computed solution can be more accurate than the
352*> \endverbatim
353*
354* Authors:
355* ========
356*
357*> \author Univ. of Tennessee
358*> \author Univ. of California Berkeley
359*> \author Univ. of Colorado Denver
360*> \author NAG Ltd.
361*
362*> \ingroup gbsvx
363*
364* =====================================================================
365 SUBROUTINE sgbsvx( FACT, TRANS, N, KL, KU, NRHS, AB, LDAB, AFB,
366 \$ LDAFB, IPIV, EQUED, R, C, B, LDB, X, LDX,
367 \$ RCOND, FERR, BERR, WORK, IWORK, INFO )
368*
369* -- LAPACK driver routine --
370* -- LAPACK is a software package provided by Univ. of Tennessee, --
371* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
372*
373* .. Scalar Arguments ..
374 CHARACTER EQUED, FACT, TRANS
375 INTEGER INFO, KL, KU, LDAB, LDAFB, LDB, LDX, N, NRHS
376 REAL RCOND
377* ..
378* .. Array Arguments ..
379 INTEGER IPIV( * ), IWORK( * )
380 REAL AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
381 \$ berr( * ), c( * ), ferr( * ), r( * ),
382 \$ work( * ), x( ldx, * )
383* ..
384*
385* =====================================================================
386* Moved setting of INFO = N+1 so INFO does not subsequently get
387* overwritten. Sven, 17 Mar 05.
388* =====================================================================
389*
390* .. Parameters ..
391 REAL ZERO, ONE
392 PARAMETER ( ZERO = 0.0e+0, one = 1.0e+0 )
393* ..
394* .. Local Scalars ..
395 LOGICAL COLEQU, EQUIL, NOFACT, NOTRAN, ROWEQU
396 CHARACTER NORM
397 INTEGER I, INFEQU, J, J1, J2
398 REAL AMAX, ANORM, BIGNUM, COLCND, RCMAX, RCMIN,
399 \$ rowcnd, rpvgrw, smlnum
400* ..
401* .. External Functions ..
402 LOGICAL LSAME
403 REAL SLAMCH, SLANGB, SLANTB
404 EXTERNAL lsame, slamch, slangb, slantb
405* ..
406* .. External Subroutines ..
407 EXTERNAL scopy, sgbcon, sgbequ, sgbrfs, sgbtrf, sgbtrs,
409* ..
410* .. Intrinsic Functions ..
411 INTRINSIC abs, max, min
412* ..
413* .. Executable Statements ..
414*
415 info = 0
416 nofact = lsame( fact, 'N' )
417 equil = lsame( fact, 'E' )
418 notran = lsame( trans, 'N' )
419 IF( nofact .OR. equil ) THEN
420 equed = 'N'
421 rowequ = .false.
422 colequ = .false.
423 ELSE
424 rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
425 colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
426 smlnum = slamch( 'Safe minimum' )
427 bignum = one / smlnum
428 END IF
429*
430* Test the input parameters.
431*
432 IF( .NOT.nofact .AND. .NOT.equil .AND. .NOT.lsame( fact, 'F' ) )
433 \$ THEN
434 info = -1
435 ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
436 \$ lsame( trans, 'C' ) ) THEN
437 info = -2
438 ELSE IF( n.LT.0 ) THEN
439 info = -3
440 ELSE IF( kl.LT.0 ) THEN
441 info = -4
442 ELSE IF( ku.LT.0 ) THEN
443 info = -5
444 ELSE IF( nrhs.LT.0 ) THEN
445 info = -6
446 ELSE IF( ldab.LT.kl+ku+1 ) THEN
447 info = -8
448 ELSE IF( ldafb.LT.2*kl+ku+1 ) THEN
449 info = -10
450 ELSE IF( lsame( fact, 'F' ) .AND. .NOT.
451 \$ ( rowequ .OR. colequ .OR. lsame( equed, 'N' ) ) ) THEN
452 info = -12
453 ELSE
454 IF( rowequ ) THEN
455 rcmin = bignum
456 rcmax = zero
457 DO 10 j = 1, n
458 rcmin = min( rcmin, r( j ) )
459 rcmax = max( rcmax, r( j ) )
460 10 CONTINUE
461 IF( rcmin.LE.zero ) THEN
462 info = -13
463 ELSE IF( n.GT.0 ) THEN
464 rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
465 ELSE
466 rowcnd = one
467 END IF
468 END IF
469 IF( colequ .AND. info.EQ.0 ) THEN
470 rcmin = bignum
471 rcmax = zero
472 DO 20 j = 1, n
473 rcmin = min( rcmin, c( j ) )
474 rcmax = max( rcmax, c( j ) )
475 20 CONTINUE
476 IF( rcmin.LE.zero ) THEN
477 info = -14
478 ELSE IF( n.GT.0 ) THEN
479 colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
480 ELSE
481 colcnd = one
482 END IF
483 END IF
484 IF( info.EQ.0 ) THEN
485 IF( ldb.LT.max( 1, n ) ) THEN
486 info = -16
487 ELSE IF( ldx.LT.max( 1, n ) ) THEN
488 info = -18
489 END IF
490 END IF
491 END IF
492*
493 IF( info.NE.0 ) THEN
494 CALL xerbla( 'SGBSVX', -info )
495 RETURN
496 END IF
497*
498 IF( equil ) THEN
499*
500* Compute row and column scalings to equilibrate the matrix A.
501*
502 CALL sgbequ( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
503 \$ amax, infequ )
504 IF( infequ.EQ.0 ) THEN
505*
506* Equilibrate the matrix.
507*
508 CALL slaqgb( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
509 \$ amax, equed )
510 rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
511 colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
512 END IF
513 END IF
514*
515* Scale the right hand side.
516*
517 IF( notran ) THEN
518 IF( rowequ ) THEN
519 DO 40 j = 1, nrhs
520 DO 30 i = 1, n
521 b( i, j ) = r( i )*b( i, j )
522 30 CONTINUE
523 40 CONTINUE
524 END IF
525 ELSE IF( colequ ) THEN
526 DO 60 j = 1, nrhs
527 DO 50 i = 1, n
528 b( i, j ) = c( i )*b( i, j )
529 50 CONTINUE
530 60 CONTINUE
531 END IF
532*
533 IF( nofact .OR. equil ) THEN
534*
535* Compute the LU factorization of the band matrix A.
536*
537 DO 70 j = 1, n
538 j1 = max( j-ku, 1 )
539 j2 = min( j+kl, n )
540 CALL scopy( j2-j1+1, ab( ku+1-j+j1, j ), 1,
541 \$ afb( kl+ku+1-j+j1, j ), 1 )
542 70 CONTINUE
543*
544 CALL sgbtrf( n, n, kl, ku, afb, ldafb, ipiv, info )
545*
546* Return if INFO is non-zero.
547*
548 IF( info.GT.0 ) THEN
549*
550* Compute the reciprocal pivot growth factor of the
551* leading rank-deficient INFO columns of A.
552*
553 anorm = zero
554 DO 90 j = 1, info
555 DO 80 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
556 anorm = max( anorm, abs( ab( i, j ) ) )
557 80 CONTINUE
558 90 CONTINUE
559 rpvgrw = slantb( 'M', 'U', 'N', info, min( info-1, kl+ku ),
560 \$ afb( max( 1, kl+ku+2-info ), 1 ), ldafb,
561 \$ work )
562 IF( rpvgrw.EQ.zero ) THEN
563 rpvgrw = one
564 ELSE
565 rpvgrw = anorm / rpvgrw
566 END IF
567 work( 1 ) = rpvgrw
568 rcond = zero
569 RETURN
570 END IF
571 END IF
572*
573* Compute the norm of the matrix A and the
574* reciprocal pivot growth factor RPVGRW.
575*
576 IF( notran ) THEN
577 norm = '1'
578 ELSE
579 norm = 'I'
580 END IF
581 anorm = slangb( norm, n, kl, ku, ab, ldab, work )
582 rpvgrw = slantb( 'M', 'U', 'N', n, kl+ku, afb, ldafb, work )
583 IF( rpvgrw.EQ.zero ) THEN
584 rpvgrw = one
585 ELSE
586 rpvgrw = slangb( 'M', n, kl, ku, ab, ldab, work ) / rpvgrw
587 END IF
588*
589* Compute the reciprocal of the condition number of A.
590*
591 CALL sgbcon( norm, n, kl, ku, afb, ldafb, ipiv, anorm, rcond,
592 \$ work, iwork, info )
593*
594* Compute the solution matrix X.
595*
596 CALL slacpy( 'Full', n, nrhs, b, ldb, x, ldx )
597 CALL sgbtrs( trans, n, kl, ku, nrhs, afb, ldafb, ipiv, x, ldx,
598 \$ info )
599*
600* Use iterative refinement to improve the computed solution and
601* compute error bounds and backward error estimates for it.
602*
603 CALL sgbrfs( trans, n, kl, ku, nrhs, ab, ldab, afb, ldafb, ipiv,
604 \$ b, ldb, x, ldx, ferr, berr, work, iwork, info )
605*
606* Transform the solution matrix X to a solution of the original
607* system.
608*
609 IF( notran ) THEN
610 IF( colequ ) THEN
611 DO 110 j = 1, nrhs
612 DO 100 i = 1, n
613 x( i, j ) = c( i )*x( i, j )
614 100 CONTINUE
615 110 CONTINUE
616 DO 120 j = 1, nrhs
617 ferr( j ) = ferr( j ) / colcnd
618 120 CONTINUE
619 END IF
620 ELSE IF( rowequ ) THEN
621 DO 140 j = 1, nrhs
622 DO 130 i = 1, n
623 x( i, j ) = r( i )*x( i, j )
624 130 CONTINUE
625 140 CONTINUE
626 DO 150 j = 1, nrhs
627 ferr( j ) = ferr( j ) / rowcnd
628 150 CONTINUE
629 END IF
630*
631* Set INFO = N+1 if the matrix is singular to working precision.
632*
633 IF( rcond.LT.slamch( 'Epsilon' ) )
634 \$ info = n + 1
635*
636 work( 1 ) = rpvgrw
637 RETURN
638*
639* End of SGBSVX
640*
641 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine scopy(n, sx, incx, sy, incy)
SCOPY
Definition scopy.f:82
subroutine sgbcon(norm, n, kl, ku, ab, ldab, ipiv, anorm, rcond, work, iwork, info)
SGBCON
Definition sgbcon.f:146
subroutine sgbequ(m, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd, amax, info)
SGBEQU
Definition sgbequ.f:153
subroutine sgbrfs(trans, n, kl, ku, nrhs, ab, ldab, afb, ldafb, ipiv, b, ldb, x, ldx, ferr, berr, work, iwork, info)
SGBRFS
Definition sgbrfs.f:205
subroutine sgbsvx(fact, trans, n, kl, ku, nrhs, ab, ldab, afb, ldafb, ipiv, equed, r, c, b, ldb, x, ldx, rcond, ferr, berr, work, iwork, info)
SGBSVX computes the solution to system of linear equations A * X = B for GB matrices
Definition sgbsvx.f:368
subroutine sgbtrf(m, n, kl, ku, ab, ldab, ipiv, info)
SGBTRF
Definition sgbtrf.f:144
subroutine sgbtrs(trans, n, kl, ku, nrhs, ab, ldab, ipiv, b, ldb, info)
SGBTRS
Definition sgbtrs.f:138
subroutine slacpy(uplo, m, n, a, lda, b, ldb)
SLACPY copies all or part of one two-dimensional array to another.
Definition slacpy.f:103
subroutine slaqgb(m, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd, amax, equed)
SLAQGB scales a general band matrix, using row and column scaling factors computed by sgbequ.
Definition slaqgb.f:159