LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ zlangb()

double precision function zlangb ( character  NORM,
integer  N,
integer  KL,
integer  KU,
complex*16, dimension( ldab, * )  AB,
integer  LDAB,
double precision, dimension( * )  WORK 
)

ZLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of general band matrix.

Download ZLANGB + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLANGB  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the element of  largest absolute value  of an
 n by n band matrix  A,  with kl sub-diagonals and ku super-diagonals.
Returns
ZLANGB
    ZLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in ZLANGB as described
          above.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, ZLANGB is
          set to zero.
[in]KL
          KL is INTEGER
          The number of sub-diagonals of the matrix A.  KL >= 0.
[in]KU
          KU is INTEGER
          The number of super-diagonals of the matrix A.  KU >= 0.
[in]AB
          AB is COMPLEX*16 array, dimension (LDAB,N)
          The band matrix A, stored in rows 1 to KL+KU+1.  The j-th
          column of A is stored in the j-th column of the array AB as
          follows:
          AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
[in]LDAB
          LDAB is INTEGER
          The leading dimension of the array AB.  LDAB >= KL+KU+1.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I'; otherwise, WORK is not
          referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 123 of file zlangb.f.

125 *
126 * -- LAPACK auxiliary routine --
127 * -- LAPACK is a software package provided by Univ. of Tennessee, --
128 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
129 *
130  IMPLICIT NONE
131 * .. Scalar Arguments ..
132  CHARACTER NORM
133  INTEGER KL, KU, LDAB, N
134 * ..
135 * .. Array Arguments ..
136  DOUBLE PRECISION WORK( * )
137  COMPLEX*16 AB( LDAB, * )
138 * ..
139 *
140 * =====================================================================
141 *
142 * .. Parameters ..
143  DOUBLE PRECISION ONE, ZERO
144  parameter( one = 1.0d+0, zero = 0.0d+0 )
145 * ..
146 * .. Local Scalars ..
147  INTEGER I, J, K, L
148  DOUBLE PRECISION SUM, VALUE, TEMP
149 * ..
150 * .. Local Arrays ..
151  DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
152 * ..
153 * .. External Functions ..
154  LOGICAL LSAME, DISNAN
155  EXTERNAL lsame, disnan
156 * ..
157 * .. External Subroutines ..
158  EXTERNAL zlassq, dcombssq
159 * ..
160 * .. Intrinsic Functions ..
161  INTRINSIC abs, max, min, sqrt
162 * ..
163 * .. Executable Statements ..
164 *
165  IF( n.EQ.0 ) THEN
166  VALUE = zero
167  ELSE IF( lsame( norm, 'M' ) ) THEN
168 *
169 * Find max(abs(A(i,j))).
170 *
171  VALUE = zero
172  DO 20 j = 1, n
173  DO 10 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
174  temp = abs( ab( i, j ) )
175  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
176  10 CONTINUE
177  20 CONTINUE
178  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
179 *
180 * Find norm1(A).
181 *
182  VALUE = zero
183  DO 40 j = 1, n
184  sum = zero
185  DO 30 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
186  sum = sum + abs( ab( i, j ) )
187  30 CONTINUE
188  IF( VALUE.LT.sum .OR. disnan( sum ) ) VALUE = sum
189  40 CONTINUE
190  ELSE IF( lsame( norm, 'I' ) ) THEN
191 *
192 * Find normI(A).
193 *
194  DO 50 i = 1, n
195  work( i ) = zero
196  50 CONTINUE
197  DO 70 j = 1, n
198  k = ku + 1 - j
199  DO 60 i = max( 1, j-ku ), min( n, j+kl )
200  work( i ) = work( i ) + abs( ab( k+i, j ) )
201  60 CONTINUE
202  70 CONTINUE
203  VALUE = zero
204  DO 80 i = 1, n
205  temp = work( i )
206  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
207  80 CONTINUE
208  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
209 *
210 * Find normF(A).
211 * SSQ(1) is scale
212 * SSQ(2) is sum-of-squares
213 * For better accuracy, sum each column separately.
214 *
215  ssq( 1 ) = zero
216  ssq( 2 ) = one
217  DO 90 j = 1, n
218  l = max( 1, j-ku )
219  k = ku + 1 - j + l
220  colssq( 1 ) = zero
221  colssq( 2 ) = one
222  CALL zlassq( min( n, j+kl )-l+1, ab( k, j ), 1,
223  $ colssq( 1 ), colssq( 2 ) )
224  CALL dcombssq( ssq, colssq )
225  90 CONTINUE
226  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
227  END IF
228 *
229  zlangb = VALUE
230  RETURN
231 *
232 * End of ZLANGB
233 *
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine dcombssq(V1, V2)
DCOMBSSQ adds two scaled sum of squares quantities.
Definition: dcombssq.f:60
subroutine zlassq(n, x, incx, scl, sumsq)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f90:126
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function zlangb(NORM, N, KL, KU, AB, LDAB, WORK)
ZLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: zlangb.f:125
Here is the call graph for this function:
Here is the caller graph for this function: