clags2()

subroutine clags2	(	logical	upper,
		real	a1,
		complex	a2,
		real	a3,
		real	b1,
		complex	b2,
		real	b3,
		real	csu,
		complex	snu,
		real	csv,
		complex	snv,
		real	csq,
		complex	snq )

CLAGS2

Download CLAGS2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CLAGS2 computes 2-by-2 unitary matrices U, V and Q, such
!> that if ( UPPER ) then
!>
!>           U**H *A*Q = U**H *( A1 A2 )*Q = ( x  0  )
!>                             ( 0  A3 )     ( x  x  )
!> and
!>           V**H*B*Q = V**H *( B1 B2 )*Q = ( x  0  )
!>                            ( 0  B3 )     ( x  x  )
!>
!> or if ( .NOT.UPPER ) then
!>
!>           U**H *A*Q = U**H *( A1 0  )*Q = ( x  x  )
!>                             ( A2 A3 )     ( 0  x  )
!> and
!>           V**H *B*Q = V**H *( B1 0  )*Q = ( x  x  )
!>                             ( B2 B3 )     ( 0  x  )
!> where
!>
!>   U = (   CSU    SNU ), V = (  CSV    SNV ),
!>       ( -SNU**H  CSU )      ( -SNV**H CSV )
!>
!>   Q = (   CSQ    SNQ )
!>       ( -SNQ**H  CSQ )
!>
!> The rows of the transformed A and B are parallel. Moreover, if the
!> input 2-by-2 matrix A is not zero, then the transformed (1,1) entry
!> of A is not zero. If the input matrices A and B are both not zero,
!> then the transformed (2,2) element of B is not zero, except when the
!> first rows of input A and B are parallel and the second rows are
!> zero.
!> 

Parameters

[in]	UPPER	!> UPPER is LOGICAL !> = .TRUE.: the input matrices A and B are upper triangular. !> = .FALSE.: the input matrices A and B are lower triangular. !>
[in]	A1	!> A1 is REAL !>
[in]	A2	!> A2 is COMPLEX !>
[in]	A3	!> A3 is REAL !> On entry, A1, A2 and A3 are elements of the input 2-by-2 !> upper (lower) triangular matrix A. !>
[in]	B1	!> B1 is REAL !>
[in]	B2	!> B2 is COMPLEX !>
[in]	B3	!> B3 is REAL !> On entry, B1, B2 and B3 are elements of the input 2-by-2 !> upper (lower) triangular matrix B. !>
[out]	CSU	!> CSU is REAL !>
[out]	SNU	!> SNU is COMPLEX !> The desired unitary matrix U. !>
[out]	CSV	!> CSV is REAL !>
[out]	SNV	!> SNV is COMPLEX !> The desired unitary matrix V. !>
[out]	CSQ	!> CSQ is REAL !>
[out]	SNQ	!> SNQ is COMPLEX !> The desired unitary matrix Q. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 154 of file clags2.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            UPPER
      REAL               A1, A3, B1, B3, CSQ, CSU, CSV
      COMPLEX            A2, B2, SNQ, SNU, SNV
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      REAL               A, AUA11, AUA12, AUA21, AUA22, AVB11, AVB12,
     $                   AVB21, AVB22, CSL, CSR, D, FB, FC, S1, S2, SNL,
     $                   SNR, UA11R, UA22R, VB11R, VB22R
      COMPLEX            B, C, D1, R, T, UA11, UA12, UA21, UA22, VB11,
     $                   VB12, VB21, VB22
*     ..
*     .. External Subroutines ..
      EXTERNAL           clartg, slasv2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, cmplx, conjg, real
*     ..
*     .. Statement Functions ..
      REAL               ABS1
*     ..
*     .. Statement Function definitions ..
      abs1( t ) = abs( real( t ) ) + abs( aimag( t ) )
*     ..
*     .. Executable Statements ..
*
      IF( upper ) THEN
*
*        Input matrices A and B are upper triangular matrices
*
*        Form matrix C = A*adj(B) = ( a b )
*                                   ( 0 d )
*
         a = a1*b3
         d = a3*b1
         b = a2*b1 - a1*b2
         fb = abs( b )
*
*        Transform complex 2-by-2 matrix C to real matrix by unitary
*        diagonal matrix diag(1,D1).
*
         d1 = one
         IF( fb.NE.zero )
     $      d1 = b / fb
*
*        The SVD of real 2 by 2 triangular C
*
*         ( CSL -SNL )*( A B )*(  CSR  SNR ) = ( R 0 )
*         ( SNL  CSL ) ( 0 D ) ( -SNR  CSR )   ( 0 T )
*
         CALL slasv2( a, fb, d, s1, s2, snr, csr, snl, csl )
*
         IF( abs( csl ).GE.abs( snl ) .OR. abs( csr ).GE.abs( snr ) )
     $        THEN
*
*           Compute the (1,1) and (1,2) elements of U**H *A and V**H *B,
*           and (1,2) element of |U|**H *|A| and |V|**H *|B|.
*
            ua11r = csl*a1
            ua12 = csl*a2 + d1*snl*a3
*
            vb11r = csr*b1
            vb12 = csr*b2 + d1*snr*b3
*
            aua12 = abs( csl )*abs1( a2 ) + abs( snl )*abs( a3 )
            avb12 = abs( csr )*abs1( b2 ) + abs( snr )*abs( b3 )
*
*           zero (1,2) elements of U**H *A and V**H *B
*
            IF( ( abs( ua11r )+abs1( ua12 ) ).EQ.zero ) THEN
               CALL clartg( -cmplx( vb11r ), conjg( vb12 ), csq, snq,
     $                      r )
            ELSE IF( ( abs( vb11r )+abs1( vb12 ) ).EQ.zero ) THEN
               CALL clartg( -cmplx( ua11r ), conjg( ua12 ), csq, snq,
     $                      r )
            ELSE IF( aua12 / ( abs( ua11r )+abs1( ua12 ) ).LE.avb12 /
     $               ( abs( vb11r )+abs1( vb12 ) ) ) THEN
               CALL clartg( -cmplx( ua11r ), conjg( ua12 ), csq, snq,
     $                      r )
            ELSE
               CALL clartg( -cmplx( vb11r ), conjg( vb12 ), csq, snq,
     $                      r )
            END IF
*
            csu = csl
            snu = -d1*snl
            csv = csr
            snv = -d1*snr
*
         ELSE
*
*           Compute the (2,1) and (2,2) elements of U**H *A and V**H *B,
*           and (2,2) element of |U|**H *|A| and |V|**H *|B|.
*
            ua21 = -conjg( d1 )*snl*a1
            ua22 = -conjg( d1 )*snl*a2 + csl*a3
*
            vb21 = -conjg( d1 )*snr*b1
            vb22 = -conjg( d1 )*snr*b2 + csr*b3
*
            aua22 = abs( snl )*abs1( a2 ) + abs( csl )*abs( a3 )
            avb22 = abs( snr )*abs1( b2 ) + abs( csr )*abs( b3 )
*
*           zero (2,2) elements of U**H *A and V**H *B, and then swap.
*
            IF( ( abs1( ua21 )+abs1( ua22 ) ).EQ.zero ) THEN
               CALL clartg( -conjg( vb21 ), conjg( vb22 ), csq, snq,
     $                      r )
            ELSE IF( ( abs1( vb21 )+abs( vb22 ) ).EQ.zero ) THEN
               CALL clartg( -conjg( ua21 ), conjg( ua22 ), csq, snq,
     $                      r )
            ELSE IF( aua22 / ( abs1( ua21 )+abs1( ua22 ) ).LE.avb22 /
     $               ( abs1( vb21 )+abs1( vb22 ) ) ) THEN
               CALL clartg( -conjg( ua21 ), conjg( ua22 ), csq, snq,
     $                      r )
            ELSE
               CALL clartg( -conjg( vb21 ), conjg( vb22 ), csq, snq,
     $                      r )
            END IF
*
            csu = snl
            snu = d1*csl
            csv = snr
            snv = d1*csr
*
         END IF
*
      ELSE
*
*        Input matrices A and B are lower triangular matrices
*
*        Form matrix C = A*adj(B) = ( a 0 )
*                                   ( c d )
*
         a = a1*b3
         d = a3*b1
         c = a2*b3 - a3*b2
         fc = abs( c )
*
*        Transform complex 2-by-2 matrix C to real matrix by unitary
*        diagonal matrix diag(d1,1).
*
         d1 = one
         IF( fc.NE.zero )
     $      d1 = c / fc
*
*        The SVD of real 2 by 2 triangular C
*
*         ( CSL -SNL )*( A 0 )*(  CSR  SNR ) = ( R 0 )
*         ( SNL  CSL ) ( C D ) ( -SNR  CSR )   ( 0 T )
*
         CALL slasv2( a, fc, d, s1, s2, snr, csr, snl, csl )
*
         IF( abs( csr ).GE.abs( snr ) .OR. abs( csl ).GE.abs( snl ) )
     $        THEN
*
*           Compute the (2,1) and (2,2) elements of U**H *A and V**H *B,
*           and (2,1) element of |U|**H *|A| and |V|**H *|B|.
*
            ua21 = -d1*snr*a1 + csr*a2
            ua22r = csr*a3
*
            vb21 = -d1*snl*b1 + csl*b2
            vb22r = csl*b3
*
            aua21 = abs( snr )*abs( a1 ) + abs( csr )*abs1( a2 )
            avb21 = abs( snl )*abs( b1 ) + abs( csl )*abs1( b2 )
*
*           zero (2,1) elements of U**H *A and V**H *B.
*
            IF( ( abs1( ua21 )+abs( ua22r ) ).EQ.zero ) THEN
               CALL clartg( cmplx( vb22r ), vb21, csq, snq, r )
            ELSE IF( ( abs1( vb21 )+abs( vb22r ) ).EQ.zero ) THEN
               CALL clartg( cmplx( ua22r ), ua21, csq, snq, r )
            ELSE IF( aua21 / ( abs1( ua21 )+abs( ua22r ) ).LE.avb21 /
     $               ( abs1( vb21 )+abs( vb22r ) ) ) THEN
               CALL clartg( cmplx( ua22r ), ua21, csq, snq, r )
            ELSE
               CALL clartg( cmplx( vb22r ), vb21, csq, snq, r )
            END IF
*
            csu = csr
            snu = -conjg( d1 )*snr
            csv = csl
            snv = -conjg( d1 )*snl
*
         ELSE
*
*           Compute the (1,1) and (1,2) elements of U**H *A and V**H *B,
*           and (1,1) element of |U|**H *|A| and |V|**H *|B|.
*
            ua11 = csr*a1 + conjg( d1 )*snr*a2
            ua12 = conjg( d1 )*snr*a3
*
            vb11 = csl*b1 + conjg( d1 )*snl*b2
            vb12 = conjg( d1 )*snl*b3
*
            aua11 = abs( csr )*abs( a1 ) + abs( snr )*abs1( a2 )
            avb11 = abs( csl )*abs( b1 ) + abs( snl )*abs1( b2 )
*
*           zero (1,1) elements of U**H *A and V**H *B, and then swap.
*
            IF( ( abs1( ua11 )+abs1( ua12 ) ).EQ.zero ) THEN
               CALL clartg( vb12, vb11, csq, snq, r )
            ELSE IF( ( abs1( vb11 )+abs1( vb12 ) ).EQ.zero ) THEN
               CALL clartg( ua12, ua11, csq, snq, r )
            ELSE IF( aua11 / ( abs1( ua11 )+abs1( ua12 ) ).LE.avb11 /
     $               ( abs1( vb11 )+abs1( vb12 ) ) ) THEN
               CALL clartg( ua12, ua11, csq, snq, r )
            ELSE
               CALL clartg( vb12, vb11, csq, snq, r )
            END IF
*
            csu = snr
            snu = conjg( d1 )*csr
            csv = snl
            snv = conjg( d1 )*csl
*
         END IF
*
      END IF
*
      RETURN
*
*     End of CLAGS2
*

Here is the call graph for this function:

Here is the caller graph for this function: