dla_lin_berr()

subroutine dla_lin_berr	(	integer	n,
		integer	nz,
		integer	nrhs,
		double precision, dimension( n, nrhs )	res,
		double precision, dimension( n, nrhs )	ayb,
		double precision, dimension( nrhs )	berr
	)

DLA_LIN_BERR computes a component-wise relative backward error.

Download DLA_LIN_BERR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

    DLA_LIN_BERR computes component-wise relative backward error from
    the formula
        max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
    where abs(Z) is the component-wise absolute value of the matrix
    or vector Z.

Parameters

[in]	N	N is INTEGER The number of linear equations, i.e., the order of the matrix A. N >= 0.
[in]	NZ	NZ is INTEGER We add (NZ+1)*SLAMCH( 'Safe minimum' ) to R(i) in the numerator to guard against spuriously zero residuals. Default value is N.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrices AYB, RES, and BERR. NRHS >= 0.
[in]	RES	RES is DOUBLE PRECISION array, dimension (N,NRHS) The residual matrix, i.e., the matrix R in the relative backward error formula above.
[in]	AYB	AYB is DOUBLE PRECISION array, dimension (N, NRHS) The denominator in the relative backward error formula above, i.e., the matrix abs(op(A_s))*abs(Y) + abs(B_s). The matrices A, Y, and B are from iterative refinement (see dla_gerfsx_extended.f).
[out]	BERR	BERR is DOUBLE PRECISION array, dimension (NRHS) The component-wise relative backward error from the formula above.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 100 of file dla_lin_berr.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            N, NZ, NRHS
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AYB( N, NRHS ), BERR( NRHS )
      DOUBLE PRECISION   RES( N, NRHS )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      DOUBLE PRECISION   TMP
      INTEGER            I, J
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. External Functions ..
      EXTERNAL           dlamch
      DOUBLE PRECISION   DLAMCH
      DOUBLE PRECISION   SAFE1
*     ..
*     .. Executable Statements ..
*
*     Adding SAFE1 to the numerator guards against spuriously zero
*     residuals.  A similar safeguard is in the SLA_yyAMV routine used
*     to compute AYB.
*
      safe1 = dlamch( 'Safe minimum' )
      safe1 = (nz+1)*safe1
 
      DO j = 1, nrhs
         berr(j) = 0.0d+0
         DO i = 1, n
            IF (ayb(i,j) .NE. 0.0d+0) THEN
               tmp = (safe1+abs(res(i,j)))/ayb(i,j)
               berr(j) = max( berr(j), tmp )
            END IF
*
*     If AYB is exactly 0.0 (and if computed by SLA_yyAMV), then we know
*     the true residual also must be exactly 0.0.
*
         END DO
      END DO
*
*     End of DLA_LIN_BERR
*

Here is the call graph for this function:

Here is the caller graph for this function: