zcposv()

subroutine zcposv	(	character	uplo,
		integer	n,
		integer	nrhs,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		complex*16, dimension( ldx, * )	x,
		integer	ldx,
		complex*16, dimension( n, * )	work,
		complex, dimension( * )	swork,
		double precision, dimension( * )	rwork,
		integer	iter,
		integer	info )

ZCPOSV computes the solution to system of linear equations A * X = B for PO matrices

Download ZCPOSV + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZCPOSV computes the solution to a complex system of linear equations
!>    A * X = B,
!> where A is an N-by-N Hermitian positive definite matrix and X and B
!> are N-by-NRHS matrices.
!>
!> ZCPOSV first attempts to factorize the matrix in COMPLEX and use this
!> factorization within an iterative refinement procedure to produce a
!> solution with COMPLEX*16 normwise backward error quality (see below).
!> If the approach fails the method switches to a COMPLEX*16
!> factorization and solve.
!>
!> The iterative refinement is not going to be a winning strategy if
!> the ratio COMPLEX performance over COMPLEX*16 performance is too
!> small. A reasonable strategy should take the number of right-hand
!> sides and the size of the matrix into account. This might be done
!> with a call to ILAENV in the future. Up to now, we always try
!> iterative refinement.
!>
!> The iterative refinement process is stopped if
!>     ITER > ITERMAX
!> or for all the RHS we have:
!>     RNRM < SQRT(N)*XNRM*ANRM*EPS*BWDMAX
!> where
!>     o ITER is the number of the current iteration in the iterative
!>       refinement process
!>     o RNRM is the infinity-norm of the residual
!>     o XNRM is the infinity-norm of the solution
!>     o ANRM is the infinity-operator-norm of the matrix A
!>     o EPS is the machine epsilon returned by DLAMCH('Epsilon')
!> The value ITERMAX and BWDMAX are fixed to 30 and 1.0D+00
!> respectively.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangle of A is stored; !> = 'L': Lower triangle of A is stored. !>
[in]	N	!> N is INTEGER !> The number of linear equations, i.e., the order of the !> matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrix B. NRHS >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, !> dimension (LDA,N) !> On entry, the Hermitian matrix A. If UPLO = 'U', the leading !> N-by-N upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading N-by-N lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. !> !> Note that the imaginary parts of the diagonal !> elements need not be set and are assumed to be zero. !> !> On exit, if iterative refinement has been successfully used !> (INFO = 0 and ITER >= 0, see description below), then A is !> unchanged, if double precision factorization has been used !> (INFO = 0 and ITER < 0, see description below), then the !> array A contains the factor U or L from the Cholesky !> factorization A = U**H*U or A = L*L**H. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in]	B	!> B is COMPLEX*16 array, dimension (LDB,NRHS) !> The N-by-NRHS right hand side matrix B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	X	!> X is COMPLEX*16 array, dimension (LDX,NRHS) !> If INFO = 0, the N-by-NRHS solution matrix X. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (N,NRHS) !> This array is used to hold the residual vectors. !>
[out]	SWORK	!> SWORK is COMPLEX array, dimension (N*(N+NRHS)) !> This array is used to use the single precision matrix and the !> right-hand sides or solutions in single precision. !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[out]	ITER	!> ITER is INTEGER !> < 0: iterative refinement has failed, COMPLEX*16 !> factorization has been performed !> -1 : the routine fell back to full precision for !> implementation- or machine-specific reasons !> -2 : narrowing the precision induced an overflow, !> the routine fell back to full precision !> -3 : failure of CPOTRF !> -31: stop the iterative refinement after the 30th !> iterations !> > 0: iterative refinement has been successfully used. !> Returns the number of iterations !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: if INFO = i, the leading principal minor of order i !> of (COMPLEX*16) A is not positive, so the factorization !> could not be completed, and the solution has not been !> computed. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 205 of file zcposv.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, ITER, LDA, LDB, LDX, N, NRHS
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   RWORK( * )
      COMPLEX            SWORK( * )
      COMPLEX*16         A( LDA, * ), B( LDB, * ), WORK( N, * ),
     $                   X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      LOGICAL            DOITREF
      parameter( doitref = .true. )
*
      INTEGER            ITERMAX
      parameter( itermax = 30 )
*
      DOUBLE PRECISION   BWDMAX
      parameter( bwdmax = 1.0e+00 )
*
      COMPLEX*16         NEGONE, ONE
      parameter( negone = ( -1.0d+00, 0.0d+00 ),
     $                   one = ( 1.0d+00, 0.0d+00 ) )
*
*     .. Local Scalars ..
      INTEGER            I, IITER, PTSA, PTSX
      DOUBLE PRECISION   ANRM, CTE, EPS, RNRM, XNRM
      COMPLEX*16         ZDUM
*
*     .. External Subroutines ..
      EXTERNAL           zaxpy, zhemm, zlacpy, zlat2c, zlag2c,
     $                   clag2z,
     $                   cpotrf, cpotrs, xerbla, zpotrf, zpotrs
*     ..
*     .. External Functions ..
      INTEGER            IZAMAX
      DOUBLE PRECISION   DLAMCH, ZLANHE
      LOGICAL            LSAME
      EXTERNAL           izamax, dlamch, zlanhe, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max, sqrt
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
      info = 0
      iter = 0
*
*     Test the input parameters.
*
      IF( .NOT.lsame( uplo, 'U' ) .AND.
     $    .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -7
      ELSE IF( ldx.LT.max( 1, n ) ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZCPOSV', -info )
         RETURN
      END IF
*
*     Quick return if (N.EQ.0).
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Skip single precision iterative refinement if a priori slower
*     than double precision factorization.
*
      IF( .NOT.doitref ) THEN
         iter = -1
         GO TO 40
      END IF
*
*     Compute some constants.
*
      anrm = zlanhe( 'I', uplo, n, a, lda, rwork )
      eps = dlamch( 'Epsilon' )
      cte = anrm*eps*sqrt( dble( n ) )*bwdmax
*
*     Set the indices PTSA, PTSX for referencing SA and SX in SWORK.
*
      ptsa = 1
      ptsx = ptsa + n*n
*
*     Convert B from double precision to single precision and store the
*     result in SX.
*
      CALL zlag2c( n, nrhs, b, ldb, swork( ptsx ), n, info )
*
      IF( info.NE.0 ) THEN
         iter = -2
         GO TO 40
      END IF
*
*     Convert A from double precision to single precision and store the
*     result in SA.
*
      CALL zlat2c( uplo, n, a, lda, swork( ptsa ), n, info )
*
      IF( info.NE.0 ) THEN
         iter = -2
         GO TO 40
      END IF
*
*     Compute the Cholesky factorization of SA.
*
      CALL cpotrf( uplo, n, swork( ptsa ), n, info )
*
      IF( info.NE.0 ) THEN
         iter = -3
         GO TO 40
      END IF
*
*     Solve the system SA*SX = SB.
*
      CALL cpotrs( uplo, n, nrhs, swork( ptsa ), n, swork( ptsx ), n,
     $             info )
*
*     Convert SX back to COMPLEX*16
*
      CALL clag2z( n, nrhs, swork( ptsx ), n, x, ldx, info )
*
*     Compute R = B - AX (R is WORK).
*
      CALL zlacpy( 'All', n, nrhs, b, ldb, work, n )
*
      CALL zhemm( 'Left', uplo, n, nrhs, negone, a, lda, x, ldx, one,
     $            work, n )
*
*     Check whether the NRHS normwise backward errors satisfy the
*     stopping criterion. If yes, set ITER=0 and return.
*
      DO i = 1, nrhs
         xnrm = cabs1( x( izamax( n, x( 1, i ), 1 ), i ) )
         rnrm = cabs1( work( izamax( n, work( 1, i ), 1 ), i ) )
         IF( rnrm.GT.xnrm*cte )
     $      GO TO 10
      END DO
*
*     If we are here, the NRHS normwise backward errors satisfy the
*     stopping criterion. We are good to exit.
*
      iter = 0
      RETURN
*
   10 CONTINUE
*
      DO 30 iiter = 1, itermax
*
*        Convert R (in WORK) from double precision to single precision
*        and store the result in SX.
*
         CALL zlag2c( n, nrhs, work, n, swork( ptsx ), n, info )
*
         IF( info.NE.0 ) THEN
            iter = -2
            GO TO 40
         END IF
*
*        Solve the system SA*SX = SR.
*
         CALL cpotrs( uplo, n, nrhs, swork( ptsa ), n, swork( ptsx ),
     $                n,
     $                info )
*
*        Convert SX back to double precision and update the current
*        iterate.
*
         CALL clag2z( n, nrhs, swork( ptsx ), n, work, n, info )
*
         DO i = 1, nrhs
            CALL zaxpy( n, one, work( 1, i ), 1, x( 1, i ), 1 )
         END DO
*
*        Compute R = B - AX (R is WORK).
*
         CALL zlacpy( 'All', n, nrhs, b, ldb, work, n )
*
         CALL zhemm( 'L', uplo, n, nrhs, negone, a, lda, x, ldx, one,
     $               work, n )
*
*        Check whether the NRHS normwise backward errors satisfy the
*        stopping criterion. If yes, set ITER=IITER>0 and return.
*
         DO i = 1, nrhs
            xnrm = cabs1( x( izamax( n, x( 1, i ), 1 ), i ) )
            rnrm = cabs1( work( izamax( n, work( 1, i ), 1 ), i ) )
            IF( rnrm.GT.xnrm*cte )
     $         GO TO 20
         END DO
*
*        If we are here, the NRHS normwise backward errors satisfy the
*        stopping criterion, we are good to exit.
*
         iter = iiter
*
         RETURN
*
   20    CONTINUE
*
   30 CONTINUE
*
*     If we are at this place of the code, this is because we have
*     performed ITER=ITERMAX iterations and never satisfied the
*     stopping criterion, set up the ITER flag accordingly and follow
*     up on double precision routine.
*
      iter = -itermax - 1
*
   40 CONTINUE
*
*     Single-precision iterative refinement failed to converge to a
*     satisfactory solution, so we resort to double precision.
*
      CALL zpotrf( uplo, n, a, lda, info )
*
      IF( info.NE.0 )
     $   RETURN
*
      CALL zlacpy( 'All', n, nrhs, b, ldb, x, ldx )
      CALL zpotrs( uplo, n, nrhs, a, lda, x, ldx, info )
*
      RETURN
*
*     End of ZCPOSV
*

Here is the call graph for this function:

Here is the caller graph for this function: