zglmts()

subroutine zglmts	(	integer	n,
		integer	m,
		integer	p,
		complex*16, dimension( lda, * )	a,
		complex*16, dimension( lda, * )	af,
		integer	lda,
		complex*16, dimension( ldb, * )	b,
		complex*16, dimension( ldb, * )	bf,
		integer	ldb,
		complex*16, dimension( * )	d,
		complex*16, dimension( * )	df,
		complex*16, dimension( * )	x,
		complex*16, dimension( * )	u,
		complex*16, dimension( lwork )	work,
		integer	lwork,
		double precision, dimension( * )	rwork,
		double precision	result
	)

ZGLMTS

Purpose:

 ZGLMTS tests ZGGGLM - a subroutine for solving the generalized
 linear model problem.

Parameters

[in]	N	N is INTEGER The number of rows of the matrices A and B. N >= 0.
[in]	M	M is INTEGER The number of columns of the matrix A. M >= 0.
[in]	P	P is INTEGER The number of columns of the matrix B. P >= 0.
[in]	A	A is COMPLEX*16 array, dimension (LDA,M) The N-by-M matrix A.
[out]	AF	AF is COMPLEX*16 array, dimension (LDA,M)
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF. LDA >= max(M,N).
[in]	B	B is COMPLEX*16 array, dimension (LDB,P) The N-by-P matrix A.
[out]	BF	BF is COMPLEX*16 array, dimension (LDB,P)
[in]	LDB	LDB is INTEGER The leading dimension of the arrays B, BF. LDB >= max(P,N).
[in]	D	D is COMPLEX*16 array, dimension( N ) On input, the left hand side of the GLM.
[out]	DF	DF is COMPLEX*16 array, dimension( N )
[out]	X	X is COMPLEX*16 array, dimension( M ) solution vector X in the GLM problem.
[out]	U	U is COMPLEX*16 array, dimension( P ) solution vector U in the GLM problem.
[out]	WORK	WORK is COMPLEX*16 array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (M)
[out]	RESULT	RESULT is DOUBLE PRECISION The test ratio: norm( d - A*x - B*u ) RESULT = ----------------------------------------- (norm(A)+norm(B))*(norm(x)+norm(u))*EPS

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 144 of file zglmts.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, LWORK, M, N, P
      DOUBLE PRECISION   RESULT
*     ..
*     .. Array Arguments ..
*
*  ====================================================================
*
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( LDA, * ), AF( LDA, * ), B( LDB, * ),
     $                   BF( LDB, * ), D( * ), DF( * ), U( * ),
     $                   WORK( LWORK ), X( * )
*     ..
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
      COMPLEX*16         CONE
      parameter( cone = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      DOUBLE PRECISION   ANORM, BNORM, DNORM, EPS, UNFL, XNORM, YNORM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DZASUM, ZLANGE
      EXTERNAL           dlamch, dzasum, zlange
*     ..
*     .. External Subroutines ..
*
      EXTERNAL           zcopy, zgemv, zggglm, zlacpy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
      unfl = dlamch( 'Safe minimum' )
      anorm = max( zlange( '1', n, m, a, lda, rwork ), unfl )
      bnorm = max( zlange( '1', n, p, b, ldb, rwork ), unfl )
*
*     Copy the matrices A and B to the arrays AF and BF,
*     and the vector D the array DF.
*
      CALL zlacpy( 'Full', n, m, a, lda, af, lda )
      CALL zlacpy( 'Full', n, p, b, ldb, bf, ldb )
      CALL zcopy( n, d, 1, df, 1 )
*
*     Solve GLM problem
*
      CALL zggglm( n, m, p, af, lda, bf, ldb, df, x, u, work, lwork,
     $             info )
*
*     Test the residual for the solution of LSE
*
*                       norm( d - A*x - B*u )
*       RESULT = -----------------------------------------
*                (norm(A)+norm(B))*(norm(x)+norm(u))*EPS
*
      CALL zcopy( n, d, 1, df, 1 )
      CALL zgemv( 'No transpose', n, m, -cone, a, lda, x, 1, cone, df,
     $            1 )
*
      CALL zgemv( 'No transpose', n, p, -cone, b, ldb, u, 1, cone, df,
     $            1 )
*
      dnorm = dzasum( n, df, 1 )
      xnorm = dzasum( m, x, 1 ) + dzasum( p, u, 1 )
      ynorm = anorm + bnorm
*
      IF( xnorm.LE.zero ) THEN
         result = zero
      ELSE
         result = ( ( dnorm / ynorm ) / xnorm ) / eps
      END IF
*
      RETURN
*
*     End of ZGLMTS
*

Here is the call graph for this function:

Here is the caller graph for this function: