LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ stpmlqt()

subroutine stpmlqt ( character  SIDE,
character  TRANS,
integer  M,
integer  N,
integer  K,
integer  L,
integer  MB,
real, dimension( ldv, * )  V,
integer  LDV,
real, dimension( ldt, * )  T,
integer  LDT,
real, dimension( lda, * )  A,
integer  LDA,
real, dimension( ldb, * )  B,
integer  LDB,
real, dimension( * )  WORK,
integer  INFO 
)

STPMLQT

Download STPMLQT + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 STPMLQT applies a real orthogonal matrix Q obtained from a
 "triangular-pentagonal" real block reflector H to a general
 real matrix C, which consists of two blocks A and B.
Parameters
[in]SIDE
          SIDE is CHARACTER*1
          = 'L': apply Q or Q**T from the Left;
          = 'R': apply Q or Q**T from the Right.
[in]TRANS
          TRANS is CHARACTER*1
          = 'N':  No transpose, apply Q;
          = 'T':  Transpose, apply Q**T.
[in]M
          M is INTEGER
          The number of rows of the matrix B. M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix B. N >= 0.
[in]K
          K is INTEGER
          The number of elementary reflectors whose product defines
          the matrix Q.
[in]L
          L is INTEGER
          The order of the trapezoidal part of V.
          K >= L >= 0.  See Further Details.
[in]MB
          MB is INTEGER
          The block size used for the storage of T.  K >= MB >= 1.
          This must be the same value of MB used to generate T
          in STPLQT.
[in]V
          V is REAL array, dimension (LDV,K)
          The i-th row must contain the vector which defines the
          elementary reflector H(i), for i = 1,2,...,k, as returned by
          STPLQT in B.  See Further Details.
[in]LDV
          LDV is INTEGER
          The leading dimension of the array V.
          If SIDE = 'L', LDV >= max(1,M);
          if SIDE = 'R', LDV >= max(1,N).
[in]T
          T is REAL array, dimension (LDT,K)
          The upper triangular factors of the block reflectors
          as returned by STPLQT, stored as a MB-by-K matrix.
[in]LDT
          LDT is INTEGER
          The leading dimension of the array T.  LDT >= MB.
[in,out]A
          A is REAL array, dimension
          (LDA,N) if SIDE = 'L' or
          (LDA,K) if SIDE = 'R'
          On entry, the K-by-N or M-by-K matrix A.
          On exit, A is overwritten by the corresponding block of
          Q*C or Q**T*C or C*Q or C*Q**T.  See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.
          If SIDE = 'L', LDC >= max(1,K);
          If SIDE = 'R', LDC >= max(1,M).
[in,out]B
          B is REAL array, dimension (LDB,N)
          On entry, the M-by-N matrix B.
          On exit, B is overwritten by the corresponding block of
          Q*C or Q**T*C or C*Q or C*Q**T.  See Further Details.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.
          LDB >= max(1,M).
[out]WORK
          WORK is REAL array. The dimension of WORK is
           N*MB if SIDE = 'L', or  M*MB if SIDE = 'R'.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  The columns of the pentagonal matrix V contain the elementary reflectors
  H(1), H(2), ..., H(K); V is composed of a rectangular block V1 and a
  trapezoidal block V2:

        V = [V1] [V2].


  The size of the trapezoidal block V2 is determined by the parameter L,
  where 0 <= L <= K; V2 is lower trapezoidal, consisting of the first L
  rows of a K-by-K upper triangular matrix.  If L=K, V2 is lower triangular;
  if L=0, there is no trapezoidal block, hence V = V1 is rectangular.

  If SIDE = 'L':  C = [A]  where A is K-by-N,  B is M-by-N and V is K-by-M.
                      [B]

  If SIDE = 'R':  C = [A B]  where A is M-by-K, B is M-by-N and V is K-by-N.

  The real orthogonal matrix Q is formed from V and T.

  If TRANS='N' and SIDE='L', C is on exit replaced with Q * C.

  If TRANS='T' and SIDE='L', C is on exit replaced with Q**T * C.

  If TRANS='N' and SIDE='R', C is on exit replaced with C * Q.

  If TRANS='T' and SIDE='R', C is on exit replaced with C * Q**T.

Definition at line 214 of file stpmlqt.f.

216 *
217 * -- LAPACK computational routine --
218 * -- LAPACK is a software package provided by Univ. of Tennessee, --
219 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
220 *
221 * .. Scalar Arguments ..
222  CHARACTER SIDE, TRANS
223  INTEGER INFO, K, LDV, LDA, LDB, M, N, L, MB, LDT
224 * ..
225 * .. Array Arguments ..
226  REAL V( LDV, * ), A( LDA, * ), B( LDB, * ),
227  $ T( LDT, * ), WORK( * )
228 * ..
229 *
230 * =====================================================================
231 *
232 * ..
233 * .. Local Scalars ..
234  LOGICAL LEFT, RIGHT, TRAN, NOTRAN
235  INTEGER I, IB, NB, LB, KF, LDAQ
236 * ..
237 * .. External Functions ..
238  LOGICAL LSAME
239  EXTERNAL lsame
240 * ..
241 * .. External Subroutines ..
242  EXTERNAL slarfb, stprfb, xerbla
243 * ..
244 * .. Intrinsic Functions ..
245  INTRINSIC max, min
246 * ..
247 * .. Executable Statements ..
248 *
249 * .. Test the input arguments ..
250 *
251  info = 0
252  left = lsame( side, 'L' )
253  right = lsame( side, 'R' )
254  tran = lsame( trans, 'T' )
255  notran = lsame( trans, 'N' )
256 *
257  IF ( left ) THEN
258  ldaq = max( 1, k )
259  ELSE IF ( right ) THEN
260  ldaq = max( 1, m )
261  END IF
262  IF( .NOT.left .AND. .NOT.right ) THEN
263  info = -1
264  ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
265  info = -2
266  ELSE IF( m.LT.0 ) THEN
267  info = -3
268  ELSE IF( n.LT.0 ) THEN
269  info = -4
270  ELSE IF( k.LT.0 ) THEN
271  info = -5
272  ELSE IF( l.LT.0 .OR. l.GT.k ) THEN
273  info = -6
274  ELSE IF( mb.LT.1 .OR. (mb.GT.k .AND. k.GT.0) ) THEN
275  info = -7
276  ELSE IF( ldv.LT.k ) THEN
277  info = -9
278  ELSE IF( ldt.LT.mb ) THEN
279  info = -11
280  ELSE IF( lda.LT.ldaq ) THEN
281  info = -13
282  ELSE IF( ldb.LT.max( 1, m ) ) THEN
283  info = -15
284  END IF
285 *
286  IF( info.NE.0 ) THEN
287  CALL xerbla( 'STPMLQT', -info )
288  RETURN
289  END IF
290 *
291 * .. Quick return if possible ..
292 *
293  IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) RETURN
294 *
295  IF( left .AND. notran ) THEN
296 *
297  DO i = 1, k, mb
298  ib = min( mb, k-i+1 )
299  nb = min( m-l+i+ib-1, m )
300  IF( i.GE.l ) THEN
301  lb = 0
302  ELSE
303  lb = 0
304  END IF
305  CALL stprfb( 'L', 'T', 'F', 'R', nb, n, ib, lb,
306  $ v( i, 1 ), ldv, t( 1, i ), ldt,
307  $ a( i, 1 ), lda, b, ldb, work, ib )
308  END DO
309 *
310  ELSE IF( right .AND. tran ) THEN
311 *
312  DO i = 1, k, mb
313  ib = min( mb, k-i+1 )
314  nb = min( n-l+i+ib-1, n )
315  IF( i.GE.l ) THEN
316  lb = 0
317  ELSE
318  lb = nb-n+l-i+1
319  END IF
320  CALL stprfb( 'R', 'N', 'F', 'R', m, nb, ib, lb,
321  $ v( i, 1 ), ldv, t( 1, i ), ldt,
322  $ a( 1, i ), lda, b, ldb, work, m )
323  END DO
324 *
325  ELSE IF( left .AND. tran ) THEN
326 *
327  kf = ((k-1)/mb)*mb+1
328  DO i = kf, 1, -mb
329  ib = min( mb, k-i+1 )
330  nb = min( m-l+i+ib-1, m )
331  IF( i.GE.l ) THEN
332  lb = 0
333  ELSE
334  lb = 0
335  END IF
336  CALL stprfb( 'L', 'N', 'F', 'R', nb, n, ib, lb,
337  $ v( i, 1 ), ldv, t( 1, i ), ldt,
338  $ a( i, 1 ), lda, b, ldb, work, ib )
339  END DO
340 *
341  ELSE IF( right .AND. notran ) THEN
342 *
343  kf = ((k-1)/mb)*mb+1
344  DO i = kf, 1, -mb
345  ib = min( mb, k-i+1 )
346  nb = min( n-l+i+ib-1, n )
347  IF( i.GE.l ) THEN
348  lb = 0
349  ELSE
350  lb = nb-n+l-i+1
351  END IF
352  CALL stprfb( 'R', 'T', 'F', 'R', m, nb, ib, lb,
353  $ v( i, 1 ), ldv, t( 1, i ), ldt,
354  $ a( 1, i ), lda, b, ldb, work, m )
355  END DO
356 *
357  END IF
358 *
359  RETURN
360 *
361 * End of STPMLQT
362 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine slarfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, V, LDV, T, LDT, C, LDC, WORK, LDWORK)
SLARFB applies a block reflector or its transpose to a general rectangular matrix.
Definition: slarfb.f:197
subroutine stprfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, L, V, LDV, T, LDT, A, LDA, B, LDB, WORK, LDWORK)
STPRFB applies a real or complex "triangular-pentagonal" blocked reflector to a real or complex matri...
Definition: stprfb.f:251
Here is the call graph for this function:
Here is the caller graph for this function: