LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
sgbt05.f
Go to the documentation of this file.
1 *> \brief \b SGBT05
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 * Definition:
9 * ===========
10 *
11 * SUBROUTINE SGBT05( TRANS, N, KL, KU, NRHS, AB, LDAB, B, LDB, X,
12 * LDX, XACT, LDXACT, FERR, BERR, RESLTS )
13 *
14 * .. Scalar Arguments ..
15 * CHARACTER TRANS
16 * INTEGER KL, KU, LDAB, LDB, LDX, LDXACT, N, NRHS
17 * ..
18 * .. Array Arguments ..
19 * REAL AB( LDAB, * ), B( LDB, * ), BERR( * ),
20 * $ FERR( * ), RESLTS( * ), X( LDX, * ),
21 * $ XACT( LDXACT, * )
22 * ..
23 *
24 *
25 *> \par Purpose:
26 * =============
27 *>
28 *> \verbatim
29 *>
30 *> SGBT05 tests the error bounds from iterative refinement for the
31 *> computed solution to a system of equations op(A)*X = B, where A is a
32 *> general band matrix of order n with kl subdiagonals and ku
33 *> superdiagonals and op(A) = A or A**T, depending on TRANS.
34 *>
35 *> RESLTS(1) = test of the error bound
36 *> = norm(X - XACT) / ( norm(X) * FERR )
37 *>
38 *> A large value is returned if this ratio is not less than one.
39 *>
40 *> RESLTS(2) = residual from the iterative refinement routine
41 *> = the maximum of BERR / ( NZ*EPS + (*) ), where
42 *> (*) = NZ*UNFL / (min_i (abs(op(A))*abs(X) +abs(b))_i )
43 *> and NZ = max. number of nonzeros in any row of A, plus 1
44 *> \endverbatim
45 *
46 * Arguments:
47 * ==========
48 *
49 *> \param[in] TRANS
50 *> \verbatim
51 *> TRANS is CHARACTER*1
52 *> Specifies the form of the system of equations.
53 *> = 'N': A * X = B (No transpose)
54 *> = 'T': A**T * X = B (Transpose)
55 *> = 'C': A**H * X = B (Conjugate transpose = Transpose)
56 *> \endverbatim
57 *>
58 *> \param[in] N
59 *> \verbatim
60 *> N is INTEGER
61 *> The number of rows of the matrices X, B, and XACT, and the
62 *> order of the matrix A. N >= 0.
63 *> \endverbatim
64 *>
65 *> \param[in] KL
66 *> \verbatim
67 *> KL is INTEGER
68 *> The number of subdiagonals within the band of A. KL >= 0.
69 *> \endverbatim
70 *>
71 *> \param[in] KU
72 *> \verbatim
73 *> KU is INTEGER
74 *> The number of superdiagonals within the band of A. KU >= 0.
75 *> \endverbatim
76 *>
77 *> \param[in] NRHS
78 *> \verbatim
79 *> NRHS is INTEGER
80 *> The number of columns of the matrices X, B, and XACT.
81 *> NRHS >= 0.
82 *> \endverbatim
83 *>
84 *> \param[in] AB
85 *> \verbatim
86 *> AB is REAL array, dimension (LDAB,N)
87 *> The original band matrix A, stored in rows 1 to KL+KU+1.
88 *> The j-th column of A is stored in the j-th column of the
89 *> array AB as follows:
90 *> AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
91 *> \endverbatim
92 *>
93 *> \param[in] LDAB
94 *> \verbatim
95 *> LDAB is INTEGER
96 *> The leading dimension of the array AB. LDAB >= KL+KU+1.
97 *> \endverbatim
98 *>
99 *> \param[in] B
100 *> \verbatim
101 *> B is REAL array, dimension (LDB,NRHS)
102 *> The right hand side vectors for the system of linear
103 *> equations.
104 *> \endverbatim
105 *>
106 *> \param[in] LDB
107 *> \verbatim
108 *> LDB is INTEGER
109 *> The leading dimension of the array B. LDB >= max(1,N).
110 *> \endverbatim
111 *>
112 *> \param[in] X
113 *> \verbatim
114 *> X is REAL array, dimension (LDX,NRHS)
115 *> The computed solution vectors. Each vector is stored as a
116 *> column of the matrix X.
117 *> \endverbatim
118 *>
119 *> \param[in] LDX
120 *> \verbatim
121 *> LDX is INTEGER
122 *> The leading dimension of the array X. LDX >= max(1,N).
123 *> \endverbatim
124 *>
125 *> \param[in] XACT
126 *> \verbatim
127 *> XACT is REAL array, dimension (LDX,NRHS)
128 *> The exact solution vectors. Each vector is stored as a
129 *> column of the matrix XACT.
130 *> \endverbatim
131 *>
132 *> \param[in] LDXACT
133 *> \verbatim
134 *> LDXACT is INTEGER
135 *> The leading dimension of the array XACT. LDXACT >= max(1,N).
136 *> \endverbatim
137 *>
138 *> \param[in] FERR
139 *> \verbatim
140 *> FERR is REAL array, dimension (NRHS)
141 *> The estimated forward error bounds for each solution vector
142 *> X. If XTRUE is the true solution, FERR bounds the magnitude
143 *> of the largest entry in (X - XTRUE) divided by the magnitude
144 *> of the largest entry in X.
145 *> \endverbatim
146 *>
147 *> \param[in] BERR
148 *> \verbatim
149 *> BERR is REAL array, dimension (NRHS)
150 *> The componentwise relative backward error of each solution
151 *> vector (i.e., the smallest relative change in any entry of A
152 *> or B that makes X an exact solution).
153 *> \endverbatim
154 *>
155 *> \param[out] RESLTS
156 *> \verbatim
157 *> RESLTS is REAL array, dimension (2)
158 *> The maximum over the NRHS solution vectors of the ratios:
159 *> RESLTS(1) = norm(X - XACT) / ( norm(X) * FERR )
160 *> RESLTS(2) = BERR / ( NZ*EPS + (*) )
161 *> \endverbatim
162 *
163 * Authors:
164 * ========
165 *
166 *> \author Univ. of Tennessee
167 *> \author Univ. of California Berkeley
168 *> \author Univ. of Colorado Denver
169 *> \author NAG Ltd.
170 *
171 *> \ingroup single_lin
172 *
173 * =====================================================================
174  SUBROUTINE sgbt05( TRANS, N, KL, KU, NRHS, AB, LDAB, B, LDB, X,
175  $ LDX, XACT, LDXACT, FERR, BERR, RESLTS )
176 *
177 * -- LAPACK test routine --
178 * -- LAPACK is a software package provided by Univ. of Tennessee, --
179 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
180 *
181 * .. Scalar Arguments ..
182  CHARACTER TRANS
183  INTEGER KL, KU, LDAB, LDB, LDX, LDXACT, N, NRHS
184 * ..
185 * .. Array Arguments ..
186  REAL AB( LDAB, * ), B( LDB, * ), BERR( * ),
187  $ ferr( * ), reslts( * ), x( ldx, * ),
188  $ xact( ldxact, * )
189 * ..
190 *
191 * =====================================================================
192 *
193 * .. Parameters ..
194  REAL ZERO, ONE
195  parameter( zero = 0.0e+0, one = 1.0e+0 )
196 * ..
197 * .. Local Scalars ..
198  LOGICAL NOTRAN
199  INTEGER I, IMAX, J, K, NZ
200  REAL AXBI, DIFF, EPS, ERRBND, OVFL, TMP, UNFL, XNORM
201 * ..
202 * .. External Functions ..
203  LOGICAL LSAME
204  INTEGER ISAMAX
205  REAL SLAMCH
206  EXTERNAL lsame, isamax, slamch
207 * ..
208 * .. Intrinsic Functions ..
209  INTRINSIC abs, max, min
210 * ..
211 * .. Executable Statements ..
212 *
213 * Quick exit if N = 0 or NRHS = 0.
214 *
215  IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
216  reslts( 1 ) = zero
217  reslts( 2 ) = zero
218  RETURN
219  END IF
220 *
221  eps = slamch( 'Epsilon' )
222  unfl = slamch( 'Safe minimum' )
223  ovfl = one / unfl
224  notran = lsame( trans, 'N' )
225  nz = min( kl+ku+2, n+1 )
226 *
227 * Test 1: Compute the maximum of
228 * norm(X - XACT) / ( norm(X) * FERR )
229 * over all the vectors X and XACT using the infinity-norm.
230 *
231  errbnd = zero
232  DO 30 j = 1, nrhs
233  imax = isamax( n, x( 1, j ), 1 )
234  xnorm = max( abs( x( imax, j ) ), unfl )
235  diff = zero
236  DO 10 i = 1, n
237  diff = max( diff, abs( x( i, j )-xact( i, j ) ) )
238  10 CONTINUE
239 *
240  IF( xnorm.GT.one ) THEN
241  GO TO 20
242  ELSE IF( diff.LE.ovfl*xnorm ) THEN
243  GO TO 20
244  ELSE
245  errbnd = one / eps
246  GO TO 30
247  END IF
248 *
249  20 CONTINUE
250  IF( diff / xnorm.LE.ferr( j ) ) THEN
251  errbnd = max( errbnd, ( diff / xnorm ) / ferr( j ) )
252  ELSE
253  errbnd = one / eps
254  END IF
255  30 CONTINUE
256  reslts( 1 ) = errbnd
257 *
258 * Test 2: Compute the maximum of BERR / ( NZ*EPS + (*) ), where
259 * (*) = NZ*UNFL / (min_i (abs(op(A))*abs(X) +abs(b))_i )
260 *
261  DO 70 k = 1, nrhs
262  DO 60 i = 1, n
263  tmp = abs( b( i, k ) )
264  IF( notran ) THEN
265  DO 40 j = max( i-kl, 1 ), min( i+ku, n )
266  tmp = tmp + abs( ab( ku+1+i-j, j ) )*abs( x( j, k ) )
267  40 CONTINUE
268  ELSE
269  DO 50 j = max( i-ku, 1 ), min( i+kl, n )
270  tmp = tmp + abs( ab( ku+1+j-i, i ) )*abs( x( j, k ) )
271  50 CONTINUE
272  END IF
273  IF( i.EQ.1 ) THEN
274  axbi = tmp
275  ELSE
276  axbi = min( axbi, tmp )
277  END IF
278  60 CONTINUE
279  tmp = berr( k ) / ( nz*eps+nz*unfl / max( axbi, nz*unfl ) )
280  IF( k.EQ.1 ) THEN
281  reslts( 2 ) = tmp
282  ELSE
283  reslts( 2 ) = max( reslts( 2 ), tmp )
284  END IF
285  70 CONTINUE
286 *
287  RETURN
288 *
289 * End of SGBT05
290 *
291  END
subroutine sgbt05(TRANS, N, KL, KU, NRHS, AB, LDAB, B, LDB, X, LDX, XACT, LDXACT, FERR, BERR, RESLTS)
SGBT05
Definition: sgbt05.f:176