LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
zsprfs.f
Go to the documentation of this file.
1 *> \brief \b ZSPRFS
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZSPRFS + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zsprfs.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zsprfs.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zsprfs.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZSPRFS( UPLO, N, NRHS, AP, AFP, IPIV, B, LDB, X, LDX,
22 * FERR, BERR, WORK, RWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER UPLO
26 * INTEGER INFO, LDB, LDX, N, NRHS
27 * ..
28 * .. Array Arguments ..
29 * INTEGER IPIV( * )
30 * DOUBLE PRECISION BERR( * ), FERR( * ), RWORK( * )
31 * COMPLEX*16 AFP( * ), AP( * ), B( LDB, * ), WORK( * ),
32 * $ X( LDX, * )
33 * ..
34 *
35 *
36 *> \par Purpose:
37 * =============
38 *>
39 *> \verbatim
40 *>
41 *> ZSPRFS improves the computed solution to a system of linear
42 *> equations when the coefficient matrix is symmetric indefinite
43 *> and packed, and provides error bounds and backward error estimates
44 *> for the solution.
45 *> \endverbatim
46 *
47 * Arguments:
48 * ==========
49 *
50 *> \param[in] UPLO
51 *> \verbatim
52 *> UPLO is CHARACTER*1
53 *> = 'U': Upper triangle of A is stored;
54 *> = 'L': Lower triangle of A is stored.
55 *> \endverbatim
56 *>
57 *> \param[in] N
58 *> \verbatim
59 *> N is INTEGER
60 *> The order of the matrix A. N >= 0.
61 *> \endverbatim
62 *>
63 *> \param[in] NRHS
64 *> \verbatim
65 *> NRHS is INTEGER
66 *> The number of right hand sides, i.e., the number of columns
67 *> of the matrices B and X. NRHS >= 0.
68 *> \endverbatim
69 *>
70 *> \param[in] AP
71 *> \verbatim
72 *> AP is COMPLEX*16 array, dimension (N*(N+1)/2)
73 *> The upper or lower triangle of the symmetric matrix A, packed
74 *> columnwise in a linear array. The j-th column of A is stored
75 *> in the array AP as follows:
76 *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
77 *> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
78 *> \endverbatim
79 *>
80 *> \param[in] AFP
81 *> \verbatim
82 *> AFP is COMPLEX*16 array, dimension (N*(N+1)/2)
83 *> The factored form of the matrix A. AFP contains the block
84 *> diagonal matrix D and the multipliers used to obtain the
85 *> factor U or L from the factorization A = U*D*U**T or
86 *> A = L*D*L**T as computed by ZSPTRF, stored as a packed
87 *> triangular matrix.
88 *> \endverbatim
89 *>
90 *> \param[in] IPIV
91 *> \verbatim
92 *> IPIV is INTEGER array, dimension (N)
93 *> Details of the interchanges and the block structure of D
94 *> as determined by ZSPTRF.
95 *> \endverbatim
96 *>
97 *> \param[in] B
98 *> \verbatim
99 *> B is COMPLEX*16 array, dimension (LDB,NRHS)
100 *> The right hand side matrix B.
101 *> \endverbatim
102 *>
103 *> \param[in] LDB
104 *> \verbatim
105 *> LDB is INTEGER
106 *> The leading dimension of the array B. LDB >= max(1,N).
107 *> \endverbatim
108 *>
109 *> \param[in,out] X
110 *> \verbatim
111 *> X is COMPLEX*16 array, dimension (LDX,NRHS)
112 *> On entry, the solution matrix X, as computed by ZSPTRS.
113 *> On exit, the improved solution matrix X.
114 *> \endverbatim
115 *>
116 *> \param[in] LDX
117 *> \verbatim
118 *> LDX is INTEGER
119 *> The leading dimension of the array X. LDX >= max(1,N).
120 *> \endverbatim
121 *>
122 *> \param[out] FERR
123 *> \verbatim
124 *> FERR is DOUBLE PRECISION array, dimension (NRHS)
125 *> The estimated forward error bound for each solution vector
126 *> X(j) (the j-th column of the solution matrix X).
127 *> If XTRUE is the true solution corresponding to X(j), FERR(j)
128 *> is an estimated upper bound for the magnitude of the largest
129 *> element in (X(j) - XTRUE) divided by the magnitude of the
130 *> largest element in X(j). The estimate is as reliable as
131 *> the estimate for RCOND, and is almost always a slight
132 *> overestimate of the true error.
133 *> \endverbatim
134 *>
135 *> \param[out] BERR
136 *> \verbatim
137 *> BERR is DOUBLE PRECISION array, dimension (NRHS)
138 *> The componentwise relative backward error of each solution
139 *> vector X(j) (i.e., the smallest relative change in
140 *> any element of A or B that makes X(j) an exact solution).
141 *> \endverbatim
142 *>
143 *> \param[out] WORK
144 *> \verbatim
145 *> WORK is COMPLEX*16 array, dimension (2*N)
146 *> \endverbatim
147 *>
148 *> \param[out] RWORK
149 *> \verbatim
150 *> RWORK is DOUBLE PRECISION array, dimension (N)
151 *> \endverbatim
152 *>
153 *> \param[out] INFO
154 *> \verbatim
155 *> INFO is INTEGER
156 *> = 0: successful exit
157 *> < 0: if INFO = -i, the i-th argument had an illegal value
158 *> \endverbatim
159 *
160 *> \par Internal Parameters:
161 * =========================
162 *>
163 *> \verbatim
164 *> ITMAX is the maximum number of steps of iterative refinement.
165 *> \endverbatim
166 *
167 * Authors:
168 * ========
169 *
170 *> \author Univ. of Tennessee
171 *> \author Univ. of California Berkeley
172 *> \author Univ. of Colorado Denver
173 *> \author NAG Ltd.
174 *
175 *> \ingroup complex16OTHERcomputational
176 *
177 * =====================================================================
178  SUBROUTINE zsprfs( UPLO, N, NRHS, AP, AFP, IPIV, B, LDB, X, LDX,
179  $ FERR, BERR, WORK, RWORK, INFO )
180 *
181 * -- LAPACK computational routine --
182 * -- LAPACK is a software package provided by Univ. of Tennessee, --
183 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
184 *
185 * .. Scalar Arguments ..
186  CHARACTER UPLO
187  INTEGER INFO, LDB, LDX, N, NRHS
188 * ..
189 * .. Array Arguments ..
190  INTEGER IPIV( * )
191  DOUBLE PRECISION BERR( * ), FERR( * ), RWORK( * )
192  COMPLEX*16 AFP( * ), AP( * ), B( LDB, * ), WORK( * ),
193  $ x( ldx, * )
194 * ..
195 *
196 * =====================================================================
197 *
198 * .. Parameters ..
199  INTEGER ITMAX
200  parameter( itmax = 5 )
201  DOUBLE PRECISION ZERO
202  parameter( zero = 0.0d+0 )
203  COMPLEX*16 ONE
204  parameter( one = ( 1.0d+0, 0.0d+0 ) )
205  DOUBLE PRECISION TWO
206  parameter( two = 2.0d+0 )
207  DOUBLE PRECISION THREE
208  parameter( three = 3.0d+0 )
209 * ..
210 * .. Local Scalars ..
211  LOGICAL UPPER
212  INTEGER COUNT, I, IK, J, K, KASE, KK, NZ
213  DOUBLE PRECISION EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
214  COMPLEX*16 ZDUM
215 * ..
216 * .. Local Arrays ..
217  INTEGER ISAVE( 3 )
218 * ..
219 * .. External Subroutines ..
220  EXTERNAL xerbla, zaxpy, zcopy, zlacn2, zspmv, zsptrs
221 * ..
222 * .. Intrinsic Functions ..
223  INTRINSIC abs, dble, dimag, max
224 * ..
225 * .. External Functions ..
226  LOGICAL LSAME
227  DOUBLE PRECISION DLAMCH
228  EXTERNAL lsame, dlamch
229 * ..
230 * .. Statement Functions ..
231  DOUBLE PRECISION CABS1
232 * ..
233 * .. Statement Function definitions ..
234  cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
235 * ..
236 * .. Executable Statements ..
237 *
238 * Test the input parameters.
239 *
240  info = 0
241  upper = lsame( uplo, 'U' )
242  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
243  info = -1
244  ELSE IF( n.LT.0 ) THEN
245  info = -2
246  ELSE IF( nrhs.LT.0 ) THEN
247  info = -3
248  ELSE IF( ldb.LT.max( 1, n ) ) THEN
249  info = -8
250  ELSE IF( ldx.LT.max( 1, n ) ) THEN
251  info = -10
252  END IF
253  IF( info.NE.0 ) THEN
254  CALL xerbla( 'ZSPRFS', -info )
255  RETURN
256  END IF
257 *
258 * Quick return if possible
259 *
260  IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
261  DO 10 j = 1, nrhs
262  ferr( j ) = zero
263  berr( j ) = zero
264  10 CONTINUE
265  RETURN
266  END IF
267 *
268 * NZ = maximum number of nonzero elements in each row of A, plus 1
269 *
270  nz = n + 1
271  eps = dlamch( 'Epsilon' )
272  safmin = dlamch( 'Safe minimum' )
273  safe1 = nz*safmin
274  safe2 = safe1 / eps
275 *
276 * Do for each right hand side
277 *
278  DO 140 j = 1, nrhs
279 *
280  count = 1
281  lstres = three
282  20 CONTINUE
283 *
284 * Loop until stopping criterion is satisfied.
285 *
286 * Compute residual R = B - A * X
287 *
288  CALL zcopy( n, b( 1, j ), 1, work, 1 )
289  CALL zspmv( uplo, n, -one, ap, x( 1, j ), 1, one, work, 1 )
290 *
291 * Compute componentwise relative backward error from formula
292 *
293 * max(i) ( abs(R(i)) / ( abs(A)*abs(X) + abs(B) )(i) )
294 *
295 * where abs(Z) is the componentwise absolute value of the matrix
296 * or vector Z. If the i-th component of the denominator is less
297 * than SAFE2, then SAFE1 is added to the i-th components of the
298 * numerator and denominator before dividing.
299 *
300  DO 30 i = 1, n
301  rwork( i ) = cabs1( b( i, j ) )
302  30 CONTINUE
303 *
304 * Compute abs(A)*abs(X) + abs(B).
305 *
306  kk = 1
307  IF( upper ) THEN
308  DO 50 k = 1, n
309  s = zero
310  xk = cabs1( x( k, j ) )
311  ik = kk
312  DO 40 i = 1, k - 1
313  rwork( i ) = rwork( i ) + cabs1( ap( ik ) )*xk
314  s = s + cabs1( ap( ik ) )*cabs1( x( i, j ) )
315  ik = ik + 1
316  40 CONTINUE
317  rwork( k ) = rwork( k ) + cabs1( ap( kk+k-1 ) )*xk + s
318  kk = kk + k
319  50 CONTINUE
320  ELSE
321  DO 70 k = 1, n
322  s = zero
323  xk = cabs1( x( k, j ) )
324  rwork( k ) = rwork( k ) + cabs1( ap( kk ) )*xk
325  ik = kk + 1
326  DO 60 i = k + 1, n
327  rwork( i ) = rwork( i ) + cabs1( ap( ik ) )*xk
328  s = s + cabs1( ap( ik ) )*cabs1( x( i, j ) )
329  ik = ik + 1
330  60 CONTINUE
331  rwork( k ) = rwork( k ) + s
332  kk = kk + ( n-k+1 )
333  70 CONTINUE
334  END IF
335  s = zero
336  DO 80 i = 1, n
337  IF( rwork( i ).GT.safe2 ) THEN
338  s = max( s, cabs1( work( i ) ) / rwork( i ) )
339  ELSE
340  s = max( s, ( cabs1( work( i ) )+safe1 ) /
341  $ ( rwork( i )+safe1 ) )
342  END IF
343  80 CONTINUE
344  berr( j ) = s
345 *
346 * Test stopping criterion. Continue iterating if
347 * 1) The residual BERR(J) is larger than machine epsilon, and
348 * 2) BERR(J) decreased by at least a factor of 2 during the
349 * last iteration, and
350 * 3) At most ITMAX iterations tried.
351 *
352  IF( berr( j ).GT.eps .AND. two*berr( j ).LE.lstres .AND.
353  $ count.LE.itmax ) THEN
354 *
355 * Update solution and try again.
356 *
357  CALL zsptrs( uplo, n, 1, afp, ipiv, work, n, info )
358  CALL zaxpy( n, one, work, 1, x( 1, j ), 1 )
359  lstres = berr( j )
360  count = count + 1
361  GO TO 20
362  END IF
363 *
364 * Bound error from formula
365 *
366 * norm(X - XTRUE) / norm(X) .le. FERR =
367 * norm( abs(inv(A))*
368 * ( abs(R) + NZ*EPS*( abs(A)*abs(X)+abs(B) ))) / norm(X)
369 *
370 * where
371 * norm(Z) is the magnitude of the largest component of Z
372 * inv(A) is the inverse of A
373 * abs(Z) is the componentwise absolute value of the matrix or
374 * vector Z
375 * NZ is the maximum number of nonzeros in any row of A, plus 1
376 * EPS is machine epsilon
377 *
378 * The i-th component of abs(R)+NZ*EPS*(abs(A)*abs(X)+abs(B))
379 * is incremented by SAFE1 if the i-th component of
380 * abs(A)*abs(X) + abs(B) is less than SAFE2.
381 *
382 * Use ZLACN2 to estimate the infinity-norm of the matrix
383 * inv(A) * diag(W),
384 * where W = abs(R) + NZ*EPS*( abs(A)*abs(X)+abs(B) )))
385 *
386  DO 90 i = 1, n
387  IF( rwork( i ).GT.safe2 ) THEN
388  rwork( i ) = cabs1( work( i ) ) + nz*eps*rwork( i )
389  ELSE
390  rwork( i ) = cabs1( work( i ) ) + nz*eps*rwork( i ) +
391  $ safe1
392  END IF
393  90 CONTINUE
394 *
395  kase = 0
396  100 CONTINUE
397  CALL zlacn2( n, work( n+1 ), work, ferr( j ), kase, isave )
398  IF( kase.NE.0 ) THEN
399  IF( kase.EQ.1 ) THEN
400 *
401 * Multiply by diag(W)*inv(A**T).
402 *
403  CALL zsptrs( uplo, n, 1, afp, ipiv, work, n, info )
404  DO 110 i = 1, n
405  work( i ) = rwork( i )*work( i )
406  110 CONTINUE
407  ELSE IF( kase.EQ.2 ) THEN
408 *
409 * Multiply by inv(A)*diag(W).
410 *
411  DO 120 i = 1, n
412  work( i ) = rwork( i )*work( i )
413  120 CONTINUE
414  CALL zsptrs( uplo, n, 1, afp, ipiv, work, n, info )
415  END IF
416  GO TO 100
417  END IF
418 *
419 * Normalize error.
420 *
421  lstres = zero
422  DO 130 i = 1, n
423  lstres = max( lstres, cabs1( x( i, j ) ) )
424  130 CONTINUE
425  IF( lstres.NE.zero )
426  $ ferr( j ) = ferr( j ) / lstres
427 *
428  140 CONTINUE
429 *
430  RETURN
431 *
432 * End of ZSPRFS
433 *
434  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine zaxpy(N, ZA, ZX, INCX, ZY, INCY)
ZAXPY
Definition: zaxpy.f:88
subroutine zcopy(N, ZX, INCX, ZY, INCY)
ZCOPY
Definition: zcopy.f:81
subroutine zlacn2(N, V, X, EST, KASE, ISAVE)
ZLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: zlacn2.f:133
subroutine zspmv(UPLO, N, ALPHA, AP, X, INCX, BETA, Y, INCY)
ZSPMV computes a matrix-vector product for complex vectors using a complex symmetric packed matrix
Definition: zspmv.f:151
subroutine zsprfs(UPLO, N, NRHS, AP, AFP, IPIV, B, LDB, X, LDX, FERR, BERR, WORK, RWORK, INFO)
ZSPRFS
Definition: zsprfs.f:180
subroutine zsptrs(UPLO, N, NRHS, AP, IPIV, B, LDB, INFO)
ZSPTRS
Definition: zsptrs.f:115