LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
zhpcon.f
Go to the documentation of this file.
1 *> \brief \b ZHPCON
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZHPCON + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zhpcon.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zhpcon.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zhpcon.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZHPCON( UPLO, N, AP, IPIV, ANORM, RCOND, WORK, INFO )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER UPLO
25 * INTEGER INFO, N
26 * DOUBLE PRECISION ANORM, RCOND
27 * ..
28 * .. Array Arguments ..
29 * INTEGER IPIV( * )
30 * COMPLEX*16 AP( * ), WORK( * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> ZHPCON estimates the reciprocal of the condition number of a complex
40 *> Hermitian packed matrix A using the factorization A = U*D*U**H or
41 *> A = L*D*L**H computed by ZHPTRF.
42 *>
43 *> An estimate is obtained for norm(inv(A)), and the reciprocal of the
44 *> condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
45 *> \endverbatim
46 *
47 * Arguments:
48 * ==========
49 *
50 *> \param[in] UPLO
51 *> \verbatim
52 *> UPLO is CHARACTER*1
53 *> Specifies whether the details of the factorization are stored
54 *> as an upper or lower triangular matrix.
55 *> = 'U': Upper triangular, form is A = U*D*U**H;
56 *> = 'L': Lower triangular, form is A = L*D*L**H.
57 *> \endverbatim
58 *>
59 *> \param[in] N
60 *> \verbatim
61 *> N is INTEGER
62 *> The order of the matrix A. N >= 0.
63 *> \endverbatim
64 *>
65 *> \param[in] AP
66 *> \verbatim
67 *> AP is COMPLEX*16 array, dimension (N*(N+1)/2)
68 *> The block diagonal matrix D and the multipliers used to
69 *> obtain the factor U or L as computed by ZHPTRF, stored as a
70 *> packed triangular matrix.
71 *> \endverbatim
72 *>
73 *> \param[in] IPIV
74 *> \verbatim
75 *> IPIV is INTEGER array, dimension (N)
76 *> Details of the interchanges and the block structure of D
77 *> as determined by ZHPTRF.
78 *> \endverbatim
79 *>
80 *> \param[in] ANORM
81 *> \verbatim
82 *> ANORM is DOUBLE PRECISION
83 *> The 1-norm of the original matrix A.
84 *> \endverbatim
85 *>
86 *> \param[out] RCOND
87 *> \verbatim
88 *> RCOND is DOUBLE PRECISION
89 *> The reciprocal of the condition number of the matrix A,
90 *> computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
91 *> estimate of the 1-norm of inv(A) computed in this routine.
92 *> \endverbatim
93 *>
94 *> \param[out] WORK
95 *> \verbatim
96 *> WORK is COMPLEX*16 array, dimension (2*N)
97 *> \endverbatim
98 *>
99 *> \param[out] INFO
100 *> \verbatim
101 *> INFO is INTEGER
102 *> = 0: successful exit
103 *> < 0: if INFO = -i, the i-th argument had an illegal value
104 *> \endverbatim
105 *
106 * Authors:
107 * ========
108 *
109 *> \author Univ. of Tennessee
110 *> \author Univ. of California Berkeley
111 *> \author Univ. of Colorado Denver
112 *> \author NAG Ltd.
113 *
114 *> \ingroup complex16OTHERcomputational
115 *
116 * =====================================================================
117  SUBROUTINE zhpcon( UPLO, N, AP, IPIV, ANORM, RCOND, WORK, INFO )
118 *
119 * -- LAPACK computational routine --
120 * -- LAPACK is a software package provided by Univ. of Tennessee, --
121 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
122 *
123 * .. Scalar Arguments ..
124  CHARACTER UPLO
125  INTEGER INFO, N
126  DOUBLE PRECISION ANORM, RCOND
127 * ..
128 * .. Array Arguments ..
129  INTEGER IPIV( * )
130  COMPLEX*16 AP( * ), WORK( * )
131 * ..
132 *
133 * =====================================================================
134 *
135 * .. Parameters ..
136  DOUBLE PRECISION ONE, ZERO
137  parameter( one = 1.0d+0, zero = 0.0d+0 )
138 * ..
139 * .. Local Scalars ..
140  LOGICAL UPPER
141  INTEGER I, IP, KASE
142  DOUBLE PRECISION AINVNM
143 * ..
144 * .. Local Arrays ..
145  INTEGER ISAVE( 3 )
146 * ..
147 * .. External Functions ..
148  LOGICAL LSAME
149  EXTERNAL lsame
150 * ..
151 * .. External Subroutines ..
152  EXTERNAL xerbla, zhptrs, zlacn2
153 * ..
154 * .. Executable Statements ..
155 *
156 * Test the input parameters.
157 *
158  info = 0
159  upper = lsame( uplo, 'U' )
160  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
161  info = -1
162  ELSE IF( n.LT.0 ) THEN
163  info = -2
164  ELSE IF( anorm.LT.zero ) THEN
165  info = -5
166  END IF
167  IF( info.NE.0 ) THEN
168  CALL xerbla( 'ZHPCON', -info )
169  RETURN
170  END IF
171 *
172 * Quick return if possible
173 *
174  rcond = zero
175  IF( n.EQ.0 ) THEN
176  rcond = one
177  RETURN
178  ELSE IF( anorm.LE.zero ) THEN
179  RETURN
180  END IF
181 *
182 * Check that the diagonal matrix D is nonsingular.
183 *
184  IF( upper ) THEN
185 *
186 * Upper triangular storage: examine D from bottom to top
187 *
188  ip = n*( n+1 ) / 2
189  DO 10 i = n, 1, -1
190  IF( ipiv( i ).GT.0 .AND. ap( ip ).EQ.zero )
191  $ RETURN
192  ip = ip - i
193  10 CONTINUE
194  ELSE
195 *
196 * Lower triangular storage: examine D from top to bottom.
197 *
198  ip = 1
199  DO 20 i = 1, n
200  IF( ipiv( i ).GT.0 .AND. ap( ip ).EQ.zero )
201  $ RETURN
202  ip = ip + n - i + 1
203  20 CONTINUE
204  END IF
205 *
206 * Estimate the 1-norm of the inverse.
207 *
208  kase = 0
209  30 CONTINUE
210  CALL zlacn2( n, work( n+1 ), work, ainvnm, kase, isave )
211  IF( kase.NE.0 ) THEN
212 *
213 * Multiply by inv(L*D*L**H) or inv(U*D*U**H).
214 *
215  CALL zhptrs( uplo, n, 1, ap, ipiv, work, n, info )
216  GO TO 30
217  END IF
218 *
219 * Compute the estimate of the reciprocal condition number.
220 *
221  IF( ainvnm.NE.zero )
222  $ rcond = ( one / ainvnm ) / anorm
223 *
224  RETURN
225 *
226 * End of ZHPCON
227 *
228  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine zlacn2(N, V, X, EST, KASE, ISAVE)
ZLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: zlacn2.f:133
subroutine zhpcon(UPLO, N, AP, IPIV, ANORM, RCOND, WORK, INFO)
ZHPCON
Definition: zhpcon.f:118
subroutine zhptrs(UPLO, N, NRHS, AP, IPIV, B, LDB, INFO)
ZHPTRS
Definition: zhptrs.f:115