LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ ctgsna()

 subroutine ctgsna ( character job, character howmny, logical, dimension( * ) select, integer n, complex, dimension( lda, * ) a, integer lda, complex, dimension( ldb, * ) b, integer ldb, complex, dimension( ldvl, * ) vl, integer ldvl, complex, dimension( ldvr, * ) vr, integer ldvr, real, dimension( * ) s, real, dimension( * ) dif, integer mm, integer m, complex, dimension( * ) work, integer lwork, integer, dimension( * ) iwork, integer info )

CTGSNA

Purpose:
``` CTGSNA estimates reciprocal condition numbers for specified
eigenvalues and/or eigenvectors of a matrix pair (A, B).

(A, B) must be in generalized Schur canonical form, that is, A and
B are both upper triangular.```
Parameters
 [in] JOB ``` JOB is CHARACTER*1 Specifies whether condition numbers are required for eigenvalues (S) or eigenvectors (DIF): = 'E': for eigenvalues only (S); = 'V': for eigenvectors only (DIF); = 'B': for both eigenvalues and eigenvectors (S and DIF).``` [in] HOWMNY ``` HOWMNY is CHARACTER*1 = 'A': compute condition numbers for all eigenpairs; = 'S': compute condition numbers for selected eigenpairs specified by the array SELECT.``` [in] SELECT ``` SELECT is LOGICAL array, dimension (N) If HOWMNY = 'S', SELECT specifies the eigenpairs for which condition numbers are required. To select condition numbers for the corresponding j-th eigenvalue and/or eigenvector, SELECT(j) must be set to .TRUE.. If HOWMNY = 'A', SELECT is not referenced.``` [in] N ``` N is INTEGER The order of the square matrix pair (A, B). N >= 0.``` [in] A ``` A is COMPLEX array, dimension (LDA,N) The upper triangular matrix A in the pair (A,B).``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).``` [in] B ``` B is COMPLEX array, dimension (LDB,N) The upper triangular matrix B in the pair (A, B).``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).``` [in] VL ``` VL is COMPLEX array, dimension (LDVL,M) IF JOB = 'E' or 'B', VL must contain left eigenvectors of (A, B), corresponding to the eigenpairs specified by HOWMNY and SELECT. The eigenvectors must be stored in consecutive columns of VL, as returned by CTGEVC. If JOB = 'V', VL is not referenced.``` [in] LDVL ``` LDVL is INTEGER The leading dimension of the array VL. LDVL >= 1; and If JOB = 'E' or 'B', LDVL >= N.``` [in] VR ``` VR is COMPLEX array, dimension (LDVR,M) IF JOB = 'E' or 'B', VR must contain right eigenvectors of (A, B), corresponding to the eigenpairs specified by HOWMNY and SELECT. The eigenvectors must be stored in consecutive columns of VR, as returned by CTGEVC. If JOB = 'V', VR is not referenced.``` [in] LDVR ``` LDVR is INTEGER The leading dimension of the array VR. LDVR >= 1; If JOB = 'E' or 'B', LDVR >= N.``` [out] S ``` S is REAL array, dimension (MM) If JOB = 'E' or 'B', the reciprocal condition numbers of the selected eigenvalues, stored in consecutive elements of the array. If JOB = 'V', S is not referenced.``` [out] DIF ``` DIF is REAL array, dimension (MM) If JOB = 'V' or 'B', the estimated reciprocal condition numbers of the selected eigenvectors, stored in consecutive elements of the array. If the eigenvalues cannot be reordered to compute DIF(j), DIF(j) is set to 0; this can only occur when the true value would be very small anyway. For each eigenvalue/vector specified by SELECT, DIF stores a Frobenius norm-based estimate of Difl. If JOB = 'E', DIF is not referenced.``` [in] MM ``` MM is INTEGER The number of elements in the arrays S and DIF. MM >= M.``` [out] M ``` M is INTEGER The number of elements of the arrays S and DIF used to store the specified condition numbers; for each selected eigenvalue one element is used. If HOWMNY = 'A', M is set to N.``` [out] WORK ``` WORK is COMPLEX array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.``` [in] LWORK ``` LWORK is INTEGER The dimension of the array WORK. LWORK >= max(1,N). If JOB = 'V' or 'B', LWORK >= max(1,2*N*N).``` [out] IWORK ``` IWORK is INTEGER array, dimension (N+2) If JOB = 'E', IWORK is not referenced.``` [out] INFO ``` INFO is INTEGER = 0: Successful exit < 0: If INFO = -i, the i-th argument had an illegal value```
Further Details:
```  The reciprocal of the condition number of the i-th generalized
eigenvalue w = (a, b) is defined as

S(I) = (|v**HAu|**2 + |v**HBu|**2)**(1/2) / (norm(u)*norm(v))

where u and v are the right and left eigenvectors of (A, B)
corresponding to w; |z| denotes the absolute value of the complex
number, and norm(u) denotes the 2-norm of the vector u. The pair
(a, b) corresponds to an eigenvalue w = a/b (= v**HAu/v**HBu) of the
matrix pair (A, B). If both a and b equal zero, then (A,B) is
singular and S(I) = -1 is returned.

An approximate error bound on the chordal distance between the i-th
computed generalized eigenvalue w and the corresponding exact
eigenvalue lambda is

chord(w, lambda) <=   EPS * norm(A, B) / S(I),

where EPS is the machine precision.

The reciprocal of the condition number of the right eigenvector u
and left eigenvector v corresponding to the generalized eigenvalue w
is defined as follows. Suppose

(A, B) = ( a   *  ) ( b  *  )  1
( 0  A22 ),( 0 B22 )  n-1
1  n-1     1 n-1

Then the reciprocal condition number DIF(I) is

Difl[(a, b), (A22, B22)]  = sigma-min( Zl )

where sigma-min(Zl) denotes the smallest singular value of

Zl = [ kron(a, In-1) -kron(1, A22) ]
[ kron(b, In-1) -kron(1, B22) ].

Here In-1 is the identity matrix of size n-1 and X**H is the conjugate
transpose of X. kron(X, Y) is the Kronecker product between the
matrices X and Y.

We approximate the smallest singular value of Zl with an upper
bound. This is done by CLATDF.

An approximate error bound for a computed eigenvector VL(i) or
VR(i) is given by

EPS * norm(A, B) / DIF(i).

See ref. [2-3] for more details and further references.```
Contributors:
Bo Kagstrom and Peter Poromaa, Department of Computing Science, Umea University, S-901 87 Umea, Sweden.
References:
```  [1] B. Kagstrom; A Direct Method for Reordering Eigenvalues in the
Generalized Real Schur Form of a Regular Matrix Pair (A, B), in
M.S. Moonen et al (eds), Linear Algebra for Large Scale and
Real-Time Applications, Kluwer Academic Publ. 1993, pp 195-218.

[2] B. Kagstrom and P. Poromaa; Computing Eigenspaces with Specified
Eigenvalues of a Regular Matrix Pair (A, B) and Condition
Estimation: Theory, Algorithms and Software, Report
UMINF - 94.04, Department of Computing Science, Umea University,
S-901 87 Umea, Sweden, 1994. Also as LAPACK Working Note 87.
To appear in Numerical Algorithms, 1996.

[3] B. Kagstrom and P. Poromaa, LAPACK-Style Algorithms and Software
for Solving the Generalized Sylvester Equation and Estimating the
Separation between Regular Matrix Pairs, Report UMINF - 93.23,
Department of Computing Science, Umea University, S-901 87 Umea,
Sweden, December 1993, Revised April 1994, Also as LAPACK Working
Note 75.
To appear in ACM Trans. on Math. Software, Vol 22, No 1, 1996.```

Definition at line 308 of file ctgsna.f.

311*
312* -- LAPACK computational routine --
313* -- LAPACK is a software package provided by Univ. of Tennessee, --
314* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
315*
316* .. Scalar Arguments ..
317 CHARACTER HOWMNY, JOB
318 INTEGER INFO, LDA, LDB, LDVL, LDVR, LWORK, M, MM, N
319* ..
320* .. Array Arguments ..
321 LOGICAL SELECT( * )
322 INTEGER IWORK( * )
323 REAL DIF( * ), S( * )
324 COMPLEX A( LDA, * ), B( LDB, * ), VL( LDVL, * ),
325 \$ VR( LDVR, * ), WORK( * )
326* ..
327*
328* =====================================================================
329*
330* .. Parameters ..
331 REAL ZERO, ONE
332 INTEGER IDIFJB
333 parameter( zero = 0.0e+0, one = 1.0e+0, idifjb = 3 )
334* ..
335* .. Local Scalars ..
336 LOGICAL LQUERY, SOMCON, WANTBH, WANTDF, WANTS
337 INTEGER I, IERR, IFST, ILST, K, KS, LWMIN, N1, N2
338 REAL BIGNUM, COND, EPS, LNRM, RNRM, SCALE, SMLNUM
339 COMPLEX YHAX, YHBX
340* ..
341* .. Local Arrays ..
342 COMPLEX DUMMY( 1 ), DUMMY1( 1 )
343* ..
344* .. External Functions ..
345 LOGICAL LSAME
346 REAL SCNRM2, SLAMCH, SLAPY2, SROUNDUP_LWORK
347 COMPLEX CDOTC
349 \$ cdotc
350* ..
351* .. External Subroutines ..
352 EXTERNAL cgemv, clacpy, ctgexc, ctgsyl, xerbla
353* ..
354* .. Intrinsic Functions ..
355 INTRINSIC abs, cmplx, max
356* ..
357* .. Executable Statements ..
358*
359* Decode and test the input parameters
360*
361 wantbh = lsame( job, 'B' )
362 wants = lsame( job, 'E' ) .OR. wantbh
363 wantdf = lsame( job, 'V' ) .OR. wantbh
364*
365 somcon = lsame( howmny, 'S' )
366*
367 info = 0
368 lquery = ( lwork.EQ.-1 )
369*
370 IF( .NOT.wants .AND. .NOT.wantdf ) THEN
371 info = -1
372 ELSE IF( .NOT.lsame( howmny, 'A' ) .AND. .NOT.somcon ) THEN
373 info = -2
374 ELSE IF( n.LT.0 ) THEN
375 info = -4
376 ELSE IF( lda.LT.max( 1, n ) ) THEN
377 info = -6
378 ELSE IF( ldb.LT.max( 1, n ) ) THEN
379 info = -8
380 ELSE IF( wants .AND. ldvl.LT.n ) THEN
381 info = -10
382 ELSE IF( wants .AND. ldvr.LT.n ) THEN
383 info = -12
384 ELSE
385*
386* Set M to the number of eigenpairs for which condition numbers
387* are required, and test MM.
388*
389 IF( somcon ) THEN
390 m = 0
391 DO 10 k = 1, n
392 IF( SELECT( k ) )
393 \$ m = m + 1
394 10 CONTINUE
395 ELSE
396 m = n
397 END IF
398*
399 IF( n.EQ.0 ) THEN
400 lwmin = 1
401 ELSE IF( lsame( job, 'V' ) .OR. lsame( job, 'B' ) ) THEN
402 lwmin = 2*n*n
403 ELSE
404 lwmin = n
405 END IF
406 work( 1 ) = sroundup_lwork(lwmin)
407*
408 IF( mm.LT.m ) THEN
409 info = -15
410 ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
411 info = -18
412 END IF
413 END IF
414*
415 IF( info.NE.0 ) THEN
416 CALL xerbla( 'CTGSNA', -info )
417 RETURN
418 ELSE IF( lquery ) THEN
419 RETURN
420 END IF
421*
422* Quick return if possible
423*
424 IF( n.EQ.0 )
425 \$ RETURN
426*
427* Get machine constants
428*
429 eps = slamch( 'P' )
430 smlnum = slamch( 'S' ) / eps
431 bignum = one / smlnum
432 ks = 0
433 DO 20 k = 1, n
434*
435* Determine whether condition numbers are required for the k-th
436* eigenpair.
437*
438 IF( somcon ) THEN
439 IF( .NOT.SELECT( k ) )
440 \$ GO TO 20
441 END IF
442*
443 ks = ks + 1
444*
445 IF( wants ) THEN
446*
447* Compute the reciprocal condition number of the k-th
448* eigenvalue.
449*
450 rnrm = scnrm2( n, vr( 1, ks ), 1 )
451 lnrm = scnrm2( n, vl( 1, ks ), 1 )
452 CALL cgemv( 'N', n, n, cmplx( one, zero ), a, lda,
453 \$ vr( 1, ks ), 1, cmplx( zero, zero ), work, 1 )
454 yhax = cdotc( n, work, 1, vl( 1, ks ), 1 )
455 CALL cgemv( 'N', n, n, cmplx( one, zero ), b, ldb,
456 \$ vr( 1, ks ), 1, cmplx( zero, zero ), work, 1 )
457 yhbx = cdotc( n, work, 1, vl( 1, ks ), 1 )
458 cond = slapy2( abs( yhax ), abs( yhbx ) )
459 IF( cond.EQ.zero ) THEN
460 s( ks ) = -one
461 ELSE
462 s( ks ) = cond / ( rnrm*lnrm )
463 END IF
464 END IF
465*
466 IF( wantdf ) THEN
467 IF( n.EQ.1 ) THEN
468 dif( ks ) = slapy2( abs( a( 1, 1 ) ), abs( b( 1, 1 ) ) )
469 ELSE
470*
471* Estimate the reciprocal condition number of the k-th
472* eigenvectors.
473*
474* Copy the matrix (A, B) to the array WORK and move the
475* (k,k)th pair to the (1,1) position.
476*
477 CALL clacpy( 'Full', n, n, a, lda, work, n )
478 CALL clacpy( 'Full', n, n, b, ldb, work( n*n+1 ), n )
479 ifst = k
480 ilst = 1
481*
482 CALL ctgexc( .false., .false., n, work, n, work( n*n+1 ),
483 \$ n, dummy, 1, dummy1, 1, ifst, ilst, ierr )
484*
485 IF( ierr.GT.0 ) THEN
486*
487* Ill-conditioned problem - swap rejected.
488*
489 dif( ks ) = zero
490 ELSE
491*
492* Reordering successful, solve generalized Sylvester
493* equation for R and L,
494* A22 * R - L * A11 = A12
495* B22 * R - L * B11 = B12,
496* and compute estimate of Difl[(A11,B11), (A22, B22)].
497*
498 n1 = 1
499 n2 = n - n1
500 i = n*n + 1
501 CALL ctgsyl( 'N', idifjb, n2, n1, work( n*n1+n1+1 ),
502 \$ n, work, n, work( n1+1 ), n,
503 \$ work( n*n1+n1+i ), n, work( i ), n,
504 \$ work( n1+i ), n, scale, dif( ks ), dummy,
505 \$ 1, iwork, ierr )
506 END IF
507 END IF
508 END IF
509*
510 20 CONTINUE
511 work( 1 ) = sroundup_lwork(lwmin)
512 RETURN
513*
514* End of CTGSNA
515*
subroutine xerbla(srname, info)
Definition cblat2.f:3285
complex function cdotc(n, cx, incx, cy, incy)
CDOTC
Definition cdotc.f:83
subroutine cgemv(trans, m, n, alpha, a, lda, x, incx, beta, y, incy)
CGEMV
Definition cgemv.f:160
subroutine clacpy(uplo, m, n, a, lda, b, ldb)
CLACPY copies all or part of one two-dimensional array to another.
Definition clacpy.f:103
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
real function slapy2(x, y)
SLAPY2 returns sqrt(x2+y2).
Definition slapy2.f:63
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
real(wp) function scnrm2(n, x, incx)
SCNRM2
Definition scnrm2.f90:90
real function sroundup_lwork(lwork)
SROUNDUP_LWORK
subroutine ctgexc(wantq, wantz, n, a, lda, b, ldb, q, ldq, z, ldz, ifst, ilst, info)
CTGEXC
Definition ctgexc.f:200
subroutine ctgsyl(trans, ijob, m, n, a, lda, b, ldb, c, ldc, d, ldd, e, lde, f, ldf, scale, dif, work, lwork, iwork, info)
CTGSYL
Definition ctgsyl.f:295
Here is the call graph for this function:
Here is the caller graph for this function: