 LAPACK  3.10.0 LAPACK: Linear Algebra PACKage

◆ ztbt02()

 subroutine ztbt02 ( character UPLO, character TRANS, character DIAG, integer N, integer KD, integer NRHS, complex*16, dimension( ldab, * ) AB, integer LDAB, complex*16, dimension( ldx, * ) X, integer LDX, complex*16, dimension( ldb, * ) B, integer LDB, complex*16, dimension( * ) WORK, double precision, dimension( * ) RWORK, double precision RESID )

ZTBT02

Purpose:
ZTBT02 computes the residual for the computed solution to a
triangular system of linear equations  A*x = b,  A**T *x = b,  or
A**H *x = b  when A is a triangular band matrix.  Here A**T denotes
the transpose of A, A**H denotes the conjugate transpose of A, and
x and b are N by NRHS matrices.  The test ratio is the maximum over
the number of right hand sides of
norm(b - op(A)*x) / ( norm(op(A)) * norm(x) * EPS ),
where op(A) denotes A, A**T, or A**H, and EPS is the machine epsilon.
Parameters
 [in] UPLO UPLO is CHARACTER*1 Specifies whether the matrix A is upper or lower triangular. = 'U': Upper triangular = 'L': Lower triangular [in] TRANS TRANS is CHARACTER*1 Specifies the operation applied to A. = 'N': A * X = B (No transpose) = 'T': A**T * X = B (Transpose) = 'C': A**H * X = B (Conjugate transpose) [in] DIAG DIAG is CHARACTER*1 Specifies whether or not the matrix A is unit triangular. = 'N': Non-unit triangular = 'U': Unit triangular [in] N N is INTEGER The order of the matrix A. N >= 0. [in] KD KD is INTEGER The number of superdiagonals or subdiagonals of the triangular band matrix A. KD >= 0. [in] NRHS NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrices X and B. NRHS >= 0. [in] AB AB is COMPLEX*16 array, dimension (LDA,N) The upper or lower triangular band matrix A, stored in the first kd+1 rows of the array. The j-th column of A is stored in the j-th column of the array AB as follows: if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j; if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd). [in] LDAB LDAB is INTEGER The leading dimension of the array AB. LDAB >= max(1,KD+1). [in] X X is COMPLEX*16 array, dimension (LDX,NRHS) The computed solution vectors for the system of linear equations. [in] LDX LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N). [in] B B is COMPLEX*16 array, dimension (LDB,NRHS) The right hand side vectors for the system of linear equations. [in] LDB LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N). [out] WORK WORK is COMPLEX*16 array, dimension (N) [out] RWORK RWORK is DOUBLE PRECISION array, dimension (N) [out] RESID RESID is DOUBLE PRECISION The maximum over the number of right hand sides of norm(B - op(A)*X) / ( norm(op(A)) * norm(X) * EPS ).

Definition at line 159 of file ztbt02.f.

161 *
162 * -- LAPACK test routine --
163 * -- LAPACK is a software package provided by Univ. of Tennessee, --
164 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
165 *
166 * .. Scalar Arguments ..
167  CHARACTER DIAG, TRANS, UPLO
168  INTEGER KD, LDAB, LDB, LDX, N, NRHS
169  DOUBLE PRECISION RESID
170 * ..
171 * .. Array Arguments ..
172  DOUBLE PRECISION RWORK( * )
173  COMPLEX*16 AB( LDAB, * ), B( LDB, * ), WORK( * ),
174  \$ X( LDX, * )
175 * ..
176 *
177 * =====================================================================
178 *
179 * .. Parameters ..
180  DOUBLE PRECISION ZERO, ONE
181  parameter( zero = 0.0d+0, one = 1.0d+0 )
182 * ..
183 * .. Local Scalars ..
184  INTEGER J
185  DOUBLE PRECISION ANORM, BNORM, EPS, XNORM
186 * ..
187 * .. External Functions ..
188  LOGICAL LSAME
189  DOUBLE PRECISION DLAMCH, DZASUM, ZLANTB
190  EXTERNAL lsame, dlamch, dzasum, zlantb
191 * ..
192 * .. External Subroutines ..
193  EXTERNAL zaxpy, zcopy, ztbmv
194 * ..
195 * .. Intrinsic Functions ..
196  INTRINSIC dcmplx, max
197 * ..
198 * .. Executable Statements ..
199 *
200 * Quick exit if N = 0 or NRHS = 0
201 *
202  IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
203  resid = zero
204  RETURN
205  END IF
206 *
207 * Compute the 1-norm of op(A).
208 *
209  IF( lsame( trans, 'N' ) ) THEN
210  anorm = zlantb( '1', uplo, diag, n, kd, ab, ldab, rwork )
211  ELSE
212  anorm = zlantb( 'I', uplo, diag, n, kd, ab, ldab, rwork )
213  END IF
214 *
215 * Exit with RESID = 1/EPS if ANORM = 0.
216 *
217  eps = dlamch( 'Epsilon' )
218  IF( anorm.LE.zero ) THEN
219  resid = one / eps
220  RETURN
221  END IF
222 *
223 * Compute the maximum over the number of right hand sides of
224 * norm(B - op(A)*X) / ( norm(op(A)) * norm(X) * EPS ).
225 *
226  resid = zero
227  DO 10 j = 1, nrhs
228  CALL zcopy( n, x( 1, j ), 1, work, 1 )
229  CALL ztbmv( uplo, trans, diag, n, kd, ab, ldab, work, 1 )
230  CALL zaxpy( n, dcmplx( -one ), b( 1, j ), 1, work, 1 )
231  bnorm = dzasum( n, work, 1 )
232  xnorm = dzasum( n, x( 1, j ), 1 )
233  IF( xnorm.LE.zero ) THEN
234  resid = one / eps
235  ELSE
236  resid = max( resid, ( ( bnorm / anorm ) / xnorm ) / eps )
237  END IF
238  10 CONTINUE
239 *
240  RETURN
241 *
242 * End of ZTBT02
243 *
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine zaxpy(N, ZA, ZX, INCX, ZY, INCY)
ZAXPY
Definition: zaxpy.f:88
subroutine zcopy(N, ZX, INCX, ZY, INCY)
ZCOPY
Definition: zcopy.f:81
subroutine ztbmv(UPLO, TRANS, DIAG, N, K, A, LDA, X, INCX)
ZTBMV
Definition: ztbmv.f:186
double precision function zlantb(NORM, UPLO, DIAG, N, K, AB, LDAB, WORK)
ZLANTB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: zlantb.f:141
double precision function dzasum(N, ZX, INCX)
DZASUM
Definition: dzasum.f:72
Here is the call graph for this function:
Here is the caller graph for this function: