LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ zqlt01()

subroutine zqlt01 ( integer  M,
integer  N,
complex*16, dimension( lda, * )  A,
complex*16, dimension( lda, * )  AF,
complex*16, dimension( lda, * )  Q,
complex*16, dimension( lda, * )  L,
integer  LDA,
complex*16, dimension( * )  TAU,
complex*16, dimension( lwork )  WORK,
integer  LWORK,
double precision, dimension( * )  RWORK,
double precision, dimension( * )  RESULT 
)

ZQLT01

Purpose:
 ZQLT01 tests ZGEQLF, which computes the QL factorization of an m-by-n
 matrix A, and partially tests ZUNGQL which forms the m-by-m
 orthogonal matrix Q.

 ZQLT01 compares L with Q'*A, and checks that Q is orthogonal.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
          The m-by-n matrix A.
[out]AF
          AF is COMPLEX*16 array, dimension (LDA,N)
          Details of the QL factorization of A, as returned by ZGEQLF.
          See ZGEQLF for further details.
[out]Q
          Q is COMPLEX*16 array, dimension (LDA,M)
          The m-by-m orthogonal matrix Q.
[out]L
          L is COMPLEX*16 array, dimension (LDA,max(M,N))
[in]LDA
          LDA is INTEGER
          The leading dimension of the arrays A, AF, Q and R.
          LDA >= max(M,N).
[out]TAU
          TAU is COMPLEX*16 array, dimension (min(M,N))
          The scalar factors of the elementary reflectors, as returned
          by ZGEQLF.
[out]WORK
          WORK is COMPLEX*16 array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK.
[out]RWORK
          RWORK is DOUBLE PRECISION array, dimension (M)
[out]RESULT
          RESULT is DOUBLE PRECISION array, dimension (2)
          The test ratios:
          RESULT(1) = norm( L - Q'*A ) / ( M * norm(A) * EPS )
          RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 124 of file zqlt01.f.

126 *
127 * -- LAPACK test routine --
128 * -- LAPACK is a software package provided by Univ. of Tennessee, --
129 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130 *
131 * .. Scalar Arguments ..
132  INTEGER LDA, LWORK, M, N
133 * ..
134 * .. Array Arguments ..
135  DOUBLE PRECISION RESULT( * ), RWORK( * )
136  COMPLEX*16 A( LDA, * ), AF( LDA, * ), L( LDA, * ),
137  $ Q( LDA, * ), TAU( * ), WORK( LWORK )
138 * ..
139 *
140 * =====================================================================
141 *
142 * .. Parameters ..
143  DOUBLE PRECISION ZERO, ONE
144  parameter( zero = 0.0d+0, one = 1.0d+0 )
145  COMPLEX*16 ROGUE
146  parameter( rogue = ( -1.0d+10, -1.0d+10 ) )
147 * ..
148 * .. Local Scalars ..
149  INTEGER INFO, MINMN
150  DOUBLE PRECISION ANORM, EPS, RESID
151 * ..
152 * .. External Functions ..
153  DOUBLE PRECISION DLAMCH, ZLANGE, ZLANSY
154  EXTERNAL dlamch, zlange, zlansy
155 * ..
156 * .. External Subroutines ..
157  EXTERNAL zgemm, zgeqlf, zherk, zlacpy, zlaset, zungql
158 * ..
159 * .. Intrinsic Functions ..
160  INTRINSIC dble, dcmplx, max, min
161 * ..
162 * .. Scalars in Common ..
163  CHARACTER*32 SRNAMT
164 * ..
165 * .. Common blocks ..
166  COMMON / srnamc / srnamt
167 * ..
168 * .. Executable Statements ..
169 *
170  minmn = min( m, n )
171  eps = dlamch( 'Epsilon' )
172 *
173 * Copy the matrix A to the array AF.
174 *
175  CALL zlacpy( 'Full', m, n, a, lda, af, lda )
176 *
177 * Factorize the matrix A in the array AF.
178 *
179  srnamt = 'ZGEQLF'
180  CALL zgeqlf( m, n, af, lda, tau, work, lwork, info )
181 *
182 * Copy details of Q
183 *
184  CALL zlaset( 'Full', m, m, rogue, rogue, q, lda )
185  IF( m.GE.n ) THEN
186  IF( n.LT.m .AND. n.GT.0 )
187  $ CALL zlacpy( 'Full', m-n, n, af, lda, q( 1, m-n+1 ), lda )
188  IF( n.GT.1 )
189  $ CALL zlacpy( 'Upper', n-1, n-1, af( m-n+1, 2 ), lda,
190  $ q( m-n+1, m-n+2 ), lda )
191  ELSE
192  IF( m.GT.1 )
193  $ CALL zlacpy( 'Upper', m-1, m-1, af( 1, n-m+2 ), lda,
194  $ q( 1, 2 ), lda )
195  END IF
196 *
197 * Generate the m-by-m matrix Q
198 *
199  srnamt = 'ZUNGQL'
200  CALL zungql( m, m, minmn, q, lda, tau, work, lwork, info )
201 *
202 * Copy L
203 *
204  CALL zlaset( 'Full', m, n, dcmplx( zero ), dcmplx( zero ), l,
205  $ lda )
206  IF( m.GE.n ) THEN
207  IF( n.GT.0 )
208  $ CALL zlacpy( 'Lower', n, n, af( m-n+1, 1 ), lda,
209  $ l( m-n+1, 1 ), lda )
210  ELSE
211  IF( n.GT.m .AND. m.GT.0 )
212  $ CALL zlacpy( 'Full', m, n-m, af, lda, l, lda )
213  IF( m.GT.0 )
214  $ CALL zlacpy( 'Lower', m, m, af( 1, n-m+1 ), lda,
215  $ l( 1, n-m+1 ), lda )
216  END IF
217 *
218 * Compute L - Q'*A
219 *
220  CALL zgemm( 'Conjugate transpose', 'No transpose', m, n, m,
221  $ dcmplx( -one ), q, lda, a, lda, dcmplx( one ), l,
222  $ lda )
223 *
224 * Compute norm( L - Q'*A ) / ( M * norm(A) * EPS ) .
225 *
226  anorm = zlange( '1', m, n, a, lda, rwork )
227  resid = zlange( '1', m, n, l, lda, rwork )
228  IF( anorm.GT.zero ) THEN
229  result( 1 ) = ( ( resid / dble( max( 1, m ) ) ) / anorm ) / eps
230  ELSE
231  result( 1 ) = zero
232  END IF
233 *
234 * Compute I - Q'*Q
235 *
236  CALL zlaset( 'Full', m, m, dcmplx( zero ), dcmplx( one ), l, lda )
237  CALL zherk( 'Upper', 'Conjugate transpose', m, m, -one, q, lda,
238  $ one, l, lda )
239 *
240 * Compute norm( I - Q'*Q ) / ( M * EPS ) .
241 *
242  resid = zlansy( '1', 'Upper', m, l, lda, rwork )
243 *
244  result( 2 ) = ( resid / dble( max( 1, m ) ) ) / eps
245 *
246  RETURN
247 *
248 * End of ZQLT01
249 *
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
subroutine zgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
ZGEMM
Definition: zgemm.f:187
subroutine zherk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
ZHERK
Definition: zherk.f:173
double precision function zlange(NORM, M, N, A, LDA, WORK)
ZLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: zlange.f:115
subroutine zgeqlf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
ZGEQLF
Definition: zgeqlf.f:138
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:103
subroutine zlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: zlaset.f:106
subroutine zungql(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
ZUNGQL
Definition: zungql.f:128
double precision function zlansy(NORM, UPLO, N, A, LDA, WORK)
ZLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: zlansy.f:123
Here is the call graph for this function:
Here is the caller graph for this function: