LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
cunmrz.f
Go to the documentation of this file.
1 *> \brief \b CUNMRZ
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CUNMRZ + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunmrz.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunmrz.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunmrz.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CUNMRZ( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
22 * WORK, LWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER SIDE, TRANS
26 * INTEGER INFO, K, L, LDA, LDC, LWORK, M, N
27 * ..
28 * .. Array Arguments ..
29 * COMPLEX A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> CUNMRZ overwrites the general complex M-by-N matrix C with
39 *>
40 *> SIDE = 'L' SIDE = 'R'
41 *> TRANS = 'N': Q * C C * Q
42 *> TRANS = 'C': Q**H * C C * Q**H
43 *>
44 *> where Q is a complex unitary matrix defined as the product of k
45 *> elementary reflectors
46 *>
47 *> Q = H(1) H(2) . . . H(k)
48 *>
49 *> as returned by CTZRZF. Q is of order M if SIDE = 'L' and of order N
50 *> if SIDE = 'R'.
51 *> \endverbatim
52 *
53 * Arguments:
54 * ==========
55 *
56 *> \param[in] SIDE
57 *> \verbatim
58 *> SIDE is CHARACTER*1
59 *> = 'L': apply Q or Q**H from the Left;
60 *> = 'R': apply Q or Q**H from the Right.
61 *> \endverbatim
62 *>
63 *> \param[in] TRANS
64 *> \verbatim
65 *> TRANS is CHARACTER*1
66 *> = 'N': No transpose, apply Q;
67 *> = 'C': Conjugate transpose, apply Q**H.
68 *> \endverbatim
69 *>
70 *> \param[in] M
71 *> \verbatim
72 *> M is INTEGER
73 *> The number of rows of the matrix C. M >= 0.
74 *> \endverbatim
75 *>
76 *> \param[in] N
77 *> \verbatim
78 *> N is INTEGER
79 *> The number of columns of the matrix C. N >= 0.
80 *> \endverbatim
81 *>
82 *> \param[in] K
83 *> \verbatim
84 *> K is INTEGER
85 *> The number of elementary reflectors whose product defines
86 *> the matrix Q.
87 *> If SIDE = 'L', M >= K >= 0;
88 *> if SIDE = 'R', N >= K >= 0.
89 *> \endverbatim
90 *>
91 *> \param[in] L
92 *> \verbatim
93 *> L is INTEGER
94 *> The number of columns of the matrix A containing
95 *> the meaningful part of the Householder reflectors.
96 *> If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
97 *> \endverbatim
98 *>
99 *> \param[in] A
100 *> \verbatim
101 *> A is COMPLEX array, dimension
102 *> (LDA,M) if SIDE = 'L',
103 *> (LDA,N) if SIDE = 'R'
104 *> The i-th row must contain the vector which defines the
105 *> elementary reflector H(i), for i = 1,2,...,k, as returned by
106 *> CTZRZF in the last k rows of its array argument A.
107 *> A is modified by the routine but restored on exit.
108 *> \endverbatim
109 *>
110 *> \param[in] LDA
111 *> \verbatim
112 *> LDA is INTEGER
113 *> The leading dimension of the array A. LDA >= max(1,K).
114 *> \endverbatim
115 *>
116 *> \param[in] TAU
117 *> \verbatim
118 *> TAU is COMPLEX array, dimension (K)
119 *> TAU(i) must contain the scalar factor of the elementary
120 *> reflector H(i), as returned by CTZRZF.
121 *> \endverbatim
122 *>
123 *> \param[in,out] C
124 *> \verbatim
125 *> C is COMPLEX array, dimension (LDC,N)
126 *> On entry, the M-by-N matrix C.
127 *> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
128 *> \endverbatim
129 *>
130 *> \param[in] LDC
131 *> \verbatim
132 *> LDC is INTEGER
133 *> The leading dimension of the array C. LDC >= max(1,M).
134 *> \endverbatim
135 *>
136 *> \param[out] WORK
137 *> \verbatim
138 *> WORK is COMPLEX array, dimension (MAX(1,LWORK))
139 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
140 *> \endverbatim
141 *>
142 *> \param[in] LWORK
143 *> \verbatim
144 *> LWORK is INTEGER
145 *> The dimension of the array WORK.
146 *> If SIDE = 'L', LWORK >= max(1,N);
147 *> if SIDE = 'R', LWORK >= max(1,M).
148 *> For good performance, LWORK should generally be larger.
149 *>
150 *> If LWORK = -1, then a workspace query is assumed; the routine
151 *> only calculates the optimal size of the WORK array, returns
152 *> this value as the first entry of the WORK array, and no error
153 *> message related to LWORK is issued by XERBLA.
154 *> \endverbatim
155 *>
156 *> \param[out] INFO
157 *> \verbatim
158 *> INFO is INTEGER
159 *> = 0: successful exit
160 *> < 0: if INFO = -i, the i-th argument had an illegal value
161 *> \endverbatim
162 *
163 * Authors:
164 * ========
165 *
166 *> \author Univ. of Tennessee
167 *> \author Univ. of California Berkeley
168 *> \author Univ. of Colorado Denver
169 *> \author NAG Ltd.
170 *
171 *> \ingroup complexOTHERcomputational
172 *
173 *> \par Contributors:
174 * ==================
175 *>
176 *> A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
177 *
178 *> \par Further Details:
179 * =====================
180 *>
181 *> \verbatim
182 *> \endverbatim
183 *>
184 * =====================================================================
185  SUBROUTINE cunmrz( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
186  $ WORK, LWORK, INFO )
187 *
188 * -- LAPACK computational routine --
189 * -- LAPACK is a software package provided by Univ. of Tennessee, --
190 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
191 *
192 * .. Scalar Arguments ..
193  CHARACTER SIDE, TRANS
194  INTEGER INFO, K, L, LDA, LDC, LWORK, M, N
195 * ..
196 * .. Array Arguments ..
197  COMPLEX A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
198 * ..
199 *
200 * =====================================================================
201 *
202 * .. Parameters ..
203  INTEGER NBMAX, LDT, TSIZE
204  parameter( nbmax = 64, ldt = nbmax+1,
205  $ tsize = ldt*nbmax )
206 * ..
207 * .. Local Scalars ..
208  LOGICAL LEFT, LQUERY, NOTRAN
209  CHARACTER TRANST
210  INTEGER I, I1, I2, I3, IB, IC, IINFO, IWT, JA, JC,
211  $ ldwork, lwkopt, mi, nb, nbmin, ni, nq, nw
212 * ..
213 * .. External Functions ..
214  LOGICAL LSAME
215  INTEGER ILAENV
216  EXTERNAL lsame, ilaenv
217 * ..
218 * .. External Subroutines ..
219  EXTERNAL clarzb, clarzt, cunmr3, xerbla
220 * ..
221 * .. Intrinsic Functions ..
222  INTRINSIC max, min
223 * ..
224 * .. Executable Statements ..
225 *
226 * Test the input arguments
227 *
228  info = 0
229  left = lsame( side, 'L' )
230  notran = lsame( trans, 'N' )
231  lquery = ( lwork.EQ.-1 )
232 *
233 * NQ is the order of Q and NW is the minimum dimension of WORK
234 *
235  IF( left ) THEN
236  nq = m
237  nw = max( 1, n )
238  ELSE
239  nq = n
240  nw = max( 1, m )
241  END IF
242  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
243  info = -1
244  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
245  info = -2
246  ELSE IF( m.LT.0 ) THEN
247  info = -3
248  ELSE IF( n.LT.0 ) THEN
249  info = -4
250  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
251  info = -5
252  ELSE IF( l.LT.0 .OR. ( left .AND. ( l.GT.m ) ) .OR.
253  $ ( .NOT.left .AND. ( l.GT.n ) ) ) THEN
254  info = -6
255  ELSE IF( lda.LT.max( 1, k ) ) THEN
256  info = -8
257  ELSE IF( ldc.LT.max( 1, m ) ) THEN
258  info = -11
259  ELSE IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
260  info = -13
261  END IF
262 *
263  IF( info.EQ.0 ) THEN
264 *
265 * Compute the workspace requirements
266 *
267  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
268  lwkopt = 1
269  ELSE
270  nb = min( nbmax, ilaenv( 1, 'CUNMRQ', side // trans, m, n,
271  $ k, -1 ) )
272  lwkopt = nw*nb + tsize
273  END IF
274  work( 1 ) = lwkopt
275  END IF
276 *
277  IF( info.NE.0 ) THEN
278  CALL xerbla( 'CUNMRZ', -info )
279  RETURN
280  ELSE IF( lquery ) THEN
281  RETURN
282  END IF
283 *
284 * Quick return if possible
285 *
286  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
287  RETURN
288  END IF
289 *
290 * Determine the block size.
291 *
292  nb = min( nbmax, ilaenv( 1, 'CUNMRQ', side // trans, m, n, k,
293  $ -1 ) )
294  nbmin = 2
295  ldwork = nw
296  IF( nb.GT.1 .AND. nb.LT.k ) THEN
297  IF( lwork.LT.lwkopt ) THEN
298  nb = (lwork-tsize) / ldwork
299  nbmin = max( 2, ilaenv( 2, 'CUNMRQ', side // trans, m, n, k,
300  $ -1 ) )
301  END IF
302  END IF
303 *
304  IF( nb.LT.nbmin .OR. nb.GE.k ) THEN
305 *
306 * Use unblocked code
307 *
308  CALL cunmr3( side, trans, m, n, k, l, a, lda, tau, c, ldc,
309  $ work, iinfo )
310  ELSE
311 *
312 * Use blocked code
313 *
314  iwt = 1 + nw*nb
315  IF( ( left .AND. .NOT.notran ) .OR.
316  $ ( .NOT.left .AND. notran ) ) THEN
317  i1 = 1
318  i2 = k
319  i3 = nb
320  ELSE
321  i1 = ( ( k-1 ) / nb )*nb + 1
322  i2 = 1
323  i3 = -nb
324  END IF
325 *
326  IF( left ) THEN
327  ni = n
328  jc = 1
329  ja = m - l + 1
330  ELSE
331  mi = m
332  ic = 1
333  ja = n - l + 1
334  END IF
335 *
336  IF( notran ) THEN
337  transt = 'C'
338  ELSE
339  transt = 'N'
340  END IF
341 *
342  DO 10 i = i1, i2, i3
343  ib = min( nb, k-i+1 )
344 *
345 * Form the triangular factor of the block reflector
346 * H = H(i+ib-1) . . . H(i+1) H(i)
347 *
348  CALL clarzt( 'Backward', 'Rowwise', l, ib, a( i, ja ), lda,
349  $ tau( i ), work( iwt ), ldt )
350 *
351  IF( left ) THEN
352 *
353 * H or H**H is applied to C(i:m,1:n)
354 *
355  mi = m - i + 1
356  ic = i
357  ELSE
358 *
359 * H or H**H is applied to C(1:m,i:n)
360 *
361  ni = n - i + 1
362  jc = i
363  END IF
364 *
365 * Apply H or H**H
366 *
367  CALL clarzb( side, transt, 'Backward', 'Rowwise', mi, ni,
368  $ ib, l, a( i, ja ), lda, work( iwt ), ldt,
369  $ c( ic, jc ), ldc, work, ldwork )
370  10 CONTINUE
371 *
372  END IF
373 *
374  work( 1 ) = lwkopt
375 *
376  RETURN
377 *
378 * End of CUNMRZ
379 *
380  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine clarzb(SIDE, TRANS, DIRECT, STOREV, M, N, K, L, V, LDV, T, LDT, C, LDC, WORK, LDWORK)
CLARZB applies a block reflector or its conjugate-transpose to a general matrix.
Definition: clarzb.f:183
subroutine clarzt(DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT)
CLARZT forms the triangular factor T of a block reflector H = I - vtvH.
Definition: clarzt.f:185
subroutine cunmr3(SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC, WORK, INFO)
CUNMR3 multiplies a general matrix by the unitary matrix from a RZ factorization determined by ctzrzf...
Definition: cunmr3.f:178
subroutine cunmrz(SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
CUNMRZ
Definition: cunmrz.f:187