LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ zgebd2()

subroutine zgebd2 ( integer m,
integer n,
complex*16, dimension( lda, * ) a,
integer lda,
double precision, dimension( * ) d,
double precision, dimension( * ) e,
complex*16, dimension( * ) tauq,
complex*16, dimension( * ) taup,
complex*16, dimension( * ) work,
integer info )

ZGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.

Download ZGEBD2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> ZGEBD2 reduces a complex general m by n matrix A to upper or lower
!> real bidiagonal form B by a unitary transformation: Q**H * A * P = B.
!>
!> If m >= n, B is upper bidiagonal; if m < n, B is lower bidiagonal.
!>
Parameters
[in]M
!>          M is INTEGER
!>          The number of rows in the matrix A.  M >= 0.
!>
[in]N
!>          N is INTEGER
!>          The number of columns in the matrix A.  N >= 0.
!>
[in,out]A
!>          A is COMPLEX*16 array, dimension (LDA,N)
!>          On entry, the m by n general matrix to be reduced.
!>          On exit,
!>          if m >= n, the diagonal and the first superdiagonal are
!>            overwritten with the upper bidiagonal matrix B; the
!>            elements below the diagonal, with the array TAUQ, represent
!>            the unitary matrix Q as a product of elementary
!>            reflectors, and the elements above the first superdiagonal,
!>            with the array TAUP, represent the unitary matrix P as
!>            a product of elementary reflectors;
!>          if m < n, the diagonal and the first subdiagonal are
!>            overwritten with the lower bidiagonal matrix B; the
!>            elements below the first subdiagonal, with the array TAUQ,
!>            represent the unitary matrix Q as a product of
!>            elementary reflectors, and the elements above the diagonal,
!>            with the array TAUP, represent the unitary matrix P as
!>            a product of elementary reflectors.
!>          See Further Details.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.  LDA >= max(1,M).
!>
[out]D
!>          D is DOUBLE PRECISION array, dimension (min(M,N))
!>          The diagonal elements of the bidiagonal matrix B:
!>          D(i) = A(i,i).
!>
[out]E
!>          E is DOUBLE PRECISION array, dimension (min(M,N)-1)
!>          The off-diagonal elements of the bidiagonal matrix B:
!>          if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
!>          if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
!>
[out]TAUQ
!>          TAUQ is COMPLEX*16 array, dimension (min(M,N))
!>          The scalar factors of the elementary reflectors which
!>          represent the unitary matrix Q. See Further Details.
!>
[out]TAUP
!>          TAUP is COMPLEX*16 array, dimension (min(M,N))
!>          The scalar factors of the elementary reflectors which
!>          represent the unitary matrix P. See Further Details.
!>
[out]WORK
!>          WORK is COMPLEX*16 array, dimension (max(M,N))
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0: successful exit
!>          < 0: if INFO = -i, the i-th argument had an illegal value.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!>
!>  The matrices Q and P are represented as products of elementary
!>  reflectors:
!>
!>  If m >= n,
!>
!>     Q = H(1) H(2) . . . H(n)  and  P = G(1) G(2) . . . G(n-1)
!>
!>  Each H(i) and G(i) has the form:
!>
!>     H(i) = I - tauq * v * v**H  and G(i) = I - taup * u * u**H
!>
!>  where tauq and taup are complex scalars, and v and u are complex
!>  vectors; v(1:i-1) = 0, v(i) = 1, and v(i+1:m) is stored on exit in
!>  A(i+1:m,i); u(1:i) = 0, u(i+1) = 1, and u(i+2:n) is stored on exit in
!>  A(i,i+2:n); tauq is stored in TAUQ(i) and taup in TAUP(i).
!>
!>  If m < n,
!>
!>     Q = H(1) H(2) . . . H(m-1)  and  P = G(1) G(2) . . . G(m)
!>
!>  Each H(i) and G(i) has the form:
!>
!>     H(i) = I - tauq * v * v**H  and G(i) = I - taup * u * u**H
!>
!>  where tauq and taup are complex scalars, v and u are complex vectors;
!>  v(1:i) = 0, v(i+1) = 1, and v(i+2:m) is stored on exit in A(i+2:m,i);
!>  u(1:i-1) = 0, u(i) = 1, and u(i+1:n) is stored on exit in A(i,i+1:n);
!>  tauq is stored in TAUQ(i) and taup in TAUP(i).
!>
!>  The contents of A on exit are illustrated by the following examples:
!>
!>  m = 6 and n = 5 (m > n):          m = 5 and n = 6 (m < n):
!>
!>    (  d   e   u1  u1  u1 )           (  d   u1  u1  u1  u1  u1 )
!>    (  v1  d   e   u2  u2 )           (  e   d   u2  u2  u2  u2 )
!>    (  v1  v2  d   e   u3 )           (  v1  e   d   u3  u3  u3 )
!>    (  v1  v2  v3  d   e  )           (  v1  v2  e   d   u4  u4 )
!>    (  v1  v2  v3  v4  d  )           (  v1  v2  v3  e   d   u5 )
!>    (  v1  v2  v3  v4  v5 )
!>
!>  where d and e denote diagonal and off-diagonal elements of B, vi
!>  denotes an element of the vector defining H(i), and ui an element of
!>  the vector defining G(i).
!>

Definition at line 186 of file zgebd2.f.

187*
188* -- LAPACK computational routine --
189* -- LAPACK is a software package provided by Univ. of Tennessee, --
190* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
191*
192* .. Scalar Arguments ..
193 INTEGER INFO, LDA, M, N
194* ..
195* .. Array Arguments ..
196 DOUBLE PRECISION D( * ), E( * )
197 COMPLEX*16 A( LDA, * ), TAUP( * ), TAUQ( * ), WORK( * )
198* ..
199*
200* =====================================================================
201*
202* .. Parameters ..
203 COMPLEX*16 ZERO
204 parameter( zero = ( 0.0d+0, 0.0d+0 ) )
205* .. Local Scalars ..
206 INTEGER I
207 COMPLEX*16 ALPHA
208* ..
209* .. External Subroutines ..
210 EXTERNAL xerbla, zlacgv, zlarf1f, zlarfg
211* ..
212* .. Intrinsic Functions ..
213 INTRINSIC dconjg, max, min
214* ..
215* .. Executable Statements ..
216*
217* Test the input parameters
218*
219 info = 0
220 IF( m.LT.0 ) THEN
221 info = -1
222 ELSE IF( n.LT.0 ) THEN
223 info = -2
224 ELSE IF( lda.LT.max( 1, m ) ) THEN
225 info = -4
226 END IF
227 IF( info.LT.0 ) THEN
228 CALL xerbla( 'ZGEBD2', -info )
229 RETURN
230 END IF
231*
232 IF( m.GE.n ) THEN
233*
234* Reduce to upper bidiagonal form
235*
236 DO 10 i = 1, n
237*
238* Generate elementary reflector H(i) to annihilate A(i+1:m,i)
239*
240 alpha = a( i, i )
241 CALL zlarfg( m-i+1, alpha, a( min( i+1, m ), i ), 1,
242 $ tauq( i ) )
243 d( i ) = dble( alpha )
244*
245* Apply H(i)**H to A(i:m,i+1:n) from the left
246*
247 IF( i.LT.n )
248 $ CALL zlarf1f( 'Left', m-i+1, n-i, a( i, i ), 1,
249 $ dconjg( tauq( i ) ), a( i, i+1 ), lda, work )
250 a( i, i ) = d( i )
251*
252 IF( i.LT.n ) THEN
253*
254* Generate elementary reflector G(i) to annihilate
255* A(i,i+2:n)
256*
257 CALL zlacgv( n-i, a( i, i+1 ), lda )
258 alpha = a( i, i+1 )
259 CALL zlarfg( n-i, alpha, a( i, min( i+2, n ) ), lda,
260 $ taup( i ) )
261 e( i ) = dble( alpha )
262*
263* Apply G(i) to A(i+1:m,i+1:n) from the right
264*
265 CALL zlarf1f( 'Right', m-i, n-i, a( i, i+1 ), lda,
266 $ taup( i ), a( i+1, i+1 ), lda, work )
267 CALL zlacgv( n-i, a( i, i+1 ), lda )
268 a( i, i+1 ) = e( i )
269 ELSE
270 taup( i ) = zero
271 END IF
272 10 CONTINUE
273 ELSE
274*
275* Reduce to lower bidiagonal form
276*
277 DO 20 i = 1, m
278*
279* Generate elementary reflector G(i) to annihilate A(i,i+1:n)
280*
281 CALL zlacgv( n-i+1, a( i, i ), lda )
282 alpha = a( i, i )
283 CALL zlarfg( n-i+1, alpha, a( i, min( i+1, n ) ), lda,
284 $ taup( i ) )
285 d( i ) = dble( alpha )
286*
287* Apply G(i) to A(i+1:m,i:n) from the right
288*
289 IF( i.LT.m )
290 $ CALL zlarf1f( 'Right', m-i, n-i+1, a( i, i ), lda,
291 $ taup( i ), a( i+1, i ), lda, work )
292 CALL zlacgv( n-i+1, a( i, i ), lda )
293 a( i, i ) = d( i )
294*
295 IF( i.LT.m ) THEN
296*
297* Generate elementary reflector H(i) to annihilate
298* A(i+2:m,i)
299*
300 alpha = a( i+1, i )
301 CALL zlarfg( m-i, alpha, a( min( i+2, m ), i ), 1,
302 $ tauq( i ) )
303 e( i ) = dble( alpha )
304*
305* Apply H(i)**H to A(i+1:m,i+1:n) from the left
306*
307 CALL zlarf1f( 'Left', m-i, n-i, a( i+1, i ), 1,
308 $ dconjg( tauq( i ) ), a( i+1, i+1 ), lda,
309 $ work )
310 a( i+1, i ) = e( i )
311 ELSE
312 tauq( i ) = zero
313 END IF
314 20 CONTINUE
315 END IF
316 RETURN
317*
318* End of ZGEBD2
319*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
zlacgv
subroutine zlacgv(n, x, incx)
ZLACGV conjugates a complex vector.
Definition zlacgv.f:72
zlarf1f
subroutine zlarf1f(side, m, n, v, incv, tau, c, ldc, work)
ZLARF1F applies an elementary reflector to a general rectangular
Definition zlarf1f.f:157
zlarfg
subroutine zlarfg(n, alpha, x, incx, tau)
ZLARFG generates an elementary reflector (Householder matrix).
Definition zlarfg.f:104
Here is the call graph for this function:
Here is the caller graph for this function: