LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
ztrmm.f
Go to the documentation of this file.
1*> \brief \b ZTRMM
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE ZTRMM(SIDE,UPLO,TRANSA,DIAG,M,N,ALPHA,A,LDA,B,LDB)
12*
13* .. Scalar Arguments ..
14* COMPLEX*16 ALPHA
15* INTEGER LDA,LDB,M,N
16* CHARACTER DIAG,SIDE,TRANSA,UPLO
17* ..
18* .. Array Arguments ..
19* COMPLEX*16 A(LDA,*),B(LDB,*)
20* ..
21*
22*
23*> \par Purpose:
24* =============
25*>
26*> \verbatim
27*>
28*> ZTRMM performs one of the matrix-matrix operations
29*>
30*> B := alpha*op( A )*B, or B := alpha*B*op( A )
31*>
32*> where alpha is a scalar, B is an m by n matrix, A is a unit, or
33*> non-unit, upper or lower triangular matrix and op( A ) is one of
34*>
35*> op( A ) = A or op( A ) = A**T or op( A ) = A**H.
36*> \endverbatim
37*
38* Arguments:
39* ==========
40*
41*> \param[in] SIDE
42*> \verbatim
43*> SIDE is CHARACTER*1
44*> On entry, SIDE specifies whether op( A ) multiplies B from
45*> the left or right as follows:
46*>
47*> SIDE = 'L' or 'l' B := alpha*op( A )*B.
48*>
49*> SIDE = 'R' or 'r' B := alpha*B*op( A ).
50*> \endverbatim
51*>
52*> \param[in] UPLO
53*> \verbatim
54*> UPLO is CHARACTER*1
55*> On entry, UPLO specifies whether the matrix A is an upper or
56*> lower triangular matrix as follows:
57*>
58*> UPLO = 'U' or 'u' A is an upper triangular matrix.
59*>
60*> UPLO = 'L' or 'l' A is a lower triangular matrix.
61*> \endverbatim
62*>
63*> \param[in] TRANSA
64*> \verbatim
65*> TRANSA is CHARACTER*1
66*> On entry, TRANSA specifies the form of op( A ) to be used in
67*> the matrix multiplication as follows:
68*>
69*> TRANSA = 'N' or 'n' op( A ) = A.
70*>
71*> TRANSA = 'T' or 't' op( A ) = A**T.
72*>
73*> TRANSA = 'C' or 'c' op( A ) = A**H.
74*> \endverbatim
75*>
76*> \param[in] DIAG
77*> \verbatim
78*> DIAG is CHARACTER*1
79*> On entry, DIAG specifies whether or not A is unit triangular
80*> as follows:
81*>
82*> DIAG = 'U' or 'u' A is assumed to be unit triangular.
83*>
84*> DIAG = 'N' or 'n' A is not assumed to be unit
85*> triangular.
86*> \endverbatim
87*>
88*> \param[in] M
89*> \verbatim
90*> M is INTEGER
91*> On entry, M specifies the number of rows of B. M must be at
92*> least zero.
93*> \endverbatim
94*>
95*> \param[in] N
96*> \verbatim
97*> N is INTEGER
98*> On entry, N specifies the number of columns of B. N must be
99*> at least zero.
100*> \endverbatim
101*>
102*> \param[in] ALPHA
103*> \verbatim
104*> ALPHA is COMPLEX*16
105*> On entry, ALPHA specifies the scalar alpha. When alpha is
106*> zero then A is not referenced and B need not be set before
107*> entry.
108*> \endverbatim
109*>
110*> \param[in] A
111*> \verbatim
112*> A is COMPLEX*16 array, dimension ( LDA, k ), where k is m
113*> when SIDE = 'L' or 'l' and is n when SIDE = 'R' or 'r'.
114*> Before entry with UPLO = 'U' or 'u', the leading k by k
115*> upper triangular part of the array A must contain the upper
116*> triangular matrix and the strictly lower triangular part of
117*> A is not referenced.
118*> Before entry with UPLO = 'L' or 'l', the leading k by k
119*> lower triangular part of the array A must contain the lower
120*> triangular matrix and the strictly upper triangular part of
121*> A is not referenced.
122*> Note that when DIAG = 'U' or 'u', the diagonal elements of
123*> A are not referenced either, but are assumed to be unity.
124*> \endverbatim
125*>
126*> \param[in] LDA
127*> \verbatim
128*> LDA is INTEGER
129*> On entry, LDA specifies the first dimension of A as declared
130*> in the calling (sub) program. When SIDE = 'L' or 'l' then
131*> LDA must be at least max( 1, m ), when SIDE = 'R' or 'r'
132*> then LDA must be at least max( 1, n ).
133*> \endverbatim
134*>
135*> \param[in,out] B
136*> \verbatim
137*> B is COMPLEX*16 array, dimension ( LDB, N ).
138*> Before entry, the leading m by n part of the array B must
139*> contain the matrix B, and on exit is overwritten by the
140*> transformed matrix.
141*> \endverbatim
142*>
143*> \param[in] LDB
144*> \verbatim
145*> LDB is INTEGER
146*> On entry, LDB specifies the first dimension of B as declared
147*> in the calling (sub) program. LDB must be at least
148*> max( 1, m ).
149*> \endverbatim
150*
151* Authors:
152* ========
153*
154*> \author Univ. of Tennessee
155*> \author Univ. of California Berkeley
156*> \author Univ. of Colorado Denver
157*> \author NAG Ltd.
158*
159*> \ingroup trmm
160*
161*> \par Further Details:
162* =====================
163*>
164*> \verbatim
165*>
166*> Level 3 Blas routine.
167*>
168*> -- Written on 8-February-1989.
169*> Jack Dongarra, Argonne National Laboratory.
170*> Iain Duff, AERE Harwell.
171*> Jeremy Du Croz, Numerical Algorithms Group Ltd.
172*> Sven Hammarling, Numerical Algorithms Group Ltd.
173*> \endverbatim
174*>
175* =====================================================================
176 SUBROUTINE ztrmm(SIDE,UPLO,TRANSA,DIAG,M,N,ALPHA,A,LDA,B,LDB)
177*
178* -- Reference BLAS level3 routine --
179* -- Reference BLAS is a software package provided by Univ. of Tennessee, --
180* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
181*
182* .. Scalar Arguments ..
183 COMPLEX*16 ALPHA
184 INTEGER LDA,LDB,M,N
185 CHARACTER DIAG,SIDE,TRANSA,UPLO
186* ..
187* .. Array Arguments ..
188 COMPLEX*16 A(LDA,*),B(LDB,*)
189* ..
190*
191* =====================================================================
192*
193* .. External Functions ..
194 LOGICAL LSAME
195 EXTERNAL lsame
196* ..
197* .. External Subroutines ..
198 EXTERNAL xerbla
199* ..
200* .. Intrinsic Functions ..
201 INTRINSIC dconjg,max
202* ..
203* .. Local Scalars ..
204 COMPLEX*16 TEMP
205 INTEGER I,INFO,J,K,NROWA
206 LOGICAL LSIDE,NOCONJ,NOUNIT,UPPER
207* ..
208* .. Parameters ..
209 COMPLEX*16 ONE
210 parameter(one= (1.0d+0,0.0d+0))
211 COMPLEX*16 ZERO
212 parameter(zero= (0.0d+0,0.0d+0))
213* ..
214*
215* Test the input parameters.
216*
217 lside = lsame(side,'L')
218 IF (lside) THEN
219 nrowa = m
220 ELSE
221 nrowa = n
222 END IF
223 noconj = lsame(transa,'T')
224 nounit = lsame(diag,'N')
225 upper = lsame(uplo,'U')
226*
227 info = 0
228 IF ((.NOT.lside) .AND. (.NOT.lsame(side,'R'))) THEN
229 info = 1
230 ELSE IF ((.NOT.upper) .AND. (.NOT.lsame(uplo,'L'))) THEN
231 info = 2
232 ELSE IF ((.NOT.lsame(transa,'N')) .AND.
233 + (.NOT.lsame(transa,'T')) .AND.
234 + (.NOT.lsame(transa,'C'))) THEN
235 info = 3
236 ELSE IF ((.NOT.lsame(diag,'U')) .AND.
237 + (.NOT.lsame(diag,'N'))) THEN
238 info = 4
239 ELSE IF (m.LT.0) THEN
240 info = 5
241 ELSE IF (n.LT.0) THEN
242 info = 6
243 ELSE IF (lda.LT.max(1,nrowa)) THEN
244 info = 9
245 ELSE IF (ldb.LT.max(1,m)) THEN
246 info = 11
247 END IF
248 IF (info.NE.0) THEN
249 CALL xerbla('ZTRMM ',info)
250 RETURN
251 END IF
252*
253* Quick return if possible.
254*
255 IF (m.EQ.0 .OR. n.EQ.0) RETURN
256*
257* And when alpha.eq.zero.
258*
259 IF (alpha.EQ.zero) THEN
260 DO 20 j = 1,n
261 DO 10 i = 1,m
262 b(i,j) = zero
263 10 CONTINUE
264 20 CONTINUE
265 RETURN
266 END IF
267*
268* Start the operations.
269*
270 IF (lside) THEN
271 IF (lsame(transa,'N')) THEN
272*
273* Form B := alpha*A*B.
274*
275 IF (upper) THEN
276 DO 50 j = 1,n
277 DO 40 k = 1,m
278 IF (b(k,j).NE.zero) THEN
279 temp = alpha*b(k,j)
280 DO 30 i = 1,k - 1
281 b(i,j) = b(i,j) + temp*a(i,k)
282 30 CONTINUE
283 IF (nounit) temp = temp*a(k,k)
284 b(k,j) = temp
285 END IF
286 40 CONTINUE
287 50 CONTINUE
288 ELSE
289 DO 80 j = 1,n
290 DO 70 k = m,1,-1
291 IF (b(k,j).NE.zero) THEN
292 temp = alpha*b(k,j)
293 b(k,j) = temp
294 IF (nounit) b(k,j) = b(k,j)*a(k,k)
295 DO 60 i = k + 1,m
296 b(i,j) = b(i,j) + temp*a(i,k)
297 60 CONTINUE
298 END IF
299 70 CONTINUE
300 80 CONTINUE
301 END IF
302 ELSE
303*
304* Form B := alpha*A**T*B or B := alpha*A**H*B.
305*
306 IF (upper) THEN
307 DO 120 j = 1,n
308 DO 110 i = m,1,-1
309 temp = b(i,j)
310 IF (noconj) THEN
311 IF (nounit) temp = temp*a(i,i)
312 DO 90 k = 1,i - 1
313 temp = temp + a(k,i)*b(k,j)
314 90 CONTINUE
315 ELSE
316 IF (nounit) temp = temp*dconjg(a(i,i))
317 DO 100 k = 1,i - 1
318 temp = temp + dconjg(a(k,i))*b(k,j)
319 100 CONTINUE
320 END IF
321 b(i,j) = alpha*temp
322 110 CONTINUE
323 120 CONTINUE
324 ELSE
325 DO 160 j = 1,n
326 DO 150 i = 1,m
327 temp = b(i,j)
328 IF (noconj) THEN
329 IF (nounit) temp = temp*a(i,i)
330 DO 130 k = i + 1,m
331 temp = temp + a(k,i)*b(k,j)
332 130 CONTINUE
333 ELSE
334 IF (nounit) temp = temp*dconjg(a(i,i))
335 DO 140 k = i + 1,m
336 temp = temp + dconjg(a(k,i))*b(k,j)
337 140 CONTINUE
338 END IF
339 b(i,j) = alpha*temp
340 150 CONTINUE
341 160 CONTINUE
342 END IF
343 END IF
344 ELSE
345 IF (lsame(transa,'N')) THEN
346*
347* Form B := alpha*B*A.
348*
349 IF (upper) THEN
350 DO 200 j = n,1,-1
351 temp = alpha
352 IF (nounit) temp = temp*a(j,j)
353 DO 170 i = 1,m
354 b(i,j) = temp*b(i,j)
355 170 CONTINUE
356 DO 190 k = 1,j - 1
357 IF (a(k,j).NE.zero) THEN
358 temp = alpha*a(k,j)
359 DO 180 i = 1,m
360 b(i,j) = b(i,j) + temp*b(i,k)
361 180 CONTINUE
362 END IF
363 190 CONTINUE
364 200 CONTINUE
365 ELSE
366 DO 240 j = 1,n
367 temp = alpha
368 IF (nounit) temp = temp*a(j,j)
369 DO 210 i = 1,m
370 b(i,j) = temp*b(i,j)
371 210 CONTINUE
372 DO 230 k = j + 1,n
373 IF (a(k,j).NE.zero) THEN
374 temp = alpha*a(k,j)
375 DO 220 i = 1,m
376 b(i,j) = b(i,j) + temp*b(i,k)
377 220 CONTINUE
378 END IF
379 230 CONTINUE
380 240 CONTINUE
381 END IF
382 ELSE
383*
384* Form B := alpha*B*A**T or B := alpha*B*A**H.
385*
386 IF (upper) THEN
387 DO 280 k = 1,n
388 DO 260 j = 1,k - 1
389 IF (a(j,k).NE.zero) THEN
390 IF (noconj) THEN
391 temp = alpha*a(j,k)
392 ELSE
393 temp = alpha*dconjg(a(j,k))
394 END IF
395 DO 250 i = 1,m
396 b(i,j) = b(i,j) + temp*b(i,k)
397 250 CONTINUE
398 END IF
399 260 CONTINUE
400 temp = alpha
401 IF (nounit) THEN
402 IF (noconj) THEN
403 temp = temp*a(k,k)
404 ELSE
405 temp = temp*dconjg(a(k,k))
406 END IF
407 END IF
408 IF (temp.NE.one) THEN
409 DO 270 i = 1,m
410 b(i,k) = temp*b(i,k)
411 270 CONTINUE
412 END IF
413 280 CONTINUE
414 ELSE
415 DO 320 k = n,1,-1
416 DO 300 j = k + 1,n
417 IF (a(j,k).NE.zero) THEN
418 IF (noconj) THEN
419 temp = alpha*a(j,k)
420 ELSE
421 temp = alpha*dconjg(a(j,k))
422 END IF
423 DO 290 i = 1,m
424 b(i,j) = b(i,j) + temp*b(i,k)
425 290 CONTINUE
426 END IF
427 300 CONTINUE
428 temp = alpha
429 IF (nounit) THEN
430 IF (noconj) THEN
431 temp = temp*a(k,k)
432 ELSE
433 temp = temp*dconjg(a(k,k))
434 END IF
435 END IF
436 IF (temp.NE.one) THEN
437 DO 310 i = 1,m
438 b(i,k) = temp*b(i,k)
439 310 CONTINUE
440 END IF
441 320 CONTINUE
442 END IF
443 END IF
444 END IF
445*
446 RETURN
447*
448* End of ZTRMM
449*
450 END
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
ztrmm
subroutine ztrmm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
ZTRMM
Definition ztrmm.f:177