LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ sgelq2()

subroutine sgelq2 ( integer  M,
integer  N,
real, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  TAU,
real, dimension( * )  WORK,
integer  INFO 
)

SGELQ2 computes the LQ factorization of a general rectangular matrix using an unblocked algorithm.

Download SGELQ2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SGELQ2 computes an LQ factorization of a real m-by-n matrix A:

    A = ( L 0 ) *  Q

 where:

    Q is a n-by-n orthogonal matrix;
    L is a lower-triangular m-by-m matrix;
    0 is a m-by-(n-m) zero matrix, if m < n.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.
[in,out]A
          A is REAL array, dimension (LDA,N)
          On entry, the m by n matrix A.
          On exit, the elements on and below the diagonal of the array
          contain the m by min(m,n) lower trapezoidal matrix L (L is
          lower triangular if m <= n); the elements above the diagonal,
          with the array TAU, represent the orthogonal matrix Q as a
          product of elementary reflectors (see Further Details).
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]TAU
          TAU is REAL array, dimension (min(M,N))
          The scalar factors of the elementary reflectors (see Further
          Details).
[out]WORK
          WORK is REAL array, dimension (M)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  The matrix Q is represented as a product of elementary reflectors

     Q = H(k) . . . H(2) H(1), where k = min(m,n).

  Each H(i) has the form

     H(i) = I - tau * v * v**T

  where tau is a real scalar, and v is a real vector with
  v(1:i-1) = 0 and v(i) = 1; v(i+1:n) is stored on exit in A(i,i+1:n),
  and tau in TAU(i).

Definition at line 128 of file sgelq2.f.

129 *
130 * -- LAPACK computational routine --
131 * -- LAPACK is a software package provided by Univ. of Tennessee, --
132 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
133 *
134 * .. Scalar Arguments ..
135  INTEGER INFO, LDA, M, N
136 * ..
137 * .. Array Arguments ..
138  REAL A( LDA, * ), TAU( * ), WORK( * )
139 * ..
140 *
141 * =====================================================================
142 *
143 * .. Parameters ..
144  REAL ONE
145  parameter( one = 1.0e+0 )
146 * ..
147 * .. Local Scalars ..
148  INTEGER I, K
149  REAL AII
150 * ..
151 * .. External Subroutines ..
152  EXTERNAL slarf, slarfg, xerbla
153 * ..
154 * .. Intrinsic Functions ..
155  INTRINSIC max, min
156 * ..
157 * .. Executable Statements ..
158 *
159 * Test the input arguments
160 *
161  info = 0
162  IF( m.LT.0 ) THEN
163  info = -1
164  ELSE IF( n.LT.0 ) THEN
165  info = -2
166  ELSE IF( lda.LT.max( 1, m ) ) THEN
167  info = -4
168  END IF
169  IF( info.NE.0 ) THEN
170  CALL xerbla( 'SGELQ2', -info )
171  RETURN
172  END IF
173 *
174  k = min( m, n )
175 *
176  DO 10 i = 1, k
177 *
178 * Generate elementary reflector H(i) to annihilate A(i,i+1:n)
179 *
180  CALL slarfg( n-i+1, a( i, i ), a( i, min( i+1, n ) ), lda,
181  $ tau( i ) )
182  IF( i.LT.m ) THEN
183 *
184 * Apply H(i) to A(i+1:m,i:n) from the right
185 *
186  aii = a( i, i )
187  a( i, i ) = one
188  CALL slarf( 'Right', m-i, n-i+1, a( i, i ), lda, tau( i ),
189  $ a( i+1, i ), lda, work )
190  a( i, i ) = aii
191  END IF
192  10 CONTINUE
193  RETURN
194 *
195 * End of SGELQ2
196 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine slarfg(N, ALPHA, X, INCX, TAU)
SLARFG generates an elementary reflector (Householder matrix).
Definition: slarfg.f:106
subroutine slarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
SLARF applies an elementary reflector to a general rectangular matrix.
Definition: slarf.f:124
Here is the call graph for this function:
Here is the caller graph for this function: