zlasyf_rk.f

Go to the documentation of this file.

*> \brief \b ZLASYF_RK computes a partial factorization of a complex symmetric indefinite matrix using bounded Bunch-Kaufman (rook) diagonal pivoting method.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download ZLASYF_RK + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlasyf_rk.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlasyf_rk.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlasyf_rk.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZLASYF_RK( UPLO, N, NB, KB, A, LDA, E, IPIV, W, LDW,
*                             INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, KB, LDA, LDW, N, NB
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       COMPLEX*16         A( LDA, * ), E( * ), W( LDW, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*> ZLASYF_RK computes a partial factorization of a complex symmetric
*> matrix A using the bounded Bunch-Kaufman (rook) diagonal
*> pivoting method. The partial factorization has the form:
*>
*> A  =  ( I  U12 ) ( A11  0  ) (  I       0    )  if UPLO = 'U', or:
*>       ( 0  U22 ) (  0   D  ) ( U12**T U22**T )
*>
*> A  =  ( L11  0 ) (  D   0  ) ( L11**T L21**T )  if UPLO = 'L',
*>       ( L21  I ) (  0  A22 ) (  0       I    )
*>
*> where the order of D is at most NB. The actual order is returned in
*> the argument KB, and is either NB or NB-1, or N if N <= NB.
*>
*> ZLASYF_RK is an auxiliary routine called by ZSYTRF_RK. It uses
*> blocked code (calling Level 3 BLAS) to update the submatrix
*> A11 (if UPLO = 'U') or A22 (if UPLO = 'L').
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          symmetric matrix A is stored:
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          The maximum number of columns of the matrix A that should be
*>          factored.  NB should be at least 2 to allow for 2-by-2 pivot
*>          blocks.
*> \endverbatim
*>
*> \param[out] KB
*> \verbatim
*>          KB is INTEGER
*>          The number of columns of A that were actually factored.
*>          KB is either NB-1 or NB, or N if N <= NB.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          On entry, the symmetric matrix A.
*>            If UPLO = 'U': the leading N-by-N upper triangular part
*>            of A contains the upper triangular part of the matrix A,
*>            and the strictly lower triangular part of A is not
*>            referenced.
*>
*>            If UPLO = 'L': the leading N-by-N lower triangular part
*>            of A contains the lower triangular part of the matrix A,
*>            and the strictly upper triangular part of A is not
*>            referenced.
*>
*>          On exit, contains:
*>            a) ONLY diagonal elements of the symmetric block diagonal
*>               matrix D on the diagonal of A, i.e. D(k,k) = A(k,k);
*>               (superdiagonal (or subdiagonal) elements of D
*>                are stored on exit in array E), and
*>            b) If UPLO = 'U': factor U in the superdiagonal part of A.
*>               If UPLO = 'L': factor L in the subdiagonal part of A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[out] E
*> \verbatim
*>          E is COMPLEX*16 array, dimension (N)
*>          On exit, contains the superdiagonal (or subdiagonal)
*>          elements of the symmetric block diagonal matrix D
*>          with 1-by-1 or 2-by-2 diagonal blocks, where
*>          If UPLO = 'U': E(i) = D(i-1,i), i=2:N, E(1) is set to 0;
*>          If UPLO = 'L': E(i) = D(i+1,i), i=1:N-1, E(N) is set to 0.
*>
*>          NOTE: For 1-by-1 diagonal block D(k), where
*>          1 <= k <= N, the element E(k) is set to 0 in both
*>          UPLO = 'U' or UPLO = 'L' cases.
*> \endverbatim
*>
*> \param[out] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>          IPIV describes the permutation matrix P in the factorization
*>          of matrix A as follows. The absolute value of IPIV(k)
*>          represents the index of row and column that were
*>          interchanged with the k-th row and column. The value of UPLO
*>          describes the order in which the interchanges were applied.
*>          Also, the sign of IPIV represents the block structure of
*>          the symmetric block diagonal matrix D with 1-by-1 or 2-by-2
*>          diagonal blocks which correspond to 1 or 2 interchanges
*>          at each factorization step.
*>
*>          If UPLO = 'U',
*>          ( in factorization order, k decreases from N to 1 ):
*>            a) A single positive entry IPIV(k) > 0 means:
*>               D(k,k) is a 1-by-1 diagonal block.
*>               If IPIV(k) != k, rows and columns k and IPIV(k) were
*>               interchanged in the submatrix A(1:N,N-KB+1:N);
*>               If IPIV(k) = k, no interchange occurred.
*>
*>
*>            b) A pair of consecutive negative entries
*>               IPIV(k) < 0 and IPIV(k-1) < 0 means:
*>               D(k-1:k,k-1:k) is a 2-by-2 diagonal block.
*>               (NOTE: negative entries in IPIV appear ONLY in pairs).
*>               1) If -IPIV(k) != k, rows and columns
*>                  k and -IPIV(k) were interchanged
*>                  in the matrix A(1:N,N-KB+1:N).
*>                  If -IPIV(k) = k, no interchange occurred.
*>               2) If -IPIV(k-1) != k-1, rows and columns
*>                  k-1 and -IPIV(k-1) were interchanged
*>                  in the submatrix A(1:N,N-KB+1:N).
*>                  If -IPIV(k-1) = k-1, no interchange occurred.
*>
*>            c) In both cases a) and b) is always ABS( IPIV(k) ) <= k.
*>
*>            d) NOTE: Any entry IPIV(k) is always NONZERO on output.
*>
*>          If UPLO = 'L',
*>          ( in factorization order, k increases from 1 to N ):
*>            a) A single positive entry IPIV(k) > 0 means:
*>               D(k,k) is a 1-by-1 diagonal block.
*>               If IPIV(k) != k, rows and columns k and IPIV(k) were
*>               interchanged in the submatrix A(1:N,1:KB).
*>               If IPIV(k) = k, no interchange occurred.
*>
*>            b) A pair of consecutive negative entries
*>               IPIV(k) < 0 and IPIV(k+1) < 0 means:
*>               D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
*>               (NOTE: negative entries in IPIV appear ONLY in pairs).
*>               1) If -IPIV(k) != k, rows and columns
*>                  k and -IPIV(k) were interchanged
*>                  in the submatrix A(1:N,1:KB).
*>                  If -IPIV(k) = k, no interchange occurred.
*>               2) If -IPIV(k+1) != k+1, rows and columns
*>                  k-1 and -IPIV(k-1) were interchanged
*>                  in the submatrix A(1:N,1:KB).
*>                  If -IPIV(k+1) = k+1, no interchange occurred.
*>
*>            c) In both cases a) and b) is always ABS( IPIV(k) ) >= k.
*>
*>            d) NOTE: Any entry IPIV(k) is always NONZERO on output.
*> \endverbatim
*>
*> \param[out] W
*> \verbatim
*>          W is COMPLEX*16 array, dimension (LDW,NB)
*> \endverbatim
*>
*> \param[in] LDW
*> \verbatim
*>          LDW is INTEGER
*>          The leading dimension of the array W.  LDW >= max(1,N).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>
*>          < 0: If INFO = -k, the k-th argument had an illegal value
*>
*>          > 0: If INFO = k, the matrix A is singular, because:
*>                 If UPLO = 'U': column k in the upper
*>                 triangular part of A contains all zeros.
*>                 If UPLO = 'L': column k in the lower
*>                 triangular part of A contains all zeros.
*>
*>               Therefore D(k,k) is exactly zero, and superdiagonal
*>               elements of column k of U (or subdiagonal elements of
*>               column k of L ) are all zeros. The factorization has
*>               been completed, but the block diagonal matrix D is
*>               exactly singular, and division by zero will occur if
*>               it is used to solve a system of equations.
*>
*>               NOTE: INFO only stores the first occurrence of
*>               a singularity, any subsequent occurrence of singularity
*>               is not stored in INFO even though the factorization
*>               always completes.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup lahef_rk
*
*> \par Contributors:
*  ==================
*>
*> \verbatim
*>
*>  December 2016,  Igor Kozachenko,
*>                  Computer Science Division,
*>                  University of California, Berkeley
*>
*>  September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
*>                  School of Mathematics,
*>                  University of Manchester
*>
*> \endverbatim
*
*  =====================================================================
      SUBROUTINE zlasyf_rk( UPLO, N, NB, KB, A, LDA, E, IPIV, W, LDW,
     $                      INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, KB, LDA, LDW, N, NB
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX*16         A( LDA, * ), E( * ), W( LDW, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      DOUBLE PRECISION   EIGHT, SEVTEN
      parameter( eight = 8.0d+0, sevten = 17.0d+0 )
      COMPLEX*16         CONE, CZERO
      parameter( cone = ( 1.0d+0, 0.0d+0 ),
     $                   czero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            DONE
      INTEGER            IMAX, ITEMP, J, JB, JJ, JMAX, K, KK, KW, KKW,
     $                   kp, kstep, p, ii
      DOUBLE PRECISION   ABSAKK, ALPHA, COLMAX, ROWMAX, SFMIN, DTEMP
      COMPLEX*16         D11, D12, D21, D22, R1, T, Z
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            IZAMAX
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           lsame, izamax, dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           zcopy, zgemmtr, zgemv, zscal, zswap
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max, min, sqrt
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( z ) = abs( dble( z ) ) + abs( dimag( z ) )
*     ..
*     .. Executable Statements ..
*
      info = 0
*
*     Initialize ALPHA for use in choosing pivot block size.
*
      alpha = ( one+sqrt( sevten ) ) / eight
*
*     Compute machine safe minimum
*
      sfmin = dlamch( 'S' )
*
      IF( lsame( uplo, 'U' ) ) THEN
*
*        Factorize the trailing columns of A using the upper triangle
*        of A and working backwards, and compute the matrix W = U12*D
*        for use in updating A11
*
*        Initialize the first entry of array E, where superdiagonal
*        elements of D are stored
*
         e( 1 ) = czero
*
*        K is the main loop index, decreasing from N in steps of 1 or 2
*
         k = n
   10    CONTINUE
*
*        KW is the column of W which corresponds to column K of A
*
         kw = nb + k - n
*
*        Exit from loop
*
         IF( ( k.LE.n-nb+1 .AND. nb.LT.n ) .OR. k.LT.1 )
     $      GO TO 30
*
         kstep = 1
         p = k
*
*        Copy column K of A to column KW of W and update it
*
         CALL zcopy( k, a( 1, k ), 1, w( 1, kw ), 1 )
         IF( k.LT.n )
     $      CALL zgemv( 'No transpose', k, n-k, -cone, a( 1, k+1 ),
     $                  lda, w( k, kw+1 ), ldw, cone, w( 1, kw ), 1 )
*
*        Determine rows and columns to be interchanged and whether
*        a 1-by-1 or 2-by-2 pivot block will be used
*
         absakk = cabs1( w( k, kw ) )
*
*        IMAX is the row-index of the largest off-diagonal element in
*        column K, and COLMAX is its absolute value.
*        Determine both COLMAX and IMAX.
*
         IF( k.GT.1 ) THEN
            imax = izamax( k-1, w( 1, kw ), 1 )
            colmax = cabs1( w( imax, kw ) )
         ELSE
            colmax = zero
         END IF
*
         IF( max( absakk, colmax ).EQ.zero ) THEN
*
*           Column K is zero or underflow: set INFO and continue
*
            IF( info.EQ.0 )
     $         info = k
            kp = k
            CALL zcopy( k, w( 1, kw ), 1, a( 1, k ), 1 )
*
*           Set E( K ) to zero
*
            IF( k.GT.1 )
     $         e( k ) = czero
*
         ELSE
*
*           ============================================================
*
*           Test for interchange
*
*           Equivalent to testing for ABSAKK.GE.ALPHA*COLMAX
*           (used to handle NaN and Inf)
*
            IF( .NOT.( absakk.LT.alpha*colmax ) ) THEN
*
*              no interchange, use 1-by-1 pivot block
*
               kp = k
*
            ELSE
*
               done = .false.
*
*              Loop until pivot found
*
   12          CONTINUE
*
*                 Begin pivot search loop body
*
*
*                 Copy column IMAX to column KW-1 of W and update it
*
                  CALL zcopy( imax, a( 1, imax ), 1, w( 1, kw-1 ),
     $                        1 )
                  CALL zcopy( k-imax, a( imax, imax+1 ), lda,
     $                        w( imax+1, kw-1 ), 1 )
*
                  IF( k.LT.n )
     $               CALL zgemv( 'No transpose', k, n-k, -cone,
     $                           a( 1, k+1 ), lda, w( imax, kw+1 ), ldw,
     $                           cone, w( 1, kw-1 ), 1 )
*
*                 JMAX is the column-index of the largest off-diagonal
*                 element in row IMAX, and ROWMAX is its absolute value.
*                 Determine both ROWMAX and JMAX.
*
                  IF( imax.NE.k ) THEN
                     jmax = imax + izamax( k-imax, w( imax+1, kw-1 ),
     $                                     1 )
                     rowmax = cabs1( w( jmax, kw-1 ) )
                  ELSE
                     rowmax = zero
                  END IF
*
                  IF( imax.GT.1 ) THEN
                     itemp = izamax( imax-1, w( 1, kw-1 ), 1 )
                     dtemp = cabs1( w( itemp, kw-1 ) )
                     IF( dtemp.GT.rowmax ) THEN
                        rowmax = dtemp
                        jmax = itemp
                     END IF
                  END IF
*
*                 Equivalent to testing for
*                 CABS1( W( IMAX, KW-1 ) ).GE.ALPHA*ROWMAX
*                 (used to handle NaN and Inf)
*
                  IF( .NOT.(cabs1( w( imax, kw-1 ) ).LT.alpha*rowmax ) )
     $            THEN
*
*                    interchange rows and columns K and IMAX,
*                    use 1-by-1 pivot block
*
                     kp = imax
*
*                    copy column KW-1 of W to column KW of W
*
                     CALL zcopy( k, w( 1, kw-1 ), 1, w( 1, kw ), 1 )
*
                     done = .true.
*
*                 Equivalent to testing for ROWMAX.EQ.COLMAX,
*                 (used to handle NaN and Inf)
*
                  ELSE IF( ( p.EQ.jmax ) .OR. ( rowmax.LE.colmax ) )
     $            THEN
*
*                    interchange rows and columns K-1 and IMAX,
*                    use 2-by-2 pivot block
*
                     kp = imax
                     kstep = 2
                     done = .true.
                  ELSE
*
*                    Pivot not found: set params and repeat
*
                     p = imax
                     colmax = rowmax
                     imax = jmax
*
*                    Copy updated JMAXth (next IMAXth) column to Kth of W
*
                     CALL zcopy( k, w( 1, kw-1 ), 1, w( 1, kw ), 1 )
*
                  END IF
*
*                 End pivot search loop body
*
               IF( .NOT. done ) GOTO 12
*
            END IF
*
*           ============================================================
*
            kk = k - kstep + 1
*
*           KKW is the column of W which corresponds to column KK of A
*
            kkw = nb + kk - n
*
            IF( ( kstep.EQ.2 ) .AND. ( p.NE.k ) ) THEN
*
*              Copy non-updated column K to column P
*
               CALL zcopy( k-p, a( p+1, k ), 1, a( p, p+1 ), lda )
               CALL zcopy( p, a( 1, k ), 1, a( 1, p ), 1 )
*
*              Interchange rows K and P in last N-K+1 columns of A
*              and last N-K+2 columns of W
*
               CALL zswap( n-k+1, a( k, k ), lda, a( p, k ), lda )
               CALL zswap( n-kk+1, w( k, kkw ), ldw, w( p, kkw ),
     $                     ldw )
            END IF
*
*           Updated column KP is already stored in column KKW of W
*
            IF( kp.NE.kk ) THEN
*
*              Copy non-updated column KK to column KP
*
               a( kp, k ) = a( kk, k )
               CALL zcopy( k-1-kp, a( kp+1, kk ), 1, a( kp, kp+1 ),
     $                     lda )
               CALL zcopy( kp, a( 1, kk ), 1, a( 1, kp ), 1 )
*
*              Interchange rows KK and KP in last N-KK+1 columns
*              of A and W
*
               CALL zswap( n-kk+1, a( kk, kk ), lda, a( kp, kk ),
     $                     lda )
               CALL zswap( n-kk+1, w( kk, kkw ), ldw, w( kp, kkw ),
     $                     ldw )
            END IF
*
            IF( kstep.EQ.1 ) THEN
*
*              1-by-1 pivot block D(k): column KW of W now holds
*
*              W(k) = U(k)*D(k)
*
*              where U(k) is the k-th column of U
*
*              Store U(k) in column k of A
*
               CALL zcopy( k, w( 1, kw ), 1, a( 1, k ), 1 )
               IF( k.GT.1 ) THEN
                  IF( cabs1( a( k, k ) ).GE.sfmin ) THEN
                     r1 = cone / a( k, k )
                     CALL zscal( k-1, r1, a( 1, k ), 1 )
                  ELSE IF( a( k, k ).NE.czero ) THEN
                     DO 14 ii = 1, k - 1
                        a( ii, k ) = a( ii, k ) / a( k, k )
   14                CONTINUE
                  END IF
*
*                 Store the superdiagonal element of D in array E
*
                  e( k ) = czero
*
               END IF
*
            ELSE
*
*              2-by-2 pivot block D(k): columns KW and KW-1 of W now
*              hold
*
*              ( W(k-1) W(k) ) = ( U(k-1) U(k) )*D(k)
*
*              where U(k) and U(k-1) are the k-th and (k-1)-th columns
*              of U
*
               IF( k.GT.2 ) THEN
*
*                 Store U(k) and U(k-1) in columns k and k-1 of A
*
                  d12 = w( k-1, kw )
                  d11 = w( k, kw ) / d12
                  d22 = w( k-1, kw-1 ) / d12
                  t = cone / ( d11*d22-cone )
                  DO 20 j = 1, k - 2
                     a( j, k-1 ) = t*( (d11*w( j, kw-1 )-w( j, kw ) ) /
     $                             d12 )
                     a( j, k ) = t*( ( d22*w( j, kw )-w( j, kw-1 ) ) /
     $                           d12 )
   20             CONTINUE
               END IF
*
*              Copy diagonal elements of D(K) to A,
*              copy superdiagonal element of D(K) to E(K) and
*              ZERO out superdiagonal entry of A
*
               a( k-1, k-1 ) = w( k-1, kw-1 )
               a( k-1, k ) = czero
               a( k, k ) = w( k, kw )
               e( k ) = w( k-1, kw )
               e( k-1 ) = czero
*
            END IF
*
*           End column K is nonsingular
*
         END IF
*
*        Store details of the interchanges in IPIV
*
         IF( kstep.EQ.1 ) THEN
            ipiv( k ) = kp
         ELSE
            ipiv( k ) = -p
            ipiv( k-1 ) = -kp
         END IF
*
*        Decrease K and return to the start of the main loop
*
         k = k - kstep
         GO TO 10
*
   30    CONTINUE
*
*        Update the upper triangle of A11 (= A(1:k,1:k)) as
*
*        A11 := A11 - U12*D*U12**T = A11 - U12*W**T
*
         CALL zgemmtr( 'Upper', 'No transpose', 'Transpose', k, n-k,
     $                 -cone, a( 1, k+1 ), lda, w( 1, kw+1 ), ldw,
     $                 cone, a( 1, 1 ), lda )
*
*        Set KB to the number of columns factorized
*
         kb = n - k
*
      ELSE
*
*        Factorize the leading columns of A using the lower triangle
*        of A and working forwards, and compute the matrix W = L21*D
*        for use in updating A22
*
*        Initialize the unused last entry of the subdiagonal array E.
*
         e( n ) = czero
*
*        K is the main loop index, increasing from 1 in steps of 1 or 2
*
         k = 1
   70   CONTINUE
*
*        Exit from loop
*
         IF( ( k.GE.nb .AND. nb.LT.n ) .OR. k.GT.n )
     $      GO TO 90
*
         kstep = 1
         p = k
*
*        Copy column K of A to column K of W and update it
*
         CALL zcopy( n-k+1, a( k, k ), 1, w( k, k ), 1 )
         IF( k.GT.1 )
     $      CALL zgemv( 'No transpose', n-k+1, k-1, -cone, a( k, 1 ),
     $                  lda, w( k, 1 ), ldw, cone, w( k, k ), 1 )
*
*        Determine rows and columns to be interchanged and whether
*        a 1-by-1 or 2-by-2 pivot block will be used
*
         absakk = cabs1( w( k, k ) )
*
*        IMAX is the row-index of the largest off-diagonal element in
*        column K, and COLMAX is its absolute value.
*        Determine both COLMAX and IMAX.
*
         IF( k.LT.n ) THEN
            imax = k + izamax( n-k, w( k+1, k ), 1 )
            colmax = cabs1( w( imax, k ) )
         ELSE
            colmax = zero
         END IF
*
         IF( max( absakk, colmax ).EQ.zero ) THEN
*
*           Column K is zero or underflow: set INFO and continue
*
            IF( info.EQ.0 )
     $         info = k
            kp = k
            CALL zcopy( n-k+1, w( k, k ), 1, a( k, k ), 1 )
*
*           Set E( K ) to zero
*
            IF( k.LT.n )
     $         e( k ) = czero
*
         ELSE
*
*           ============================================================
*
*           Test for interchange
*
*           Equivalent to testing for ABSAKK.GE.ALPHA*COLMAX
*           (used to handle NaN and Inf)
*
            IF( .NOT.( absakk.LT.alpha*colmax ) ) THEN
*
*              no interchange, use 1-by-1 pivot block
*
               kp = k
*
            ELSE
*
               done = .false.
*
*              Loop until pivot found
*
   72          CONTINUE
*
*                 Begin pivot search loop body
*
*
*                 Copy column IMAX to column K+1 of W and update it
*
                  CALL zcopy( imax-k, a( imax, k ), lda, w( k, k+1 ),
     $                        1)
                  CALL zcopy( n-imax+1, a( imax, imax ), 1,
     $                        w( imax, k+1 ), 1 )
                  IF( k.GT.1 )
     $               CALL zgemv( 'No transpose', n-k+1, k-1, -cone,
     $                           a( k, 1 ), lda, w( imax, 1 ), ldw,
     $                           cone, w( k, k+1 ), 1 )
*
*                 JMAX is the column-index of the largest off-diagonal
*                 element in row IMAX, and ROWMAX is its absolute value.
*                 Determine both ROWMAX and JMAX.
*
                  IF( imax.NE.k ) THEN
                     jmax = k - 1 + izamax( imax-k, w( k, k+1 ), 1 )
                     rowmax = cabs1( w( jmax, k+1 ) )
                  ELSE
                     rowmax = zero
                  END IF
*
                  IF( imax.LT.n ) THEN
                     itemp = imax + izamax( n-imax, w( imax+1, k+1 ),
     $                                      1)
                     dtemp = cabs1( w( itemp, k+1 ) )
                     IF( dtemp.GT.rowmax ) THEN
                        rowmax = dtemp
                        jmax = itemp
                     END IF
                  END IF
*
*                 Equivalent to testing for
*                 CABS1( W( IMAX, K+1 ) ).GE.ALPHA*ROWMAX
*                 (used to handle NaN and Inf)
*
                  IF( .NOT.( cabs1( w( imax, k+1 ) ).LT.alpha*rowmax ) )
     $            THEN
*
*                    interchange rows and columns K and IMAX,
*                    use 1-by-1 pivot block
*
                     kp = imax
*
*                    copy column K+1 of W to column K of W
*
                     CALL zcopy( n-k+1, w( k, k+1 ), 1, w( k, k ),
     $                           1 )
*
                     done = .true.
*
*                 Equivalent to testing for ROWMAX.EQ.COLMAX,
*                 (used to handle NaN and Inf)
*
                  ELSE IF( ( p.EQ.jmax ) .OR. ( rowmax.LE.colmax ) )
     $            THEN
*
*                    interchange rows and columns K+1 and IMAX,
*                    use 2-by-2 pivot block
*
                     kp = imax
                     kstep = 2
                     done = .true.
                  ELSE
*
*                    Pivot not found: set params and repeat
*
                     p = imax
                     colmax = rowmax
                     imax = jmax
*
*                    Copy updated JMAXth (next IMAXth) column to Kth of W
*
                     CALL zcopy( n-k+1, w( k, k+1 ), 1, w( k, k ),
     $                           1 )
*
                  END IF
*
*                 End pivot search loop body
*
               IF( .NOT. done ) GOTO 72
*
            END IF
*
*           ============================================================
*
            kk = k + kstep - 1
*
            IF( ( kstep.EQ.2 ) .AND. ( p.NE.k ) ) THEN
*
*              Copy non-updated column K to column P
*
               CALL zcopy( p-k, a( k, k ), 1, a( p, k ), lda )
               CALL zcopy( n-p+1, a( p, k ), 1, a( p, p ), 1 )
*
*              Interchange rows K and P in first K columns of A
*              and first K+1 columns of W
*
               CALL zswap( k, a( k, 1 ), lda, a( p, 1 ), lda )
               CALL zswap( kk, w( k, 1 ), ldw, w( p, 1 ), ldw )
            END IF
*
*           Updated column KP is already stored in column KK of W
*
            IF( kp.NE.kk ) THEN
*
*              Copy non-updated column KK to column KP
*
               a( kp, k ) = a( kk, k )
               CALL zcopy( kp-k-1, a( k+1, kk ), 1, a( kp, k+1 ),
     $                     lda )
               CALL zcopy( n-kp+1, a( kp, kk ), 1, a( kp, kp ), 1 )
*
*              Interchange rows KK and KP in first KK columns of A and W
*
               CALL zswap( kk, a( kk, 1 ), lda, a( kp, 1 ), lda )
               CALL zswap( kk, w( kk, 1 ), ldw, w( kp, 1 ), ldw )
            END IF
*
            IF( kstep.EQ.1 ) THEN
*
*              1-by-1 pivot block D(k): column k of W now holds
*
*              W(k) = L(k)*D(k)
*
*              where L(k) is the k-th column of L
*
*              Store L(k) in column k of A
*
               CALL zcopy( n-k+1, w( k, k ), 1, a( k, k ), 1 )
               IF( k.LT.n ) THEN
                  IF( cabs1( a( k, k ) ).GE.sfmin ) THEN
                     r1 = cone / a( k, k )
                     CALL zscal( n-k, r1, a( k+1, k ), 1 )
                  ELSE IF( a( k, k ).NE.czero ) THEN
                     DO 74 ii = k + 1, n
                        a( ii, k ) = a( ii, k ) / a( k, k )
   74                CONTINUE
                  END IF
*
*                 Store the subdiagonal element of D in array E
*
                  e( k ) = czero
*
               END IF
*
            ELSE
*
*              2-by-2 pivot block D(k): columns k and k+1 of W now hold
*
*              ( W(k) W(k+1) ) = ( L(k) L(k+1) )*D(k)
*
*              where L(k) and L(k+1) are the k-th and (k+1)-th columns
*              of L
*
               IF( k.LT.n-1 ) THEN
*
*                 Store L(k) and L(k+1) in columns k and k+1 of A
*
                  d21 = w( k+1, k )
                  d11 = w( k+1, k+1 ) / d21
                  d22 = w( k, k ) / d21
                  t = cone / ( d11*d22-cone )
                  DO 80 j = k + 2, n
                     a( j, k ) = t*( ( d11*w( j, k )-w( j, k+1 ) ) /
     $                           d21 )
                     a( j, k+1 ) = t*( ( d22*w( j, k+1 )-w( j, k ) ) /
     $                             d21 )
   80             CONTINUE
               END IF
*
*              Copy diagonal elements of D(K) to A,
*              copy subdiagonal element of D(K) to E(K) and
*              ZERO out subdiagonal entry of A
*
               a( k, k ) = w( k, k )
               a( k+1, k ) = czero
               a( k+1, k+1 ) = w( k+1, k+1 )
               e( k ) = w( k+1, k )
               e( k+1 ) = czero
*
            END IF
*
*           End column K is nonsingular
*
         END IF
*
*        Store details of the interchanges in IPIV
*
         IF( kstep.EQ.1 ) THEN
            ipiv( k ) = kp
         ELSE
            ipiv( k ) = -p
            ipiv( k+1 ) = -kp
         END IF
*
*        Increase K and return to the start of the main loop
*
         k = k + kstep
         GO TO 70
*
   90    CONTINUE
*
*        Update the lower triangle of A22 (= A(k:n,k:n)) as
*
*        A22 := A22 - L21*D*L21**T = A22 - L21*W**T
*
         CALL zgemmtr( 'Lower', 'No transpose', 'Transpose', n-k+1,
     $                 k-1, -cone, a( k, 1 ), lda, w( k, 1 ), ldw,
     $                 cone, a( k, k ), lda )
*
*        Set KB to the number of columns factorized
*
         kb = k - 1
*
      END IF
*
      RETURN
*
*     End of ZLASYF_RK
*
      END