LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ zlanhe()

double precision function zlanhe ( character  NORM,
character  UPLO,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  WORK 
)

ZLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix.

Download ZLANHE + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLANHE  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 complex hermitian matrix A.
Returns
ZLANHE
    ZLANHE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in ZLANHE as described
          above.
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          hermitian matrix A is to be referenced.
          = 'U':  Upper triangular part of A is referenced
          = 'L':  Lower triangular part of A is referenced
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, ZLANHE is
          set to zero.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
          The hermitian matrix A.  If UPLO = 'U', the leading n by n
          upper triangular part of A contains the upper triangular part
          of the matrix A, and the strictly lower triangular part of A
          is not referenced.  If UPLO = 'L', the leading n by n lower
          triangular part of A contains the lower triangular part of
          the matrix A, and the strictly upper triangular part of A is
          not referenced. Note that the imaginary parts of the diagonal
          elements need not be set and are assumed to be zero.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(N,1).
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
          WORK is not referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 123 of file zlanhe.f.

124 *
125 * -- LAPACK auxiliary routine --
126 * -- LAPACK is a software package provided by Univ. of Tennessee, --
127 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
128 *
129  IMPLICIT NONE
130 * .. Scalar Arguments ..
131  CHARACTER NORM, UPLO
132  INTEGER LDA, N
133 * ..
134 * .. Array Arguments ..
135  DOUBLE PRECISION WORK( * )
136  COMPLEX*16 A( LDA, * )
137 * ..
138 *
139 * =====================================================================
140 *
141 * .. Parameters ..
142  DOUBLE PRECISION ONE, ZERO
143  parameter( one = 1.0d+0, zero = 0.0d+0 )
144 * ..
145 * .. Local Scalars ..
146  INTEGER I, J
147  DOUBLE PRECISION ABSA, SUM, VALUE
148 * ..
149 * .. Local Arrays ..
150  DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
151 * ..
152 * .. External Functions ..
153  LOGICAL LSAME, DISNAN
154  EXTERNAL lsame, disnan
155 * ..
156 * .. External Subroutines ..
157  EXTERNAL zlassq, dcombssq
158 * ..
159 * .. Intrinsic Functions ..
160  INTRINSIC abs, dble, sqrt
161 * ..
162 * .. Executable Statements ..
163 *
164  IF( n.EQ.0 ) THEN
165  VALUE = zero
166  ELSE IF( lsame( norm, 'M' ) ) THEN
167 *
168 * Find max(abs(A(i,j))).
169 *
170  VALUE = zero
171  IF( lsame( uplo, 'U' ) ) THEN
172  DO 20 j = 1, n
173  DO 10 i = 1, j - 1
174  sum = abs( a( i, j ) )
175  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
176  10 CONTINUE
177  sum = abs( dble( a( j, j ) ) )
178  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
179  20 CONTINUE
180  ELSE
181  DO 40 j = 1, n
182  sum = abs( dble( a( j, j ) ) )
183  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
184  DO 30 i = j + 1, n
185  sum = abs( a( i, j ) )
186  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
187  30 CONTINUE
188  40 CONTINUE
189  END IF
190  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
191  $ ( norm.EQ.'1' ) ) THEN
192 *
193 * Find normI(A) ( = norm1(A), since A is hermitian).
194 *
195  VALUE = zero
196  IF( lsame( uplo, 'U' ) ) THEN
197  DO 60 j = 1, n
198  sum = zero
199  DO 50 i = 1, j - 1
200  absa = abs( a( i, j ) )
201  sum = sum + absa
202  work( i ) = work( i ) + absa
203  50 CONTINUE
204  work( j ) = sum + abs( dble( a( j, j ) ) )
205  60 CONTINUE
206  DO 70 i = 1, n
207  sum = work( i )
208  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
209  70 CONTINUE
210  ELSE
211  DO 80 i = 1, n
212  work( i ) = zero
213  80 CONTINUE
214  DO 100 j = 1, n
215  sum = work( j ) + abs( dble( a( j, j ) ) )
216  DO 90 i = j + 1, n
217  absa = abs( a( i, j ) )
218  sum = sum + absa
219  work( i ) = work( i ) + absa
220  90 CONTINUE
221  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
222  100 CONTINUE
223  END IF
224  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
225 *
226 * Find normF(A).
227 * SSQ(1) is scale
228 * SSQ(2) is sum-of-squares
229 * For better accuracy, sum each column separately.
230 *
231  ssq( 1 ) = zero
232  ssq( 2 ) = one
233 *
234 * Sum off-diagonals
235 *
236  IF( lsame( uplo, 'U' ) ) THEN
237  DO 110 j = 2, n
238  colssq( 1 ) = zero
239  colssq( 2 ) = one
240  CALL zlassq( j-1, a( 1, j ), 1,
241  $ colssq( 1 ), colssq( 2 ) )
242  CALL dcombssq( ssq, colssq )
243  110 CONTINUE
244  ELSE
245  DO 120 j = 1, n - 1
246  colssq( 1 ) = zero
247  colssq( 2 ) = one
248  CALL zlassq( n-j, a( j+1, j ), 1,
249  $ colssq( 1 ), colssq( 2 ) )
250  CALL dcombssq( ssq, colssq )
251  120 CONTINUE
252  END IF
253  ssq( 2 ) = 2*ssq( 2 )
254 *
255 * Sum diagonal
256 *
257  DO 130 i = 1, n
258  IF( dble( a( i, i ) ).NE.zero ) THEN
259  absa = abs( dble( a( i, i ) ) )
260  IF( ssq( 1 ).LT.absa ) THEN
261  ssq( 2 ) = one + ssq( 2 )*( ssq( 1 ) / absa )**2
262  ssq( 1 ) = absa
263  ELSE
264  ssq( 2 ) = ssq( 2 ) + ( absa / ssq( 1 ) )**2
265  END IF
266  END IF
267  130 CONTINUE
268  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
269  END IF
270 *
271  zlanhe = VALUE
272  RETURN
273 *
274 * End of ZLANHE
275 *
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine dcombssq(V1, V2)
DCOMBSSQ adds two scaled sum of squares quantities.
Definition: dcombssq.f:60
subroutine zlassq(n, x, incx, scl, sumsq)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f90:126
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function zlanhe(NORM, UPLO, N, A, LDA, WORK)
ZLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: zlanhe.f:124
Here is the call graph for this function:
Here is the caller graph for this function: