LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ dlanhs()

double precision function dlanhs ( character  NORM,
integer  N,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  WORK 
)

DLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of an upper Hessenberg matrix.

Download DLANHS + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLANHS  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 Hessenberg matrix A.
Returns
DLANHS
    DLANHS = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in DLANHS as described
          above.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, DLANHS is
          set to zero.
[in]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          The n by n upper Hessenberg matrix A; the part of A below the
          first sub-diagonal is not referenced.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(N,1).
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I'; otherwise, WORK is not
          referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 107 of file dlanhs.f.

108 *
109 * -- LAPACK auxiliary routine --
110 * -- LAPACK is a software package provided by Univ. of Tennessee, --
111 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
112 *
113  IMPLICIT NONE
114 * .. Scalar Arguments ..
115  CHARACTER NORM
116  INTEGER LDA, N
117 * ..
118 * .. Array Arguments ..
119  DOUBLE PRECISION A( LDA, * ), WORK( * )
120 * ..
121 *
122 * =====================================================================
123 *
124 * .. Parameters ..
125  DOUBLE PRECISION ONE, ZERO
126  parameter( one = 1.0d+0, zero = 0.0d+0 )
127 * ..
128 * .. Local Scalars ..
129  INTEGER I, J
130  DOUBLE PRECISION SUM, VALUE
131 * ..
132 * .. Local Arrays ..
133  DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
134 * ..
135 * .. External Functions ..
136  LOGICAL LSAME, DISNAN
137  EXTERNAL lsame, disnan
138 * ..
139 * .. External Subroutines ..
140  EXTERNAL dlassq, dcombssq
141 * ..
142 * .. Intrinsic Functions ..
143  INTRINSIC abs, min, sqrt
144 * ..
145 * .. Executable Statements ..
146 *
147  IF( n.EQ.0 ) THEN
148  VALUE = zero
149  ELSE IF( lsame( norm, 'M' ) ) THEN
150 *
151 * Find max(abs(A(i,j))).
152 *
153  VALUE = zero
154  DO 20 j = 1, n
155  DO 10 i = 1, min( n, j+1 )
156  sum = abs( a( i, j ) )
157  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
158  10 CONTINUE
159  20 CONTINUE
160  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
161 *
162 * Find norm1(A).
163 *
164  VALUE = zero
165  DO 40 j = 1, n
166  sum = zero
167  DO 30 i = 1, min( n, j+1 )
168  sum = sum + abs( a( i, j ) )
169  30 CONTINUE
170  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
171  40 CONTINUE
172  ELSE IF( lsame( norm, 'I' ) ) THEN
173 *
174 * Find normI(A).
175 *
176  DO 50 i = 1, n
177  work( i ) = zero
178  50 CONTINUE
179  DO 70 j = 1, n
180  DO 60 i = 1, min( n, j+1 )
181  work( i ) = work( i ) + abs( a( i, j ) )
182  60 CONTINUE
183  70 CONTINUE
184  VALUE = zero
185  DO 80 i = 1, n
186  sum = work( i )
187  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
188  80 CONTINUE
189  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
190 *
191 * Find normF(A).
192 * SSQ(1) is scale
193 * SSQ(2) is sum-of-squares
194 * For better accuracy, sum each column separately.
195 *
196  ssq( 1 ) = zero
197  ssq( 2 ) = one
198  DO 90 j = 1, n
199  colssq( 1 ) = zero
200  colssq( 2 ) = one
201  CALL dlassq( min( n, j+1 ), a( 1, j ), 1,
202  $ colssq( 1 ), colssq( 2 ) )
203  CALL dcombssq( ssq, colssq )
204  90 CONTINUE
205  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
206  END IF
207 *
208  dlanhs = VALUE
209  RETURN
210 *
211 * End of DLANHS
212 *
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine dlassq(n, x, incx, scl, sumsq)
DLASSQ updates a sum of squares represented in scaled form.
Definition: dlassq.f90:126
subroutine dcombssq(V1, V2)
DCOMBSSQ adds two scaled sum of squares quantities.
Definition: dcombssq.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function dlanhs(NORM, N, A, LDA, WORK)
DLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: dlanhs.f:108
Here is the call graph for this function: