LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ dlahrd()

subroutine dlahrd ( integer  N,
integer  K,
integer  NB,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( nb )  TAU,
double precision, dimension( ldt, nb )  T,
integer  LDT,
double precision, dimension( ldy, nb )  Y,
integer  LDY 
)

DLAHRD reduces the first nb columns of a general rectangular matrix A so that elements below the k-th subdiagonal are zero, and returns auxiliary matrices which are needed to apply the transformation to the unreduced part of A.

Download DLAHRD + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 This routine is deprecated and has been replaced by routine DLAHR2.

 DLAHRD reduces the first NB columns of a real general n-by-(n-k+1)
 matrix A so that elements below the k-th subdiagonal are zero. The
 reduction is performed by an orthogonal similarity transformation
 Q**T * A * Q. The routine returns the matrices V and T which determine
 Q as a block reflector I - V*T*V**T, and also the matrix Y = A * V * T.
Parameters
[in]N
          N is INTEGER
          The order of the matrix A.
[in]K
          K is INTEGER
          The offset for the reduction. Elements below the k-th
          subdiagonal in the first NB columns are reduced to zero.
[in]NB
          NB is INTEGER
          The number of columns to be reduced.
[in,out]A
          A is DOUBLE PRECISION array, dimension (LDA,N-K+1)
          On entry, the n-by-(n-k+1) general matrix A.
          On exit, the elements on and above the k-th subdiagonal in
          the first NB columns are overwritten with the corresponding
          elements of the reduced matrix; the elements below the k-th
          subdiagonal, with the array TAU, represent the matrix Q as a
          product of elementary reflectors. The other columns of A are
          unchanged. See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[out]TAU
          TAU is DOUBLE PRECISION array, dimension (NB)
          The scalar factors of the elementary reflectors. See Further
          Details.
[out]T
          T is DOUBLE PRECISION array, dimension (LDT,NB)
          The upper triangular matrix T.
[in]LDT
          LDT is INTEGER
          The leading dimension of the array T.  LDT >= NB.
[out]Y
          Y is DOUBLE PRECISION array, dimension (LDY,NB)
          The n-by-nb matrix Y.
[in]LDY
          LDY is INTEGER
          The leading dimension of the array Y. LDY >= N.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  The matrix Q is represented as a product of nb elementary reflectors

     Q = H(1) H(2) . . . H(nb).

  Each H(i) has the form

     H(i) = I - tau * v * v**T

  where tau is a real scalar, and v is a real vector with
  v(1:i+k-1) = 0, v(i+k) = 1; v(i+k+1:n) is stored on exit in
  A(i+k+1:n,i), and tau in TAU(i).

  The elements of the vectors v together form the (n-k+1)-by-nb matrix
  V which is needed, with T and Y, to apply the transformation to the
  unreduced part of the matrix, using an update of the form:
  A := (I - V*T*V**T) * (A - Y*V**T).

  The contents of A on exit are illustrated by the following example
  with n = 7, k = 3 and nb = 2:

     ( a   h   a   a   a )
     ( a   h   a   a   a )
     ( a   h   a   a   a )
     ( h   h   a   a   a )
     ( v1  h   a   a   a )
     ( v1  v2  a   a   a )
     ( v1  v2  a   a   a )

  where a denotes an element of the original matrix A, h denotes a
  modified element of the upper Hessenberg matrix H, and vi denotes an
  element of the vector defining H(i).

Definition at line 166 of file dlahrd.f.

167 *
168 * -- LAPACK auxiliary routine --
169 * -- LAPACK is a software package provided by Univ. of Tennessee, --
170 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
171 *
172 * .. Scalar Arguments ..
173  INTEGER K, LDA, LDT, LDY, N, NB
174 * ..
175 * .. Array Arguments ..
176  DOUBLE PRECISION A( LDA, * ), T( LDT, NB ), TAU( NB ),
177  $ Y( LDY, NB )
178 * ..
179 *
180 * =====================================================================
181 *
182 * .. Parameters ..
183  DOUBLE PRECISION ZERO, ONE
184  parameter( zero = 0.0d+0, one = 1.0d+0 )
185 * ..
186 * .. Local Scalars ..
187  INTEGER I
188  DOUBLE PRECISION EI
189 * ..
190 * .. External Subroutines ..
191  EXTERNAL daxpy, dcopy, dgemv, dlarfg, dscal, dtrmv
192 * ..
193 * .. Intrinsic Functions ..
194  INTRINSIC min
195 * ..
196 * .. Executable Statements ..
197 *
198 * Quick return if possible
199 *
200  IF( n.LE.1 )
201  $ RETURN
202 *
203  DO 10 i = 1, nb
204  IF( i.GT.1 ) THEN
205 *
206 * Update A(1:n,i)
207 *
208 * Compute i-th column of A - Y * V**T
209 *
210  CALL dgemv( 'No transpose', n, i-1, -one, y, ldy,
211  $ a( k+i-1, 1 ), lda, one, a( 1, i ), 1 )
212 *
213 * Apply I - V * T**T * V**T to this column (call it b) from the
214 * left, using the last column of T as workspace
215 *
216 * Let V = ( V1 ) and b = ( b1 ) (first I-1 rows)
217 * ( V2 ) ( b2 )
218 *
219 * where V1 is unit lower triangular
220 *
221 * w := V1**T * b1
222 *
223  CALL dcopy( i-1, a( k+1, i ), 1, t( 1, nb ), 1 )
224  CALL dtrmv( 'Lower', 'Transpose', 'Unit', i-1, a( k+1, 1 ),
225  $ lda, t( 1, nb ), 1 )
226 *
227 * w := w + V2**T *b2
228 *
229  CALL dgemv( 'Transpose', n-k-i+1, i-1, one, a( k+i, 1 ),
230  $ lda, a( k+i, i ), 1, one, t( 1, nb ), 1 )
231 *
232 * w := T**T *w
233 *
234  CALL dtrmv( 'Upper', 'Transpose', 'Non-unit', i-1, t, ldt,
235  $ t( 1, nb ), 1 )
236 *
237 * b2 := b2 - V2*w
238 *
239  CALL dgemv( 'No transpose', n-k-i+1, i-1, -one, a( k+i, 1 ),
240  $ lda, t( 1, nb ), 1, one, a( k+i, i ), 1 )
241 *
242 * b1 := b1 - V1*w
243 *
244  CALL dtrmv( 'Lower', 'No transpose', 'Unit', i-1,
245  $ a( k+1, 1 ), lda, t( 1, nb ), 1 )
246  CALL daxpy( i-1, -one, t( 1, nb ), 1, a( k+1, i ), 1 )
247 *
248  a( k+i-1, i-1 ) = ei
249  END IF
250 *
251 * Generate the elementary reflector H(i) to annihilate
252 * A(k+i+1:n,i)
253 *
254  CALL dlarfg( n-k-i+1, a( k+i, i ), a( min( k+i+1, n ), i ), 1,
255  $ tau( i ) )
256  ei = a( k+i, i )
257  a( k+i, i ) = one
258 *
259 * Compute Y(1:n,i)
260 *
261  CALL dgemv( 'No transpose', n, n-k-i+1, one, a( 1, i+1 ), lda,
262  $ a( k+i, i ), 1, zero, y( 1, i ), 1 )
263  CALL dgemv( 'Transpose', n-k-i+1, i-1, one, a( k+i, 1 ), lda,
264  $ a( k+i, i ), 1, zero, t( 1, i ), 1 )
265  CALL dgemv( 'No transpose', n, i-1, -one, y, ldy, t( 1, i ), 1,
266  $ one, y( 1, i ), 1 )
267  CALL dscal( n, tau( i ), y( 1, i ), 1 )
268 *
269 * Compute T(1:i,i)
270 *
271  CALL dscal( i-1, -tau( i ), t( 1, i ), 1 )
272  CALL dtrmv( 'Upper', 'No transpose', 'Non-unit', i-1, t, ldt,
273  $ t( 1, i ), 1 )
274  t( i, i ) = tau( i )
275 *
276  10 CONTINUE
277  a( k+nb, nb ) = ei
278 *
279  RETURN
280 *
281 * End of DLAHRD
282 *
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:82
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:79
subroutine daxpy(N, DA, DX, INCX, DY, INCY)
DAXPY
Definition: daxpy.f:89
subroutine dtrmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
DTRMV
Definition: dtrmv.f:147
subroutine dgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
DGEMV
Definition: dgemv.f:156
subroutine dlarfg(N, ALPHA, X, INCX, TAU)
DLARFG generates an elementary reflector (Householder matrix).
Definition: dlarfg.f:106
Here is the call graph for this function: