LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ dlaqr4()

subroutine dlaqr4 ( logical  WANTT,
logical  WANTZ,
integer  N,
integer  ILO,
integer  IHI,
double precision, dimension( ldh, * )  H,
integer  LDH,
double precision, dimension( * )  WR,
double precision, dimension( * )  WI,
integer  ILOZ,
integer  IHIZ,
double precision, dimension( ldz, * )  Z,
integer  LDZ,
double precision, dimension( * )  WORK,
integer  LWORK,
integer  INFO 
)

DLAQR4 computes the eigenvalues of a Hessenberg matrix, and optionally the matrices from the Schur decomposition.

Download DLAQR4 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
    DLAQR4 implements one level of recursion for DLAQR0.
    It is a complete implementation of the small bulge multi-shift
    QR algorithm.  It may be called by DLAQR0 and, for large enough
    deflation window size, it may be called by DLAQR3.  This
    subroutine is identical to DLAQR0 except that it calls DLAQR2
    instead of DLAQR3.

    DLAQR4 computes the eigenvalues of a Hessenberg matrix H
    and, optionally, the matrices T and Z from the Schur decomposition
    H = Z T Z**T, where T is an upper quasi-triangular matrix (the
    Schur form), and Z is the orthogonal matrix of Schur vectors.

    Optionally Z may be postmultiplied into an input orthogonal
    matrix Q so that this routine can give the Schur factorization
    of a matrix A which has been reduced to the Hessenberg form H
    by the orthogonal matrix Q:  A = Q*H*Q**T = (QZ)*T*(QZ)**T.
Parameters
[in]WANTT
          WANTT is LOGICAL
          = .TRUE. : the full Schur form T is required;
          = .FALSE.: only eigenvalues are required.
[in]WANTZ
          WANTZ is LOGICAL
          = .TRUE. : the matrix of Schur vectors Z is required;
          = .FALSE.: Schur vectors are not required.
[in]N
          N is INTEGER
           The order of the matrix H.  N >= 0.
[in]ILO
          ILO is INTEGER
[in]IHI
          IHI is INTEGER
           It is assumed that H is already upper triangular in rows
           and columns 1:ILO-1 and IHI+1:N and, if ILO > 1,
           H(ILO,ILO-1) is zero. ILO and IHI are normally set by a
           previous call to DGEBAL, and then passed to DGEHRD when the
           matrix output by DGEBAL is reduced to Hessenberg form.
           Otherwise, ILO and IHI should be set to 1 and N,
           respectively.  If N > 0, then 1 <= ILO <= IHI <= N.
           If N = 0, then ILO = 1 and IHI = 0.
[in,out]H
          H is DOUBLE PRECISION array, dimension (LDH,N)
           On entry, the upper Hessenberg matrix H.
           On exit, if INFO = 0 and WANTT is .TRUE., then H contains
           the upper quasi-triangular matrix T from the Schur
           decomposition (the Schur form); 2-by-2 diagonal blocks
           (corresponding to complex conjugate pairs of eigenvalues)
           are returned in standard form, with H(i,i) = H(i+1,i+1)
           and H(i+1,i)*H(i,i+1) < 0. If INFO = 0 and WANTT is
           .FALSE., then the contents of H are unspecified on exit.
           (The output value of H when INFO > 0 is given under the
           description of INFO below.)

           This subroutine may explicitly set H(i,j) = 0 for i > j and
           j = 1, 2, ... ILO-1 or j = IHI+1, IHI+2, ... N.
[in]LDH
          LDH is INTEGER
           The leading dimension of the array H. LDH >= max(1,N).
[out]WR
          WR is DOUBLE PRECISION array, dimension (IHI)
[out]WI
          WI is DOUBLE PRECISION array, dimension (IHI)
           The real and imaginary parts, respectively, of the computed
           eigenvalues of H(ILO:IHI,ILO:IHI) are stored in WR(ILO:IHI)
           and WI(ILO:IHI). If two eigenvalues are computed as a
           complex conjugate pair, they are stored in consecutive
           elements of WR and WI, say the i-th and (i+1)th, with
           WI(i) > 0 and WI(i+1) < 0. If WANTT is .TRUE., then
           the eigenvalues are stored in the same order as on the
           diagonal of the Schur form returned in H, with
           WR(i) = H(i,i) and, if H(i:i+1,i:i+1) is a 2-by-2 diagonal
           block, WI(i) = sqrt(-H(i+1,i)*H(i,i+1)) and
           WI(i+1) = -WI(i).
[in]ILOZ
          ILOZ is INTEGER
[in]IHIZ
          IHIZ is INTEGER
           Specify the rows of Z to which transformations must be
           applied if WANTZ is .TRUE..
           1 <= ILOZ <= ILO; IHI <= IHIZ <= N.
[in,out]Z
          Z is DOUBLE PRECISION array, dimension (LDZ,IHI)
           If WANTZ is .FALSE., then Z is not referenced.
           If WANTZ is .TRUE., then Z(ILO:IHI,ILOZ:IHIZ) is
           replaced by Z(ILO:IHI,ILOZ:IHIZ)*U where U is the
           orthogonal Schur factor of H(ILO:IHI,ILO:IHI).
           (The output value of Z when INFO > 0 is given under
           the description of INFO below.)
[in]LDZ
          LDZ is INTEGER
           The leading dimension of the array Z.  if WANTZ is .TRUE.
           then LDZ >= MAX(1,IHIZ).  Otherwise, LDZ >= 1.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension LWORK
           On exit, if LWORK = -1, WORK(1) returns an estimate of
           the optimal value for LWORK.
[in]LWORK
          LWORK is INTEGER
           The dimension of the array WORK.  LWORK >= max(1,N)
           is sufficient, but LWORK typically as large as 6*N may
           be required for optimal performance.  A workspace query
           to determine the optimal workspace size is recommended.

           If LWORK = -1, then DLAQR4 does a workspace query.
           In this case, DLAQR4 checks the input parameters and
           estimates the optimal workspace size for the given
           values of N, ILO and IHI.  The estimate is returned
           in WORK(1).  No error message related to LWORK is
           issued by XERBLA.  Neither H nor Z are accessed.
[out]INFO
          INFO is INTEGER
             = 0:  successful exit
             > 0:  if INFO = i, DLAQR4 failed to compute all of
                the eigenvalues.  Elements 1:ilo-1 and i+1:n of WR
                and WI contain those eigenvalues which have been
                successfully computed.  (Failures are rare.)

                If INFO > 0 and WANT is .FALSE., then on exit,
                the remaining unconverged eigenvalues are the eigen-
                values of the upper Hessenberg matrix rows and
                columns ILO through INFO of the final, output
                value of H.

                If INFO > 0 and WANTT is .TRUE., then on exit

           (*)  (initial value of H)*U  = U*(final value of H)

                where U is a orthogonal matrix.  The final
                value of  H is upper Hessenberg and triangular in
                rows and columns INFO+1 through IHI.

                If INFO > 0 and WANTZ is .TRUE., then on exit

                  (final value of Z(ILO:IHI,ILOZ:IHIZ)
                   =  (initial value of Z(ILO:IHI,ILOZ:IHIZ)*U

                where U is the orthogonal matrix in (*) (regard-
                less of the value of WANTT.)

                If INFO > 0 and WANTZ is .FALSE., then Z is not
                accessed.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
Karen Braman and Ralph Byers, Department of Mathematics, University of Kansas, USA
References:
  K. Braman, R. Byers and R. Mathias, The Multi-Shift QR
  Algorithm Part I: Maintaining Well Focused Shifts, and Level 3
  Performance, SIAM Journal of Matrix Analysis, volume 23, pages
  929--947, 2002.

K. Braman, R. Byers and R. Mathias, The Multi-Shift QR Algorithm Part II: Aggressive Early Deflation, SIAM Journal of Matrix Analysis, volume 23, pages 948–973, 2002.

Definition at line 261 of file dlaqr4.f.

263 *
264 * -- LAPACK auxiliary routine --
265 * -- LAPACK is a software package provided by Univ. of Tennessee, --
266 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
267 *
268 * .. Scalar Arguments ..
269  INTEGER IHI, IHIZ, ILO, ILOZ, INFO, LDH, LDZ, LWORK, N
270  LOGICAL WANTT, WANTZ
271 * ..
272 * .. Array Arguments ..
273  DOUBLE PRECISION H( LDH, * ), WI( * ), WORK( * ), WR( * ),
274  $ Z( LDZ, * )
275 * ..
276 *
277 * ================================================================
278 * .. Parameters ..
279 *
280 * ==== Matrices of order NTINY or smaller must be processed by
281 * . DLAHQR because of insufficient subdiagonal scratch space.
282 * . (This is a hard limit.) ====
283  INTEGER NTINY
284  parameter( ntiny = 15 )
285 *
286 * ==== Exceptional deflation windows: try to cure rare
287 * . slow convergence by varying the size of the
288 * . deflation window after KEXNW iterations. ====
289  INTEGER KEXNW
290  parameter( kexnw = 5 )
291 *
292 * ==== Exceptional shifts: try to cure rare slow convergence
293 * . with ad-hoc exceptional shifts every KEXSH iterations.
294 * . ====
295  INTEGER KEXSH
296  parameter( kexsh = 6 )
297 *
298 * ==== The constants WILK1 and WILK2 are used to form the
299 * . exceptional shifts. ====
300  DOUBLE PRECISION WILK1, WILK2
301  parameter( wilk1 = 0.75d0, wilk2 = -0.4375d0 )
302  DOUBLE PRECISION ZERO, ONE
303  parameter( zero = 0.0d0, one = 1.0d0 )
304 * ..
305 * .. Local Scalars ..
306  DOUBLE PRECISION AA, BB, CC, CS, DD, SN, SS, SWAP
307  INTEGER I, INF, IT, ITMAX, K, KACC22, KBOT, KDU, KS,
308  $ KT, KTOP, KU, KV, KWH, KWTOP, KWV, LD, LS,
309  $ LWKOPT, NDEC, NDFL, NH, NHO, NIBBLE, NMIN, NS,
310  $ NSMAX, NSR, NVE, NW, NWMAX, NWR, NWUPBD
311  LOGICAL SORTED
312  CHARACTER JBCMPZ*2
313 * ..
314 * .. External Functions ..
315  INTEGER ILAENV
316  EXTERNAL ilaenv
317 * ..
318 * .. Local Arrays ..
319  DOUBLE PRECISION ZDUM( 1, 1 )
320 * ..
321 * .. External Subroutines ..
322  EXTERNAL dlacpy, dlahqr, dlanv2, dlaqr2, dlaqr5
323 * ..
324 * .. Intrinsic Functions ..
325  INTRINSIC abs, dble, int, max, min, mod
326 * ..
327 * .. Executable Statements ..
328  info = 0
329 *
330 * ==== Quick return for N = 0: nothing to do. ====
331 *
332  IF( n.EQ.0 ) THEN
333  work( 1 ) = one
334  RETURN
335  END IF
336 *
337  IF( n.LE.ntiny ) THEN
338 *
339 * ==== Tiny matrices must use DLAHQR. ====
340 *
341  lwkopt = 1
342  IF( lwork.NE.-1 )
343  $ CALL dlahqr( wantt, wantz, n, ilo, ihi, h, ldh, wr, wi,
344  $ iloz, ihiz, z, ldz, info )
345  ELSE
346 *
347 * ==== Use small bulge multi-shift QR with aggressive early
348 * . deflation on larger-than-tiny matrices. ====
349 *
350 * ==== Hope for the best. ====
351 *
352  info = 0
353 *
354 * ==== Set up job flags for ILAENV. ====
355 *
356  IF( wantt ) THEN
357  jbcmpz( 1: 1 ) = 'S'
358  ELSE
359  jbcmpz( 1: 1 ) = 'E'
360  END IF
361  IF( wantz ) THEN
362  jbcmpz( 2: 2 ) = 'V'
363  ELSE
364  jbcmpz( 2: 2 ) = 'N'
365  END IF
366 *
367 * ==== NWR = recommended deflation window size. At this
368 * . point, N .GT. NTINY = 15, so there is enough
369 * . subdiagonal workspace for NWR.GE.2 as required.
370 * . (In fact, there is enough subdiagonal space for
371 * . NWR.GE.4.) ====
372 *
373  nwr = ilaenv( 13, 'DLAQR4', jbcmpz, n, ilo, ihi, lwork )
374  nwr = max( 2, nwr )
375  nwr = min( ihi-ilo+1, ( n-1 ) / 3, nwr )
376 *
377 * ==== NSR = recommended number of simultaneous shifts.
378 * . At this point N .GT. NTINY = 15, so there is at
379 * . enough subdiagonal workspace for NSR to be even
380 * . and greater than or equal to two as required. ====
381 *
382  nsr = ilaenv( 15, 'DLAQR4', jbcmpz, n, ilo, ihi, lwork )
383  nsr = min( nsr, ( n-3 ) / 6, ihi-ilo )
384  nsr = max( 2, nsr-mod( nsr, 2 ) )
385 *
386 * ==== Estimate optimal workspace ====
387 *
388 * ==== Workspace query call to DLAQR2 ====
389 *
390  CALL dlaqr2( wantt, wantz, n, ilo, ihi, nwr+1, h, ldh, iloz,
391  $ ihiz, z, ldz, ls, ld, wr, wi, h, ldh, n, h, ldh,
392  $ n, h, ldh, work, -1 )
393 *
394 * ==== Optimal workspace = MAX(DLAQR5, DLAQR2) ====
395 *
396  lwkopt = max( 3*nsr / 2, int( work( 1 ) ) )
397 *
398 * ==== Quick return in case of workspace query. ====
399 *
400  IF( lwork.EQ.-1 ) THEN
401  work( 1 ) = dble( lwkopt )
402  RETURN
403  END IF
404 *
405 * ==== DLAHQR/DLAQR0 crossover point ====
406 *
407  nmin = ilaenv( 12, 'DLAQR4', jbcmpz, n, ilo, ihi, lwork )
408  nmin = max( ntiny, nmin )
409 *
410 * ==== Nibble crossover point ====
411 *
412  nibble = ilaenv( 14, 'DLAQR4', jbcmpz, n, ilo, ihi, lwork )
413  nibble = max( 0, nibble )
414 *
415 * ==== Accumulate reflections during ttswp? Use block
416 * . 2-by-2 structure during matrix-matrix multiply? ====
417 *
418  kacc22 = ilaenv( 16, 'DLAQR4', jbcmpz, n, ilo, ihi, lwork )
419  kacc22 = max( 0, kacc22 )
420  kacc22 = min( 2, kacc22 )
421 *
422 * ==== NWMAX = the largest possible deflation window for
423 * . which there is sufficient workspace. ====
424 *
425  nwmax = min( ( n-1 ) / 3, lwork / 2 )
426  nw = nwmax
427 *
428 * ==== NSMAX = the Largest number of simultaneous shifts
429 * . for which there is sufficient workspace. ====
430 *
431  nsmax = min( ( n-3 ) / 6, 2*lwork / 3 )
432  nsmax = nsmax - mod( nsmax, 2 )
433 *
434 * ==== NDFL: an iteration count restarted at deflation. ====
435 *
436  ndfl = 1
437 *
438 * ==== ITMAX = iteration limit ====
439 *
440  itmax = max( 30, 2*kexsh )*max( 10, ( ihi-ilo+1 ) )
441 *
442 * ==== Last row and column in the active block ====
443 *
444  kbot = ihi
445 *
446 * ==== Main Loop ====
447 *
448  DO 80 it = 1, itmax
449 *
450 * ==== Done when KBOT falls below ILO ====
451 *
452  IF( kbot.LT.ilo )
453  $ GO TO 90
454 *
455 * ==== Locate active block ====
456 *
457  DO 10 k = kbot, ilo + 1, -1
458  IF( h( k, k-1 ).EQ.zero )
459  $ GO TO 20
460  10 CONTINUE
461  k = ilo
462  20 CONTINUE
463  ktop = k
464 *
465 * ==== Select deflation window size:
466 * . Typical Case:
467 * . If possible and advisable, nibble the entire
468 * . active block. If not, use size MIN(NWR,NWMAX)
469 * . or MIN(NWR+1,NWMAX) depending upon which has
470 * . the smaller corresponding subdiagonal entry
471 * . (a heuristic).
472 * .
473 * . Exceptional Case:
474 * . If there have been no deflations in KEXNW or
475 * . more iterations, then vary the deflation window
476 * . size. At first, because, larger windows are,
477 * . in general, more powerful than smaller ones,
478 * . rapidly increase the window to the maximum possible.
479 * . Then, gradually reduce the window size. ====
480 *
481  nh = kbot - ktop + 1
482  nwupbd = min( nh, nwmax )
483  IF( ndfl.LT.kexnw ) THEN
484  nw = min( nwupbd, nwr )
485  ELSE
486  nw = min( nwupbd, 2*nw )
487  END IF
488  IF( nw.LT.nwmax ) THEN
489  IF( nw.GE.nh-1 ) THEN
490  nw = nh
491  ELSE
492  kwtop = kbot - nw + 1
493  IF( abs( h( kwtop, kwtop-1 ) ).GT.
494  $ abs( h( kwtop-1, kwtop-2 ) ) )nw = nw + 1
495  END IF
496  END IF
497  IF( ndfl.LT.kexnw ) THEN
498  ndec = -1
499  ELSE IF( ndec.GE.0 .OR. nw.GE.nwupbd ) THEN
500  ndec = ndec + 1
501  IF( nw-ndec.LT.2 )
502  $ ndec = 0
503  nw = nw - ndec
504  END IF
505 *
506 * ==== Aggressive early deflation:
507 * . split workspace under the subdiagonal into
508 * . - an nw-by-nw work array V in the lower
509 * . left-hand-corner,
510 * . - an NW-by-at-least-NW-but-more-is-better
511 * . (NW-by-NHO) horizontal work array along
512 * . the bottom edge,
513 * . - an at-least-NW-but-more-is-better (NHV-by-NW)
514 * . vertical work array along the left-hand-edge.
515 * . ====
516 *
517  kv = n - nw + 1
518  kt = nw + 1
519  nho = ( n-nw-1 ) - kt + 1
520  kwv = nw + 2
521  nve = ( n-nw ) - kwv + 1
522 *
523 * ==== Aggressive early deflation ====
524 *
525  CALL dlaqr2( wantt, wantz, n, ktop, kbot, nw, h, ldh, iloz,
526  $ ihiz, z, ldz, ls, ld, wr, wi, h( kv, 1 ), ldh,
527  $ nho, h( kv, kt ), ldh, nve, h( kwv, 1 ), ldh,
528  $ work, lwork )
529 *
530 * ==== Adjust KBOT accounting for new deflations. ====
531 *
532  kbot = kbot - ld
533 *
534 * ==== KS points to the shifts. ====
535 *
536  ks = kbot - ls + 1
537 *
538 * ==== Skip an expensive QR sweep if there is a (partly
539 * . heuristic) reason to expect that many eigenvalues
540 * . will deflate without it. Here, the QR sweep is
541 * . skipped if many eigenvalues have just been deflated
542 * . or if the remaining active block is small.
543 *
544  IF( ( ld.EQ.0 ) .OR. ( ( 100*ld.LE.nw*nibble ) .AND. ( kbot-
545  $ ktop+1.GT.min( nmin, nwmax ) ) ) ) THEN
546 *
547 * ==== NS = nominal number of simultaneous shifts.
548 * . This may be lowered (slightly) if DLAQR2
549 * . did not provide that many shifts. ====
550 *
551  ns = min( nsmax, nsr, max( 2, kbot-ktop ) )
552  ns = ns - mod( ns, 2 )
553 *
554 * ==== If there have been no deflations
555 * . in a multiple of KEXSH iterations,
556 * . then try exceptional shifts.
557 * . Otherwise use shifts provided by
558 * . DLAQR2 above or from the eigenvalues
559 * . of a trailing principal submatrix. ====
560 *
561  IF( mod( ndfl, kexsh ).EQ.0 ) THEN
562  ks = kbot - ns + 1
563  DO 30 i = kbot, max( ks+1, ktop+2 ), -2
564  ss = abs( h( i, i-1 ) ) + abs( h( i-1, i-2 ) )
565  aa = wilk1*ss + h( i, i )
566  bb = ss
567  cc = wilk2*ss
568  dd = aa
569  CALL dlanv2( aa, bb, cc, dd, wr( i-1 ), wi( i-1 ),
570  $ wr( i ), wi( i ), cs, sn )
571  30 CONTINUE
572  IF( ks.EQ.ktop ) THEN
573  wr( ks+1 ) = h( ks+1, ks+1 )
574  wi( ks+1 ) = zero
575  wr( ks ) = wr( ks+1 )
576  wi( ks ) = wi( ks+1 )
577  END IF
578  ELSE
579 *
580 * ==== Got NS/2 or fewer shifts? Use DLAHQR
581 * . on a trailing principal submatrix to
582 * . get more. (Since NS.LE.NSMAX.LE.(N-3)/6,
583 * . there is enough space below the subdiagonal
584 * . to fit an NS-by-NS scratch array.) ====
585 *
586  IF( kbot-ks+1.LE.ns / 2 ) THEN
587  ks = kbot - ns + 1
588  kt = n - ns + 1
589  CALL dlacpy( 'A', ns, ns, h( ks, ks ), ldh,
590  $ h( kt, 1 ), ldh )
591  CALL dlahqr( .false., .false., ns, 1, ns,
592  $ h( kt, 1 ), ldh, wr( ks ), wi( ks ),
593  $ 1, 1, zdum, 1, inf )
594  ks = ks + inf
595 *
596 * ==== In case of a rare QR failure use
597 * . eigenvalues of the trailing 2-by-2
598 * . principal submatrix. ====
599 *
600  IF( ks.GE.kbot ) THEN
601  aa = h( kbot-1, kbot-1 )
602  cc = h( kbot, kbot-1 )
603  bb = h( kbot-1, kbot )
604  dd = h( kbot, kbot )
605  CALL dlanv2( aa, bb, cc, dd, wr( kbot-1 ),
606  $ wi( kbot-1 ), wr( kbot ),
607  $ wi( kbot ), cs, sn )
608  ks = kbot - 1
609  END IF
610  END IF
611 *
612  IF( kbot-ks+1.GT.ns ) THEN
613 *
614 * ==== Sort the shifts (Helps a little)
615 * . Bubble sort keeps complex conjugate
616 * . pairs together. ====
617 *
618  sorted = .false.
619  DO 50 k = kbot, ks + 1, -1
620  IF( sorted )
621  $ GO TO 60
622  sorted = .true.
623  DO 40 i = ks, k - 1
624  IF( abs( wr( i ) )+abs( wi( i ) ).LT.
625  $ abs( wr( i+1 ) )+abs( wi( i+1 ) ) ) THEN
626  sorted = .false.
627 *
628  swap = wr( i )
629  wr( i ) = wr( i+1 )
630  wr( i+1 ) = swap
631 *
632  swap = wi( i )
633  wi( i ) = wi( i+1 )
634  wi( i+1 ) = swap
635  END IF
636  40 CONTINUE
637  50 CONTINUE
638  60 CONTINUE
639  END IF
640 *
641 * ==== Shuffle shifts into pairs of real shifts
642 * . and pairs of complex conjugate shifts
643 * . assuming complex conjugate shifts are
644 * . already adjacent to one another. (Yes,
645 * . they are.) ====
646 *
647  DO 70 i = kbot, ks + 2, -2
648  IF( wi( i ).NE.-wi( i-1 ) ) THEN
649 *
650  swap = wr( i )
651  wr( i ) = wr( i-1 )
652  wr( i-1 ) = wr( i-2 )
653  wr( i-2 ) = swap
654 *
655  swap = wi( i )
656  wi( i ) = wi( i-1 )
657  wi( i-1 ) = wi( i-2 )
658  wi( i-2 ) = swap
659  END IF
660  70 CONTINUE
661  END IF
662 *
663 * ==== If there are only two shifts and both are
664 * . real, then use only one. ====
665 *
666  IF( kbot-ks+1.EQ.2 ) THEN
667  IF( wi( kbot ).EQ.zero ) THEN
668  IF( abs( wr( kbot )-h( kbot, kbot ) ).LT.
669  $ abs( wr( kbot-1 )-h( kbot, kbot ) ) ) THEN
670  wr( kbot-1 ) = wr( kbot )
671  ELSE
672  wr( kbot ) = wr( kbot-1 )
673  END IF
674  END IF
675  END IF
676 *
677 * ==== Use up to NS of the the smallest magnitude
678 * . shifts. If there aren't NS shifts available,
679 * . then use them all, possibly dropping one to
680 * . make the number of shifts even. ====
681 *
682  ns = min( ns, kbot-ks+1 )
683  ns = ns - mod( ns, 2 )
684  ks = kbot - ns + 1
685 *
686 * ==== Small-bulge multi-shift QR sweep:
687 * . split workspace under the subdiagonal into
688 * . - a KDU-by-KDU work array U in the lower
689 * . left-hand-corner,
690 * . - a KDU-by-at-least-KDU-but-more-is-better
691 * . (KDU-by-NHo) horizontal work array WH along
692 * . the bottom edge,
693 * . - and an at-least-KDU-but-more-is-better-by-KDU
694 * . (NVE-by-KDU) vertical work WV arrow along
695 * . the left-hand-edge. ====
696 *
697  kdu = 2*ns
698  ku = n - kdu + 1
699  kwh = kdu + 1
700  nho = ( n-kdu+1-4 ) - ( kdu+1 ) + 1
701  kwv = kdu + 4
702  nve = n - kdu - kwv + 1
703 *
704 * ==== Small-bulge multi-shift QR sweep ====
705 *
706  CALL dlaqr5( wantt, wantz, kacc22, n, ktop, kbot, ns,
707  $ wr( ks ), wi( ks ), h, ldh, iloz, ihiz, z,
708  $ ldz, work, 3, h( ku, 1 ), ldh, nve,
709  $ h( kwv, 1 ), ldh, nho, h( ku, kwh ), ldh )
710  END IF
711 *
712 * ==== Note progress (or the lack of it). ====
713 *
714  IF( ld.GT.0 ) THEN
715  ndfl = 1
716  ELSE
717  ndfl = ndfl + 1
718  END IF
719 *
720 * ==== End of main loop ====
721  80 CONTINUE
722 *
723 * ==== Iteration limit exceeded. Set INFO to show where
724 * . the problem occurred and exit. ====
725 *
726  info = kbot
727  90 CONTINUE
728  END IF
729 *
730 * ==== Return the optimal value of LWORK. ====
731 *
732  work( 1 ) = dble( lwkopt )
733 *
734 * ==== End of DLAQR4 ====
735 *
subroutine dlacpy(UPLO, M, N, A, LDA, B, LDB)
DLACPY copies all or part of one two-dimensional array to another.
Definition: dlacpy.f:103
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV
Definition: ilaenv.f:162
subroutine dlanv2(A, B, C, D, RT1R, RT1I, RT2R, RT2I, CS, SN)
DLANV2 computes the Schur factorization of a real 2-by-2 nonsymmetric matrix in standard form.
Definition: dlanv2.f:127
subroutine dlaqr5(WANTT, WANTZ, KACC22, N, KTOP, KBOT, NSHFTS, SR, SI, H, LDH, ILOZ, IHIZ, Z, LDZ, V, LDV, U, LDU, NV, WV, LDWV, NH, WH, LDWH)
DLAQR5 performs a single small-bulge multi-shift QR sweep.
Definition: dlaqr5.f:265
subroutine dlaqr2(WANTT, WANTZ, N, KTOP, KBOT, NW, H, LDH, ILOZ, IHIZ, Z, LDZ, NS, ND, SR, SI, V, LDV, NH, T, LDT, NV, WV, LDWV, WORK, LWORK)
DLAQR2 performs the orthogonal similarity transformation of a Hessenberg matrix to detect and deflate...
Definition: dlaqr2.f:278
subroutine dlahqr(WANTT, WANTZ, N, ILO, IHI, H, LDH, WR, WI, ILOZ, IHIZ, Z, LDZ, INFO)
DLAHQR computes the eigenvalues and Schur factorization of an upper Hessenberg matrix,...
Definition: dlahqr.f:207
Here is the call graph for this function:
Here is the caller graph for this function: