srzt02.f

Go to the documentation of this file.

*> \brief \b SRZT02
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       REAL             FUNCTION SRZT02( M, N, AF, LDA, TAU, WORK,
*                        LWORK )
*
*       .. Scalar Arguments ..
*       INTEGER            LDA, LWORK, M, N
*       ..
*       .. Array Arguments ..
*       REAL               AF( LDA, * ), TAU( * ), WORK( LWORK )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SRZT02 returns
*>      || I - Q'*Q || / ( M * eps)
*> where the matrix Q is defined by the Householder transformations
*> generated by STZRZF.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix AF.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix AF.
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is REAL array, dimension (LDA,N)
*>          The output of STZRZF.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array AF.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is REAL array, dimension (M)
*>          Details of the Householder transformations as returned by
*>          STZRZF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          length of WORK array. LWORK >= N*N+N*NB.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup single_lin
*
*  =====================================================================
      REAL             function srzt02( m, n, af, lda, tau, work,
     $                 lwork )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      REAL               af( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info
*     ..
*     .. Local Arrays ..
      REAL               rwork( 1 )
*     ..
*     .. External Functions ..
      REAL               slamch, slange
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           slaset, sormrz, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, real
*     ..
*     .. Executable Statements ..
*
      srzt02 = zero
*
      IF( lwork.LT.n*n+n ) THEN
         CALL xerbla( 'SRZT02', 7 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
*     Q := I
*
      CALL slaset( 'Full', n, n, zero, one, work, n )
*
*     Q := P(1) * ... * P(m) * Q
*
      CALL sormrz( 'Left', 'No transpose', n, n, m, n-m, af, lda, tau,
     $             work, n, work( n*n+1 ), lwork-n*n, info )
*
*     Q := P(m) * ... * P(1) * Q
*
      CALL sormrz( 'Left', 'Transpose', n, n, m, n-m, af, lda, tau,
     $             work, n, work( n*n+1 ), lwork-n*n, info )
*
*     Q := Q - I
*
      DO 10 i = 1, n
         work( ( i-1 )*n+i ) = work( ( i-1 )*n+i ) - one
   10 CONTINUE
*
      srzt02 = slange( 'One-norm', n, n, work, n, rwork ) /
     $         ( slamch( 'Epsilon' )*real( max( m, n ) ) )
      RETURN
*
*     End of SRZT02
*
      END