LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
sopmtr.f
Go to the documentation of this file.
1*> \brief \b SOPMTR
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download SOPMTR + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sopmtr.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sopmtr.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sopmtr.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE SOPMTR( SIDE, UPLO, TRANS, M, N, AP, TAU, C, LDC, WORK,
22* INFO )
23*
24* .. Scalar Arguments ..
25* CHARACTER SIDE, TRANS, UPLO
26* INTEGER INFO, LDC, M, N
27* ..
28* .. Array Arguments ..
29* REAL AP( * ), C( LDC, * ), TAU( * ), WORK( * )
30* ..
31*
32*
33*> \par Purpose:
34* =============
35*>
36*> \verbatim
37*>
38*> SOPMTR overwrites the general real M-by-N matrix C with
39*>
40*> SIDE = 'L' SIDE = 'R'
41*> TRANS = 'N': Q * C C * Q
42*> TRANS = 'T': Q**T * C C * Q**T
43*>
44*> where Q is a real orthogonal matrix of order nq, with nq = m if
45*> SIDE = 'L' and nq = n if SIDE = 'R'. Q is defined as the product of
46*> nq-1 elementary reflectors, as returned by SSPTRD using packed
47*> storage:
48*>
49*> if UPLO = 'U', Q = H(nq-1) . . . H(2) H(1);
50*>
51*> if UPLO = 'L', Q = H(1) H(2) . . . H(nq-1).
52*> \endverbatim
53*
54* Arguments:
55* ==========
56*
57*> \param[in] SIDE
58*> \verbatim
59*> SIDE is CHARACTER*1
60*> = 'L': apply Q or Q**T from the Left;
61*> = 'R': apply Q or Q**T from the Right.
62*> \endverbatim
63*>
64*> \param[in] UPLO
65*> \verbatim
66*> UPLO is CHARACTER*1
67*> = 'U': Upper triangular packed storage used in previous
68*> call to SSPTRD;
69*> = 'L': Lower triangular packed storage used in previous
70*> call to SSPTRD.
71*> \endverbatim
72*>
73*> \param[in] TRANS
74*> \verbatim
75*> TRANS is CHARACTER*1
76*> = 'N': No transpose, apply Q;
77*> = 'T': Transpose, apply Q**T.
78*> \endverbatim
79*>
80*> \param[in] M
81*> \verbatim
82*> M is INTEGER
83*> The number of rows of the matrix C. M >= 0.
84*> \endverbatim
85*>
86*> \param[in] N
87*> \verbatim
88*> N is INTEGER
89*> The number of columns of the matrix C. N >= 0.
90*> \endverbatim
91*>
92*> \param[in] AP
93*> \verbatim
94*> AP is REAL array, dimension
95*> (M*(M+1)/2) if SIDE = 'L'
96*> (N*(N+1)/2) if SIDE = 'R'
97*> The vectors which define the elementary reflectors, as
98*> returned by SSPTRD. AP is modified by the routine but
99*> restored on exit.
100*> \endverbatim
101*>
102*> \param[in] TAU
103*> \verbatim
104*> TAU is REAL array, dimension (M-1) if SIDE = 'L'
105*> or (N-1) if SIDE = 'R'
106*> TAU(i) must contain the scalar factor of the elementary
107*> reflector H(i), as returned by SSPTRD.
108*> \endverbatim
109*>
110*> \param[in,out] C
111*> \verbatim
112*> C is REAL array, dimension (LDC,N)
113*> On entry, the M-by-N matrix C.
114*> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
115*> \endverbatim
116*>
117*> \param[in] LDC
118*> \verbatim
119*> LDC is INTEGER
120*> The leading dimension of the array C. LDC >= max(1,M).
121*> \endverbatim
122*>
123*> \param[out] WORK
124*> \verbatim
125*> WORK is REAL array, dimension
126*> (N) if SIDE = 'L'
127*> (M) if SIDE = 'R'
128*> \endverbatim
129*>
130*> \param[out] INFO
131*> \verbatim
132*> INFO is INTEGER
133*> = 0: successful exit
134*> < 0: if INFO = -i, the i-th argument had an illegal value
135*> \endverbatim
136*
137* Authors:
138* ========
139*
140*> \author Univ. of Tennessee
141*> \author Univ. of California Berkeley
142*> \author Univ. of Colorado Denver
143*> \author NAG Ltd.
144*
145*> \ingroup upmtr
146*
147* =====================================================================
148 SUBROUTINE sopmtr( SIDE, UPLO, TRANS, M, N, AP, TAU, C, LDC, WORK,
149 $ INFO )
150*
151* -- LAPACK computational routine --
152* -- LAPACK is a software package provided by Univ. of Tennessee, --
153* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
154*
155* .. Scalar Arguments ..
156 CHARACTER SIDE, TRANS, UPLO
157 INTEGER INFO, LDC, M, N
158* ..
159* .. Array Arguments ..
160 REAL AP( * ), C( LDC, * ), TAU( * ), WORK( * )
161* ..
162*
163* =====================================================================
164*
165* .. Parameters ..
166 REAL ONE
167 parameter( one = 1.0e+0 )
168* ..
169* .. Local Scalars ..
170 LOGICAL FORWRD, LEFT, NOTRAN, UPPER
171 INTEGER I, I1, I2, I3, IC, II, JC, MI, NI, NQ
172 REAL AII
173* ..
174* .. External Functions ..
175 LOGICAL LSAME
176 EXTERNAL lsame
177* ..
178* .. External Subroutines ..
179 EXTERNAL slarf, xerbla
180* ..
181* .. Intrinsic Functions ..
182 INTRINSIC max
183* ..
184* .. Executable Statements ..
185*
186* Test the input arguments
187*
188 info = 0
189 left = lsame( side, 'L' )
190 notran = lsame( trans, 'N' )
191 upper = lsame( uplo, 'U' )
192*
193* NQ is the order of Q
194*
195 IF( left ) THEN
196 nq = m
197 ELSE
198 nq = n
199 END IF
200 IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
201 info = -1
202 ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
203 info = -2
204 ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) ) THEN
205 info = -3
206 ELSE IF( m.LT.0 ) THEN
207 info = -4
208 ELSE IF( n.LT.0 ) THEN
209 info = -5
210 ELSE IF( ldc.LT.max( 1, m ) ) THEN
211 info = -9
212 END IF
213 IF( info.NE.0 ) THEN
214 CALL xerbla( 'SOPMTR', -info )
215 RETURN
216 END IF
217*
218* Quick return if possible
219*
220 IF( m.EQ.0 .OR. n.EQ.0 )
221 $ RETURN
222*
223 IF( upper ) THEN
224*
225* Q was determined by a call to SSPTRD with UPLO = 'U'
226*
227 forwrd = ( left .AND. notran ) .OR.
228 $ ( .NOT.left .AND. .NOT.notran )
229*
230 IF( forwrd ) THEN
231 i1 = 1
232 i2 = nq - 1
233 i3 = 1
234 ii = 2
235 ELSE
236 i1 = nq - 1
237 i2 = 1
238 i3 = -1
239 ii = nq*( nq+1 ) / 2 - 1
240 END IF
241*
242 IF( left ) THEN
243 ni = n
244 ELSE
245 mi = m
246 END IF
247*
248 DO 10 i = i1, i2, i3
249 IF( left ) THEN
250*
251* H(i) is applied to C(1:i,1:n)
252*
253 mi = i
254 ELSE
255*
256* H(i) is applied to C(1:m,1:i)
257*
258 ni = i
259 END IF
260*
261* Apply H(i)
262*
263 aii = ap( ii )
264 ap( ii ) = one
265 CALL slarf( side, mi, ni, ap( ii-i+1 ), 1, tau( i ), c, ldc,
266 $ work )
267 ap( ii ) = aii
268*
269 IF( forwrd ) THEN
270 ii = ii + i + 2
271 ELSE
272 ii = ii - i - 1
273 END IF
274 10 CONTINUE
275 ELSE
276*
277* Q was determined by a call to SSPTRD with UPLO = 'L'.
278*
279 forwrd = ( left .AND. .NOT.notran ) .OR.
280 $ ( .NOT.left .AND. notran )
281*
282 IF( forwrd ) THEN
283 i1 = 1
284 i2 = nq - 1
285 i3 = 1
286 ii = 2
287 ELSE
288 i1 = nq - 1
289 i2 = 1
290 i3 = -1
291 ii = nq*( nq+1 ) / 2 - 1
292 END IF
293*
294 IF( left ) THEN
295 ni = n
296 jc = 1
297 ELSE
298 mi = m
299 ic = 1
300 END IF
301*
302 DO 20 i = i1, i2, i3
303 aii = ap( ii )
304 ap( ii ) = one
305 IF( left ) THEN
306*
307* H(i) is applied to C(i+1:m,1:n)
308*
309 mi = m - i
310 ic = i + 1
311 ELSE
312*
313* H(i) is applied to C(1:m,i+1:n)
314*
315 ni = n - i
316 jc = i + 1
317 END IF
318*
319* Apply H(i)
320*
321 CALL slarf( side, mi, ni, ap( ii ), 1, tau( i ),
322 $ c( ic, jc ), ldc, work )
323 ap( ii ) = aii
324*
325 IF( forwrd ) THEN
326 ii = ii + nq - i + 1
327 ELSE
328 ii = ii - nq + i - 2
329 END IF
330 20 CONTINUE
331 END IF
332 RETURN
333*
334* End of SOPMTR
335*
336 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine slarf(side, m, n, v, incv, tau, c, ldc, work)
SLARF applies an elementary reflector to a general rectangular matrix.
Definition slarf.f:124
subroutine sopmtr(side, uplo, trans, m, n, ap, tau, c, ldc, work, info)
SOPMTR
Definition sopmtr.f:150