slqt05.f

Go to the documentation of this file.

*> \brief \b SLQT05
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLQT05(M,N,L,NB,RESULT)
*
*       .. Scalar Arguments ..
*       INTEGER LWORK, M, N, L, NB, LDT
*       .. Return values ..
*       REAL RESULT(6)
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*> SQRT05 tests STPLQT and STPMLQT.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          Number of rows in lower part of the test matrix.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          Number of columns in test matrix.
*> \endverbatim
*>
*> \param[in] L
*> \verbatim
*>          L is INTEGER
*>          The number of rows of the upper trapezoidal part the
*>          lower test matrix.  0 <= L <= M.
*> \endverbatim
*>
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          Block size of test matrix.  NB <= N.
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (6)
*>          Results of each of the six tests below.
*>
*>          RESULT(1) = | A - Q R |
*>          RESULT(2) = | I - Q^H Q |
*>          RESULT(3) = | Q C - Q C |
*>          RESULT(4) = | Q^H C - Q^H C |
*>          RESULT(5) = | C Q - C Q |
*>          RESULT(6) = | C Q^H - C Q^H |
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE slqt05(M,N,L,NB,RESULT)
      IMPLICIT NONE
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER  LWORK, M, N, L, NB, LDT
*     .. Return values ..
      REAL     RESULT(6)
*
*  =====================================================================
*
*     ..
*     .. Local allocatable arrays
      REAL, ALLOCATABLE :: AF(:,:), Q(:,:),
     $  R(:,:), RWORK(:), WORK( : ), T(:,:),
     $  CF(:,:), DF(:,:), A(:,:), C(:,:), D(:,:)
*
*     .. Parameters ..
      REAL ONE, ZERO
      parameter( zero = 0.0, one = 1.0 )
*     ..
*     .. Local Scalars ..
      INTEGER     INFO, J, K, N2, NP1,i
      REAL        ANORM, EPS, RESID, CNORM, DNORM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. External Functions ..
      REAL        SLAMCH, SLANGE, SLANSY
      LOGICAL     LSAME
      EXTERNAL    slamch, slange, slansy, lsame
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /
*
      eps = slamch( 'Epsilon' )
      k = m
      n2 = m+n
      IF( n.GT.0 ) THEN
         np1 = m+1
      ELSE
         np1 = 1
      END IF
      lwork = n2*n2*nb
*
*     Dynamically allocate all arrays
*
      ALLOCATE(a(m,n2),af(m,n2),q(n2,n2),r(n2,n2),rwork(n2),
     $           work(lwork),t(nb,m),c(n2,m),cf(n2,m),
     $           d(m,n2),df(m,n2) )
*
*     Put random stuff into A
*
      ldt=nb
      CALL slaset( 'Full', m, n2, zero, zero, a, m )
      CALL slaset( 'Full', nb, m, zero, zero, t, nb )
      DO j=1,m
         CALL slarnv( 2, iseed, m-j+1, a( j, j ) )
      END DO
      IF( n.GT.0 ) THEN
         DO j=1,n-l
            CALL slarnv( 2, iseed, m, a( 1, min(n+m,m+1) + j - 1 ) )
         END DO
      END IF
      IF( l.GT.0 ) THEN
         DO j=1,l
            CALL slarnv( 2, iseed, m-j+1, a( j, min(n+m,n+m-l+1)
     $          + j - 1 ) )
         END DO
      END IF
*
*     Copy the matrix A to the array AF.
*
      CALL slacpy( 'Full', m, n2, a, m, af, m )
*
*     Factor the matrix A in the array AF.
*
      CALL stplqt( m,n,l,nb,af,m,af(1,np1),m,t,ldt,work,info)
*
*     Generate the (M+N)-by-(M+N) matrix Q by applying H to I
*
      CALL slaset( 'Full', n2, n2, zero, one, q, n2 )
      CALL sgemlqt( 'L', 'N', n2, n2, k, nb, af, m, t, ldt, q, n2,
     $              work, info )
*
*     Copy L
*
      CALL slaset( 'Full', n2, n2, zero, zero, r, n2 )
      CALL slacpy( 'Lower', m, n2, af, m, r, n2 )
*
*     Compute |L - A*Q*T| / |A| and store in RESULT(1)
*
      CALL sgemm( 'N', 'T', m, n2, n2, -one,  a, m, q, n2, one, r, n2)
      anorm = slange( '1', m, n2, a, m, rwork )
      resid = slange( '1', m, n2, r, n2, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / (eps*anorm*max(1,n2))
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute |I - Q*Q'| and store in RESULT(2)
*
      CALL slaset( 'Full', n2, n2, zero, one, r, n2 )
      CALL ssyrk( 'U', 'N', n2, n2, -one, q, n2, one, r, n2 )
      resid = slansy( '1', 'Upper', n2, r, n2, rwork )
      result( 2 ) = resid / (eps*max(1,n2))
*
*     Generate random m-by-n matrix C and a copy CF
*
      CALL slaset( 'Full', n2, m, zero, one, c, n2 )
      DO j=1,m
         CALL slarnv( 2, iseed, n2, c( 1, j ) )
      END DO
      cnorm = slange( '1', n2, m, c, n2, rwork)
      CALL slacpy( 'Full', n2, m, c, n2, cf, n2 )
*
*     Apply Q to C as Q*C
*
      CALL stpmlqt( 'L','N', n,m,k,l,nb,af(1, np1),m,t,ldt,cf,n2,
     $               cf(np1,1),n2,work,info)
*
*     Compute |Q*C - Q*C| / |C|
*
      CALL sgemm( 'N', 'N', n2, m, n2, -one, q, n2, c, n2, one, cf, n2 )
      resid = slange( '1', n2, m, cf, n2, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 3 ) = resid / (eps*max(1,n2)*cnorm)
      ELSE
         result( 3 ) = zero
      END IF
 
*
*     Copy C into CF again
*
      CALL slacpy( 'Full', n2, m, c, n2, cf, n2 )
*
*     Apply Q to C as QT*C
*
      CALL stpmlqt( 'L','T',n,m,k,l,nb,af(1,np1),m,t,ldt,cf,n2,
     $              cf(np1,1),n2,work,info)
*
*     Compute |QT*C - QT*C| / |C|
*
      CALL sgemm('T','N',n2,m,n2,-one,q,n2,c,n2,one,cf,n2)
      resid = slange( '1', n2, m, cf, n2, rwork )
 
      IF( cnorm.GT.zero ) THEN
         result( 4 ) = resid / (eps*max(1,n2)*cnorm)
      ELSE
         result( 4 ) = zero
      END IF
*
*     Generate random m-by-n matrix D and a copy DF
*
      DO j=1,n2
         CALL slarnv( 2, iseed, m, d( 1, j ) )
      END DO
      dnorm = slange( '1', m, n2, d, m, rwork)
      CALL slacpy( 'Full', m, n2, d, m, df, m )
*
*     Apply Q to D as D*Q
*
      CALL stpmlqt('R','N',m,n,k,l,nb,af(1,np1),m,t,ldt,df,m,
     $             df(1,np1),m,work,info)
*
*     Compute |D*Q - D*Q| / |D|
*
      CALL sgemm('N','N',m,n2,n2,-one,d,m,q,n2,one,df,m)
      resid = slange('1',m, n2,df,m,rwork )
      IF( cnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,n2)*dnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL slacpy('Full',m,n2,d,m,df,m )
*
*     Apply Q to D as D*QT
*
      CALL stpmlqt('R','T',m,n,k,l,nb,af(1,np1),m,t,ldt,df,m,
     $             df(1,np1),m,work,info)
 
*
*     Compute |D*QT - D*QT| / |D|
*
      CALL sgemm( 'N', 'T', m, n2, n2, -one, d, m, q, n2, one, df, m )
      resid = slange( '1', m, n2, df, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,n2)*dnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, r, rwork, work, t, c, d, cf, df)
      RETURN
      END