LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
zgetrf.f
Go to the documentation of this file.
1 C> \brief \b ZGETRF VARIANT: Crout Level 3 BLAS version of the algorithm.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 * Definition:
9 * ===========
10 *
11 * SUBROUTINE ZGETRF ( M, N, A, LDA, IPIV, INFO)
12 *
13 * .. Scalar Arguments ..
14 * INTEGER INFO, LDA, M, N
15 * ..
16 * .. Array Arguments ..
17 * INTEGER IPIV( * )
18 * COMPLEX*16 A( LDA, * )
19 * ..
20 *
21 * Purpose
22 * =======
23 *
24 C>\details \b Purpose:
25 C>\verbatim
26 C>
27 C> ZGETRF computes an LU factorization of a general M-by-N matrix A
28 C> using partial pivoting with row interchanges.
29 C>
30 C> The factorization has the form
31 C> A = P * L * U
32 C> where P is a permutation matrix, L is lower triangular with unit
33 C> diagonal elements (lower trapezoidal if m > n), and U is upper
34 C> triangular (upper trapezoidal if m < n).
35 C>
36 C> This is the Crout Level 3 BLAS version of the algorithm.
37 C>
38 C>\endverbatim
39 *
40 * Arguments:
41 * ==========
42 *
43 C> \param[in] M
44 C> \verbatim
45 C> M is INTEGER
46 C> The number of rows of the matrix A. M >= 0.
47 C> \endverbatim
48 C>
49 C> \param[in] N
50 C> \verbatim
51 C> N is INTEGER
52 C> The number of columns of the matrix A. N >= 0.
53 C> \endverbatim
54 C>
55 C> \param[in,out] A
56 C> \verbatim
57 C> A is COMPLEX*16 array, dimension (LDA,N)
58 C> On entry, the M-by-N matrix to be factored.
59 C> On exit, the factors L and U from the factorization
60 C> A = P*L*U; the unit diagonal elements of L are not stored.
61 C> \endverbatim
62 C>
63 C> \param[in] LDA
64 C> \verbatim
65 C> LDA is INTEGER
66 C> The leading dimension of the array A. LDA >= max(1,M).
67 C> \endverbatim
68 C>
69 C> \param[out] IPIV
70 C> \verbatim
71 C> IPIV is INTEGER array, dimension (min(M,N))
72 C> The pivot indices; for 1 <= i <= min(M,N), row i of the
73 C> matrix was interchanged with row IPIV(i).
74 C> \endverbatim
75 C>
76 C> \param[out] INFO
77 C> \verbatim
78 C> INFO is INTEGER
79 C> = 0: successful exit
80 C> < 0: if INFO = -i, the i-th argument had an illegal value
81 C> > 0: if INFO = i, U(i,i) is exactly zero. The factorization
82 C> has been completed, but the factor U is exactly
83 C> singular, and division by zero will occur if it is used
84 C> to solve a system of equations.
85 C> \endverbatim
86 C>
87 *
88 * Authors:
89 * ========
90 *
91 C> \author Univ. of Tennessee
92 C> \author Univ. of California Berkeley
93 C> \author Univ. of Colorado Denver
94 C> \author NAG Ltd.
95 *
96 C> \date December 2016
97 *
98 C> \ingroup variantsGEcomputational
99 *
100 * =====================================================================
101  SUBROUTINE zgetrf ( M, N, A, LDA, IPIV, INFO)
102 *
103 * -- LAPACK computational routine --
104 * -- LAPACK is a software package provided by Univ. of Tennessee, --
105 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
106 *
107 * .. Scalar Arguments ..
108  INTEGER INFO, LDA, M, N
109 * ..
110 * .. Array Arguments ..
111  INTEGER IPIV( * )
112  COMPLEX*16 A( LDA, * )
113 * ..
114 *
115 * =====================================================================
116 *
117 * .. Parameters ..
118  COMPLEX*16 ONE
119  parameter( one = ( 1.0d+0, 0.0d+0 ) )
120 * ..
121 * .. Local Scalars ..
122  INTEGER I, IINFO, J, JB, NB
123 * ..
124 * .. External Subroutines ..
125  EXTERNAL zgemm, zgetf2, zlaswp, ztrsm, xerbla
126 * ..
127 * .. External Functions ..
128  INTEGER ILAENV
129  EXTERNAL ilaenv
130 * ..
131 * .. Intrinsic Functions ..
132  INTRINSIC max, min
133 * ..
134 * .. Executable Statements ..
135 *
136 * Test the input parameters.
137 *
138  info = 0
139  IF( m.LT.0 ) THEN
140  info = -1
141  ELSE IF( n.LT.0 ) THEN
142  info = -2
143  ELSE IF( lda.LT.max( 1, m ) ) THEN
144  info = -4
145  END IF
146  IF( info.NE.0 ) THEN
147  CALL xerbla( 'ZGETRF', -info )
148  RETURN
149  END IF
150 *
151 * Quick return if possible
152 *
153  IF( m.EQ.0 .OR. n.EQ.0 )
154  $ RETURN
155 *
156 * Determine the block size for this environment.
157 *
158  nb = ilaenv( 1, 'ZGETRF', ' ', m, n, -1, -1 )
159  IF( nb.LE.1 .OR. nb.GE.min( m, n ) ) THEN
160 *
161 * Use unblocked code.
162 *
163  CALL zgetf2( m, n, a, lda, ipiv, info )
164  ELSE
165 *
166 * Use blocked code.
167 *
168  DO 20 j = 1, min( m, n ), nb
169  jb = min( min( m, n )-j+1, nb )
170 *
171 * Update current block.
172 *
173  CALL zgemm( 'No transpose', 'No transpose',
174  $ m-j+1, jb, j-1, -one,
175  $ a( j, 1 ), lda, a( 1, j ), lda, one,
176  $ a( j, j ), lda )
177 
178 *
179 * Factor diagonal and subdiagonal blocks and test for exact
180 * singularity.
181 *
182  CALL zgetf2( m-j+1, jb, a( j, j ), lda, ipiv( j ), iinfo )
183 *
184 * Adjust INFO and the pivot indices.
185 *
186  IF( info.EQ.0 .AND. iinfo.GT.0 )
187  $ info = iinfo + j - 1
188  DO 10 i = j, min( m, j+jb-1 )
189  ipiv( i ) = j - 1 + ipiv( i )
190  10 CONTINUE
191 *
192 * Apply interchanges to column 1:J-1
193 *
194  CALL zlaswp( j-1, a, lda, j, j+jb-1, ipiv, 1 )
195 *
196  IF ( j+jb.LE.n ) THEN
197 *
198 * Apply interchanges to column J+JB:N
199 *
200  CALL zlaswp( n-j-jb+1, a( 1, j+jb ), lda, j, j+jb-1,
201  $ ipiv, 1 )
202 *
203  CALL zgemm( 'No transpose', 'No transpose',
204  $ jb, n-j-jb+1, j-1, -one,
205  $ a( j, 1 ), lda, a( 1, j+jb ), lda, one,
206  $ a( j, j+jb ), lda )
207 *
208 * Compute block row of U.
209 *
210  CALL ztrsm( 'Left', 'Lower', 'No transpose', 'Unit',
211  $ jb, n-j-jb+1, one, a( j, j ), lda,
212  $ a( j, j+jb ), lda )
213  END IF
214 
215  20 CONTINUE
216 
217  END IF
218  RETURN
219 *
220 * End of ZGETRF
221 *
222  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine zgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
ZGEMM
Definition: zgemm.f:187
subroutine ztrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRSM
Definition: ztrsm.f:180
subroutine zgetf2(M, N, A, LDA, IPIV, INFO)
ZGETF2 computes the LU factorization of a general m-by-n matrix using partial pivoting with row inter...
Definition: zgetf2.f:108
subroutine zlaswp(N, A, LDA, K1, K2, IPIV, INCX)
ZLASWP performs a series of row interchanges on a general rectangular matrix.
Definition: zlaswp.f:115
subroutine zgetrf(M, N, A, LDA, IPIV, INFO)
ZGETRF VARIANT: Crout Level 3 BLAS version of the algorithm.
Definition: zgetrf.f:102