zchktb()

subroutine zchktb	(	logical, dimension( * )	dotype,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nns,
		integer, dimension( * )	nsval,
		double precision	thresh,
		logical	tsterr,
		integer	nmax,
		complex*16, dimension( * )	ab,
		complex*16, dimension( * )	ainv,
		complex*16, dimension( * )	b,
		complex*16, dimension( * )	x,
		complex*16, dimension( * )	xact,
		complex*16, dimension( * )	work,
		double precision, dimension( * )	rwork,
		integer	nout )

ZCHKTB

Purpose:

!>
!> ZCHKTB tests ZTBTRS, -RFS, and -CON, and ZLATBS.
!> 

Parameters

[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> The matrix types to be used for testing. Matrices of type j !> (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = !> .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used. !>
[in]	NN	!> NN is INTEGER !> The number of values of N contained in the vector NVAL. !>
[in]	NVAL	!> NVAL is INTEGER array, dimension (NN) !> The values of the matrix column dimension N. !>
[in]	NNS	!> NNS is INTEGER !> The number of values of NRHS contained in the vector NSVAL. !>
[in]	NSVAL	!> NSVAL is INTEGER array, dimension (NNS) !> The values of the number of right hand sides NRHS. !>
[in]	THRESH	!> THRESH is DOUBLE PRECISION !> The threshold value for the test ratios. A result is !> included in the output file if RESULT >= THRESH. To have !> every test ratio printed, use THRESH = 0. !>
[in]	TSTERR	!> TSTERR is LOGICAL !> Flag that indicates whether error exits are to be tested. !>
[in]	NMAX	!> NMAX is INTEGER !> The leading dimension of the work arrays. !> NMAX >= the maximum value of N in NVAL. !>
[out]	AB	!> AB is COMPLEX*16 array, dimension (NMAX*NMAX) !>
[out]	AINV	!> AINV is COMPLEX*16 array, dimension (NMAX*NMAX) !>
[out]	B	!> B is COMPLEX*16 array, dimension (NMAX*NSMAX) !> where NSMAX is the largest entry in NSVAL. !>
[out]	X	!> X is COMPLEX*16 array, dimension (NMAX*NSMAX) !>
[out]	XACT	!> XACT is COMPLEX*16 array, dimension (NMAX*NSMAX) !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension !> (NMAX*max(3,NSMAX)) !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension !> (max(NMAX,2*NSMAX)) !>
[in]	NOUT	!> NOUT is INTEGER !> The unit number for output. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 147 of file zchktb.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNS, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            NSVAL( * ), NVAL( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         AB( * ), AINV( * ), B( * ), WORK( * ), X( * ),
     $                   XACT( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTYPE1, NTYPES
      parameter( ntype1 = 9, ntypes = 17 )
      INTEGER            NTESTS
      parameter( ntests = 8 )
      INTEGER            NTRAN
      parameter( ntran = 3 )
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          DIAG, NORM, TRANS, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, IDIAG, IK, IMAT, IN, INFO, IRHS, ITRAN,
     $                   IUPLO, J, K, KD, LDA, LDAB, N, NERRS, NFAIL,
     $                   NIMAT, NIMAT2, NK, NRHS, NRUN
      DOUBLE PRECISION   AINVNM, ANORM, RCOND, RCONDC, RCONDI, RCONDO,
     $                   SCALE
*     ..
*     .. Local Arrays ..
      CHARACTER          TRANSS( NTRAN ), UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( NTESTS )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   ZLANTB, ZLANTR
      EXTERNAL           lsame, zlantb, zlantr
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, zcopy, zerrtr, zget04,
     $                   zlacpy, zlarhs, zlaset, zlatbs, zlattb, ztbcon,
     $                   ztbrfs, ztbsv, ztbt02, ztbt03, ztbt05, ztbt06,
     $                   ztbtrs
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, IOUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, iounit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dcmplx, max, min
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' / , transs / 'N', 'T', 'C' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'TB'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL zerrtr( path, nout )
      infot = 0
*
      DO 140 in = 1, nn
*
*        Do for each value of N in NVAL
*
         n = nval( in )
         lda = max( 1, n )
         xtype = 'N'
         nimat = ntype1
         nimat2 = ntypes
         IF( n.LE.0 ) THEN
            nimat = 1
            nimat2 = ntype1 + 1
         END IF
*
         nk = min( n+1, 4 )
         DO 130 ik = 1, nk
*
*           Do for KD = 0, N, (3N-1)/4, and (N+1)/4. This order makes
*           it easier to skip redundant values for small values of N.
*
            IF( ik.EQ.1 ) THEN
               kd = 0
            ELSE IF( ik.EQ.2 ) THEN
               kd = max( n, 0 )
            ELSE IF( ik.EQ.3 ) THEN
               kd = ( 3*n-1 ) / 4
            ELSE IF( ik.EQ.4 ) THEN
               kd = ( n+1 ) / 4
            END IF
            ldab = kd + 1
*
            DO 90 imat = 1, nimat
*
*              Do the tests only if DOTYPE( IMAT ) is true.
*
               IF( .NOT.dotype( imat ) )
     $            GO TO 90
*
               DO 80 iuplo = 1, 2
*
*                 Do first for UPLO = 'U', then for UPLO = 'L'
*
                  uplo = uplos( iuplo )
*
*                 Call ZLATTB to generate a triangular test matrix.
*
                  srnamt = 'ZLATTB'
                  CALL zlattb( imat, uplo, 'No transpose', diag, iseed,
     $                         n, kd, ab, ldab, x, work, rwork, info )
*
*                 Set IDIAG = 1 for non-unit matrices, 2 for unit.
*
                  IF( lsame( diag, 'N' ) ) THEN
                     idiag = 1
                  ELSE
                     idiag = 2
                  END IF
*
*                 Form the inverse of A so we can get a good estimate
*                 of RCONDC = 1/(norm(A) * norm(inv(A))).
*
                  CALL zlaset( 'Full', n, n, dcmplx( zero ),
     $                         dcmplx( one ), ainv, lda )
                  IF( lsame( uplo, 'U' ) ) THEN
                     DO 20 j = 1, n
                        CALL ztbsv( uplo, 'No transpose', diag, j, kd,
     $                              ab, ldab, ainv( ( j-1 )*lda+1 ), 1 )
   20                CONTINUE
                  ELSE
                     DO 30 j = 1, n
                        CALL ztbsv( uplo, 'No transpose', diag, n-j+1,
     $                              kd, ab( ( j-1 )*ldab+1 ), ldab,
     $                              ainv( ( j-1 )*lda+j ), 1 )
   30                CONTINUE
                  END IF
*
*                 Compute the 1-norm condition number of A.
*
                  anorm = zlantb( '1', uplo, diag, n, kd, ab, ldab,
     $                    rwork )
                  ainvnm = zlantr( '1', uplo, diag, n, n, ainv, lda,
     $                     rwork )
                  IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                     rcondo = one
                  ELSE
                     rcondo = ( one / anorm ) / ainvnm
                  END IF
*
*                 Compute the infinity-norm condition number of A.
*
                  anorm = zlantb( 'I', uplo, diag, n, kd, ab, ldab,
     $                    rwork )
                  ainvnm = zlantr( 'I', uplo, diag, n, n, ainv, lda,
     $                     rwork )
                  IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                     rcondi = one
                  ELSE
                     rcondi = ( one / anorm ) / ainvnm
                  END IF
*
                  DO 60 irhs = 1, nns
                     nrhs = nsval( irhs )
                     xtype = 'N'
*
                     DO 50 itran = 1, ntran
*
*                    Do for op(A) = A, A**T, or A**H.
*
                        trans = transs( itran )
                        IF( itran.EQ.1 ) THEN
                           norm = 'O'
                           rcondc = rcondo
                        ELSE
                           norm = 'I'
                           rcondc = rcondi
                        END IF
*
*+    TEST 1
*                    Solve and compute residual for op(A)*x = b.
*
                        srnamt = 'ZLARHS'
                        CALL zlarhs( path, xtype, uplo, trans, n, n, kd,
     $                               idiag, nrhs, ab, ldab, xact, lda,
     $                               b, lda, iseed, info )
                        xtype = 'C'
                        CALL zlacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                        srnamt = 'ZTBTRS'
                        CALL ztbtrs( uplo, trans, diag, n, kd, nrhs, ab,
     $                               ldab, x, lda, info )
*
*                    Check error code from ZTBTRS.
*
                        IF( info.NE.0 )
     $                     CALL alaerh( path, 'ZTBTRS', info, 0,
     $                                  uplo // trans // diag, n, n, kd,
     $                                  kd, nrhs, imat, nfail, nerrs,
     $                                  nout )
*
                        CALL ztbt02( uplo, trans, diag, n, kd, nrhs, ab,
     $                               ldab, x, lda, b, lda, work, rwork,
     $                               result( 1 ) )
*
*+    TEST 2
*                    Check solution from generated exact solution.
*
                        CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 2 ) )
*
*+    TESTS 3, 4, and 5
*                    Use iterative refinement to improve the solution
*                    and compute error bounds.
*
                        srnamt = 'ZTBRFS'
                        CALL ztbrfs( uplo, trans, diag, n, kd, nrhs, ab,
     $                               ldab, b, lda, x, lda, rwork,
     $                               rwork( nrhs+1 ), work,
     $                               rwork( 2*nrhs+1 ), info )
*
*                    Check error code from ZTBRFS.
*
                        IF( info.NE.0 )
     $                     CALL alaerh( path, 'ZTBRFS', info, 0,
     $                                  uplo // trans // diag, n, n, kd,
     $                                  kd, nrhs, imat, nfail, nerrs,
     $                                  nout )
*
                        CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 3 ) )
                        CALL ztbt05( uplo, trans, diag, n, kd, nrhs, ab,
     $                               ldab, b, lda, x, lda, xact, lda,
     $                               rwork, rwork( nrhs+1 ),
     $                               result( 4 ) )
*
*                       Print information about the tests that did not
*                       pass the threshold.
*
                        DO 40 k = 1, 5
                           IF( result( k ).GE.thresh ) THEN
                              IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                           CALL alahd( nout, path )
                              WRITE( nout, fmt = 9999 )uplo, trans,
     $                           diag, n, kd, nrhs, imat, k, result( k )
                              nfail = nfail + 1
                           END IF
   40                   CONTINUE
                        nrun = nrun + 5
   50                CONTINUE
   60             CONTINUE
*
*+    TEST 6
*                    Get an estimate of RCOND = 1/CNDNUM.
*
                  DO 70 itran = 1, 2
                     IF( itran.EQ.1 ) THEN
                        norm = 'O'
                        rcondc = rcondo
                     ELSE
                        norm = 'I'
                        rcondc = rcondi
                     END IF
                     srnamt = 'ZTBCON'
                     CALL ztbcon( norm, uplo, diag, n, kd, ab, ldab,
     $                            rcond, work, rwork, info )
*
*                    Check error code from ZTBCON.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'ZTBCON', info, 0,
     $                               norm // uplo // diag, n, n, kd, kd,
     $                               -1, imat, nfail, nerrs, nout )
*
                     CALL ztbt06( rcond, rcondc, uplo, diag, n, kd, ab,
     $                            ldab, rwork, result( 6 ) )
*
*                    Print the test ratio if it is .GE. THRESH.
*
                     IF( result( 6 ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9998 ) 'ZTBCON', norm, uplo,
     $                     diag, n, kd, imat, 6, result( 6 )
                        nfail = nfail + 1
                     END IF
                     nrun = nrun + 1
   70             CONTINUE
   80          CONTINUE
   90       CONTINUE
*
*           Use pathological test matrices to test ZLATBS.
*
            DO 120 imat = ntype1 + 1, nimat2
*
*              Do the tests only if DOTYPE( IMAT ) is true.
*
               IF( .NOT.dotype( imat ) )
     $            GO TO 120
*
               DO 110 iuplo = 1, 2
*
*                 Do first for UPLO = 'U', then for UPLO = 'L'
*
                  uplo = uplos( iuplo )
                  DO 100 itran = 1, ntran
*
*                    Do for op(A) = A, A**T, and A**H.
*
                     trans = transs( itran )
*
*                    Call ZLATTB to generate a triangular test matrix.
*
                     srnamt = 'ZLATTB'
                     CALL zlattb( imat, uplo, trans, diag, iseed, n, kd,
     $                            ab, ldab, x, work, rwork, info )
*
*+    TEST 7
*                    Solve the system op(A)*x = b
*
                     srnamt = 'ZLATBS'
                     CALL zcopy( n, x, 1, b, 1 )
                     CALL zlatbs( uplo, trans, diag, 'N', n, kd, ab,
     $                            ldab, b, scale, rwork, info )
*
*                    Check error code from ZLATBS.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'ZLATBS', info, 0,
     $                               uplo // trans // diag // 'N', n, n,
     $                               kd, kd, -1, imat, nfail, nerrs,
     $                               nout )
*
                     CALL ztbt03( uplo, trans, diag, n, kd, 1, ab, ldab,
     $                            scale, rwork, one, b, lda, x, lda,
     $                            work, result( 7 ) )
*
*+    TEST 8
*                    Solve op(A)*x = b again with NORMIN = 'Y'.
*
                     CALL zcopy( n, x, 1, b, 1 )
                     CALL zlatbs( uplo, trans, diag, 'Y', n, kd, ab,
     $                            ldab, b, scale, rwork, info )
*
*                    Check error code from ZLATBS.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'ZLATBS', info, 0,
     $                               uplo // trans // diag // 'Y', n, n,
     $                               kd, kd, -1, imat, nfail, nerrs,
     $                               nout )
*
                     CALL ztbt03( uplo, trans, diag, n, kd, 1, ab, ldab,
     $                            scale, rwork, one, b, lda, x, lda,
     $                            work, result( 8 ) )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     IF( result( 7 ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9997 )'ZLATBS', uplo, trans,
     $                     diag, 'N', n, kd, imat, 7, result( 7 )
                        nfail = nfail + 1
                     END IF
                     IF( result( 8 ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9997 )'ZLATBS', uplo, trans,
     $                     diag, 'Y', n, kd, imat, 8, result( 8 )
                        nfail = nfail + 1
                     END IF
                     nrun = nrun + 2
  100             CONTINUE
  110          CONTINUE
  120       CONTINUE
  130    CONTINUE
  140 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO=''', a1, ''', TRANS=''', a1, ''',
     $      DIAG=''', a1, ''', N=', i5, ', KD=', i5, ', NRHS=', i5,
     $      ', type ', i2, ', test(', i2, ')=', g12.5 )
 9998 FORMAT( 1x, a, '( ''', a1, ''', ''', a1, ''', ''', a1, ''',',
     $      i5, ',', i5, ',  ... ), type ', i2, ', test(', i2, ')=',
     $      g12.5 )
 9997 FORMAT( 1x, a, '( ''', a1, ''', ''', a1, ''', ''', a1, ''', ''',
     $      a1, ''',', i5, ',', i5, ', ...  ),  type ', i2, ', test(',
     $      i1, ')=', g12.5 )
      RETURN
*
*     End of ZCHKTB
*

Here is the call graph for this function:

Here is the caller graph for this function: