zchkec.f

Go to the documentation of this file.

*> \brief \b ZCHKEC
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZCHKEC( THRESH, TSTERR, NIN, NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NIN, NOUT
*       DOUBLE PRECISION   THRESH
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZCHKEC tests eigen- condition estimation routines
*>        ZTRSYL, CTREXC, CTRSNA, CTRSEN
*>
*> In all cases, the routine runs through a fixed set of numerical
*> examples, subjects them to various tests, and compares the test
*> results to a threshold THRESH. In addition, ZTRSNA and CTRSEN are
*> tested by reading in precomputed examples from a file (on input unit
*> NIN).  Output is written to output unit NOUT.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          Threshold for residual tests.  A computed test ratio passes
*>          the threshold if it is less than THRESH.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NIN
*> \verbatim
*>          NIN is INTEGER
*>          The logical unit number for input.
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The logical unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex16_eig
*
*  =====================================================================
      SUBROUTINE zchkec( THRESH, TSTERR, NIN, NOUT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NIN, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            OK
      CHARACTER*3        PATH
      INTEGER            KTREXC, KTRSEN, KTRSNA, KTRSYL, KTRSYL3,
     $                   LTREXC, LTRSYL, NTESTS, NTREXC, NTRSYL
      DOUBLE PRECISION   EPS, RTREXC, SFMIN
*     ..
*     .. Local Arrays ..
      INTEGER            FTRSYL( 3 ), ITRSYL( 2 ), LTRSEN( 3 ),
     $                   LTRSNA( 3 ), NTRSEN( 3 ), NTRSNA( 3 )
      DOUBLE PRECISION   RTRSEN( 3 ), RTRSNA( 3 ), RTRSYL( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           zerrec, zget35, zget36, zget37, zget38, zsyl01
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           dlamch
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'EC'
      eps = dlamch( 'P' )
      sfmin = dlamch( 'S' )
      WRITE( nout, fmt = 9994 )
      WRITE( nout, fmt = 9993 )eps, sfmin
      WRITE( nout, fmt = 9992 )thresh
*
*     Test error exits if TSTERR is .TRUE.
*
      IF( tsterr )
     $   CALL zerrec( path, nout )
*
      ok = .true.
      CALL zget35( rtrsyl( 1 ), ltrsyl, ntrsyl, ktrsyl, nin )
      IF( rtrsyl( 1 ).GT.thresh ) THEN
         ok = .false.
         WRITE( nout, fmt = 9999 )rtrsyl( 1 ), ltrsyl, ntrsyl, ktrsyl
      END IF
*
      CALL zsyl01( thresh, ftrsyl, rtrsyl, itrsyl, ktrsyl3 )
      IF( ftrsyl( 1 ).GT.0 ) THEN
         ok = .false.
         WRITE( nout, fmt = 9970 )ftrsyl( 1 ), rtrsyl( 1 ), thresh
      END IF
      IF( ftrsyl( 2 ).GT.0 ) THEN
         ok = .false.
         WRITE( nout, fmt = 9971 )ftrsyl( 2 ), rtrsyl( 2 ), thresh
      END IF
      IF( ftrsyl( 3 ).GT.0 ) THEN
         ok = .false.
         WRITE( nout, fmt = 9972 )ftrsyl( 3 )
      END IF
*
      CALL zget36( rtrexc, ltrexc, ntrexc, ktrexc, nin )
      IF( rtrexc.GT.thresh .OR. ntrexc.GT.0 ) THEN
         ok = .false.
         WRITE( nout, fmt = 9998 )rtrexc, ltrexc, ntrexc, ktrexc
      END IF
*
      CALL zget37( rtrsna, ltrsna, ntrsna, ktrsna, nin )
      IF( rtrsna( 1 ).GT.thresh .OR. rtrsna( 2 ).GT.thresh .OR.
     $    ntrsna( 1 ).NE.0 .OR. ntrsna( 2 ).NE.0 .OR. ntrsna( 3 ).NE.0 )
     $     THEN
         ok = .false.
         WRITE( nout, fmt = 9997 )rtrsna, ltrsna, ntrsna, ktrsna
      END IF
*
      CALL zget38( rtrsen, ltrsen, ntrsen, ktrsen, nin )
      IF( rtrsen( 1 ).GT.thresh .OR. rtrsen( 2 ).GT.thresh .OR.
     $    ntrsen( 1 ).NE.0 .OR. ntrsen( 2 ).NE.0 .OR. ntrsen( 3 ).NE.0 )
     $     THEN
         ok = .false.
         WRITE( nout, fmt = 9996 )rtrsen, ltrsen, ntrsen, ktrsen
      END IF
*
      ntests = ktrsyl + ktrsyl3 + ktrexc + ktrsna + ktrsen
      IF( ok )
     $   WRITE( nout, fmt = 9995 )path, ntests
*
 9999 FORMAT( ' Error in ZTRSYL: RMAX =', d12.3, / ' LMAX = ', i8,
     $      ' NINFO=', i8, ' KNT=', i8 )
 9998 FORMAT( ' Error in ZTREXC: RMAX =', d12.3, / ' LMAX = ', i8,
     $      ' NINFO=', i8, ' KNT=', i8 )
 9997 FORMAT( ' Error in ZTRSNA: RMAX =', 3d12.3, / ' LMAX = ', 3i8,
     $      ' NINFO=', 3i8, ' KNT=', i8 )
 9996 FORMAT( ' Error in ZTRSEN: RMAX =', 3d12.3, / ' LMAX = ', 3i8,
     $      ' NINFO=', 3i8, ' KNT=', i8 )
 9995 FORMAT( / 1x, 'All tests for ', a3,
     $      ' routines passed the threshold ( ', i6, ' tests run)' )
 9994 FORMAT( ' Tests of the Nonsymmetric eigenproblem condition',
     $      ' estimation routines', / ' ZTRSYL, ZTREXC, ZTRSNA, ZTRSEN',
     $      / )
 9993 FORMAT( ' Relative machine precision (EPS) = ', d16.6,
     $      / ' Safe minimum (SFMIN)             = ', d16.6, / )
 9992 FORMAT( ' Routines pass computational tests if test ratio is ',
     $      'less than', f8.2, / / )
 9970 FORMAT( 'Error in ZTRSYL: ', i8, ' tests fail the threshold.', /
     $      'Maximum test ratio =', d12.3, ' threshold =', d12.3 )
 9971 FORMAT( 'Error in ZTRSYL3: ', i8, ' tests fail the threshold.', /
     $      'Maximum test ratio =', d12.3, ' threshold =', d12.3 )
 9972 FORMAT( 'ZTRSYL and ZTRSYL3 compute an inconsistent scale ',
     $      'factor in ', i8, ' tests.')
      RETURN
*
*     End of ZCHKEC
*
      END