zggesx()

subroutine zggesx	(	character	jobvsl,
		character	jobvsr,
		character	sort,
		external	selctg,
		character	sense,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		integer	sdim,
		complex*16, dimension( * )	alpha,
		complex*16, dimension( * )	beta,
		complex*16, dimension( ldvsl, * )	vsl,
		integer	ldvsl,
		complex*16, dimension( ldvsr, * )	vsr,
		integer	ldvsr,
		double precision, dimension( 2 )	rconde,
		double precision, dimension( 2 )	rcondv,
		complex*16, dimension( * )	work,
		integer	lwork,
		double precision, dimension( * )	rwork,
		integer, dimension( * )	iwork,
		integer	liwork,
		logical, dimension( * )	bwork,
		integer	info )

ZGGESX computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE matrices

Download ZGGESX + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZGGESX computes for a pair of N-by-N complex nonsymmetric matrices
!> (A,B), the generalized eigenvalues, the complex Schur form (S,T),
!> and, optionally, the left and/or right matrices of Schur vectors (VSL
!> and VSR).  This gives the generalized Schur factorization
!>
!>      (A,B) = ( (VSL) S (VSR)**H, (VSL) T (VSR)**H )
!>
!> where (VSR)**H is the conjugate-transpose of VSR.
!>
!> Optionally, it also orders the eigenvalues so that a selected cluster
!> of eigenvalues appears in the leading diagonal blocks of the upper
!> triangular matrix S and the upper triangular matrix T; computes
!> a reciprocal condition number for the average of the selected
!> eigenvalues (RCONDE); and computes a reciprocal condition number for
!> the right and left deflating subspaces corresponding to the selected
!> eigenvalues (RCONDV). The leading columns of VSL and VSR then form
!> an orthonormal basis for the corresponding left and right eigenspaces
!> (deflating subspaces).
!>
!> A generalized eigenvalue for a pair of matrices (A,B) is a scalar w
!> or a ratio alpha/beta = w, such that  A - w*B is singular.  It is
!> usually represented as the pair (alpha,beta), as there is a
!> reasonable interpretation for beta=0 or for both being zero.
!>
!> A pair of matrices (S,T) is in generalized complex Schur form if T is
!> upper triangular with non-negative diagonal and S is upper
!> triangular.
!> 

Parameters

[in]	JOBVSL	!> JOBVSL is CHARACTER*1 !> = 'N': do not compute the left Schur vectors; !> = 'V': compute the left Schur vectors. !>
[in]	JOBVSR	!> JOBVSR is CHARACTER*1 !> = 'N': do not compute the right Schur vectors; !> = 'V': compute the right Schur vectors. !>
[in]	SORT	!> SORT is CHARACTER*1 !> Specifies whether or not to order the eigenvalues on the !> diagonal of the generalized Schur form. !> = 'N': Eigenvalues are not ordered; !> = 'S': Eigenvalues are ordered (see SELCTG). !>
[in]	SELCTG	!> SELCTG is a LOGICAL FUNCTION of two COMPLEX*16 arguments !> SELCTG must be declared EXTERNAL in the calling subroutine. !> If SORT = 'N', SELCTG is not referenced. !> If SORT = 'S', SELCTG is used to select eigenvalues to sort !> to the top left of the Schur form. !> Note that a selected complex eigenvalue may no longer satisfy !> SELCTG(ALPHA(j),BETA(j)) = .TRUE. after ordering, since !> ordering may change the value of complex eigenvalues !> (especially if the eigenvalue is ill-conditioned), in this !> case INFO is set to N+3 see INFO below). !>
[in]	SENSE	!> SENSE is CHARACTER*1 !> Determines which reciprocal condition numbers are computed. !> = 'N': None are computed; !> = 'E': Computed for average of selected eigenvalues only; !> = 'V': Computed for selected deflating subspaces only; !> = 'B': Computed for both. !> If SENSE = 'E', 'V', or 'B', SORT must equal 'S'. !>
[in]	N	!> N is INTEGER !> The order of the matrices A, B, VSL, and VSR. N >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA, N) !> On entry, the first of the pair of matrices. !> On exit, A has been overwritten by its generalized Schur !> form S. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of A. LDA >= max(1,N). !>
[in,out]	B	!> B is COMPLEX*16 array, dimension (LDB, N) !> On entry, the second of the pair of matrices. !> On exit, B has been overwritten by its generalized Schur !> form T. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of B. LDB >= max(1,N). !>
[out]	SDIM	!> SDIM is INTEGER !> If SORT = 'N', SDIM = 0. !> If SORT = 'S', SDIM = number of eigenvalues (after sorting) !> for which SELCTG is true. !>
[out]	ALPHA	!> ALPHA is COMPLEX*16 array, dimension (N) !>
[out]	BETA	!> BETA is COMPLEX*16 array, dimension (N) !> On exit, ALPHA(j)/BETA(j), j=1,...,N, will be the !> generalized eigenvalues. ALPHA(j) and BETA(j),j=1,...,N are !> the diagonals of the complex Schur form (S,T). BETA(j) will !> be non-negative real. !> !> Note: the quotients ALPHA(j)/BETA(j) may easily over- or !> underflow, and BETA(j) may even be zero. Thus, the user !> should avoid naively computing the ratio alpha/beta. !> However, ALPHA will be always less than and usually !> comparable with norm(A) in magnitude, and BETA always less !> than and usually comparable with norm(B). !>
[out]	VSL	!> VSL is COMPLEX*16 array, dimension (LDVSL,N) !> If JOBVSL = 'V', VSL will contain the left Schur vectors. !> Not referenced if JOBVSL = 'N'. !>
[in]	LDVSL	!> LDVSL is INTEGER !> The leading dimension of the matrix VSL. LDVSL >=1, and !> if JOBVSL = 'V', LDVSL >= N. !>
[out]	VSR	!> VSR is COMPLEX*16 array, dimension (LDVSR,N) !> If JOBVSR = 'V', VSR will contain the right Schur vectors. !> Not referenced if JOBVSR = 'N'. !>
[in]	LDVSR	!> LDVSR is INTEGER !> The leading dimension of the matrix VSR. LDVSR >= 1, and !> if JOBVSR = 'V', LDVSR >= N. !>
[out]	RCONDE	!> RCONDE is DOUBLE PRECISION array, dimension ( 2 ) !> If SENSE = 'E' or 'B', RCONDE(1) and RCONDE(2) contain the !> reciprocal condition numbers for the average of the selected !> eigenvalues. !> Not referenced if SENSE = 'N' or 'V'. !>
[out]	RCONDV	!> RCONDV is DOUBLE PRECISION array, dimension ( 2 ) !> If SENSE = 'V' or 'B', RCONDV(1) and RCONDV(2) contain the !> reciprocal condition number for the selected deflating !> subspaces. !> Not referenced if SENSE = 'N' or 'E'. !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !> If N = 0, LWORK >= 1, else if SENSE = 'E', 'V', or 'B', !> LWORK >= MAX(1,2*N,2*SDIM*(N-SDIM)), else !> LWORK >= MAX(1,2*N). Note that 2*SDIM*(N-SDIM) <= N*N/2. !> Note also that an error is only returned if !> LWORK < MAX(1,2*N), but if SENSE = 'E' or 'V' or 'B' this may !> not be large enough. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the bound on the optimal size of the WORK !> array and the minimum size of the IWORK array, returns these !> values as the first entries of the WORK and IWORK arrays, and !> no error message related to LWORK or LIWORK is issued by !> XERBLA. !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension ( 8*N ) !> Real workspace. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (MAX(1,LIWORK)) !> On exit, if INFO = 0, IWORK(1) returns the minimum LIWORK. !>
[in]	LIWORK	!> LIWORK is INTEGER !> The dimension of the array IWORK. !> If SENSE = 'N' or N = 0, LIWORK >= 1, otherwise !> LIWORK >= N+2. !> !> If LIWORK = -1, then a workspace query is assumed; the !> routine only calculates the bound on the optimal size of the !> WORK array and the minimum size of the IWORK array, returns !> these values as the first entries of the WORK and IWORK !> arrays, and no error message related to LWORK or LIWORK is !> issued by XERBLA. !>
[out]	BWORK	!> BWORK is LOGICAL array, dimension (N) !> Not referenced if SORT = 'N'. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> = 1,...,N: !> The QZ iteration failed. (A,B) are not in Schur !> form, but ALPHA(j) and BETA(j) should be correct for !> j=INFO+1,...,N. !> > N: =N+1: other than QZ iteration failed in ZHGEQZ !> =N+2: after reordering, roundoff changed values of !> some complex eigenvalues so that leading !> eigenvalues in the Generalized Schur form no !> longer satisfy SELCTG=.TRUE. This could also !> be caused due to scaling. !> =N+3: reordering failed in ZTGSEN. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 324 of file zggesx.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBVSL, JOBVSR, SENSE, SORT
      INTEGER            INFO, LDA, LDB, LDVSL, LDVSR, LIWORK, LWORK, N,
     $                   SDIM
*     ..
*     .. Array Arguments ..
      LOGICAL            BWORK( * )
      INTEGER            IWORK( * )
      DOUBLE PRECISION   RCONDE( 2 ), RCONDV( 2 ), RWORK( * )
      COMPLEX*16         A( LDA, * ), ALPHA( * ), B( LDB, * ),
     $                   BETA( * ), VSL( LDVSL, * ), VSR( LDVSR, * ),
     $                   WORK( * )
*     ..
*     .. Function Arguments ..
      LOGICAL            SELCTG
      EXTERNAL           selctg
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CZERO, CONE
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            CURSL, ILASCL, ILBSCL, ILVSL, ILVSR, LASTSL,
     $                   LQUERY, WANTSB, WANTSE, WANTSN, WANTST, WANTSV
      INTEGER            I, ICOLS, IERR, IHI, IJOB, IJOBVL, IJOBVR,
     $                   ILEFT, ILO, IRIGHT, IROWS, IRWRK, ITAU, IWRK,
     $                   LIWMIN, LWRK, MAXWRK, MINWRK
      DOUBLE PRECISION   ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS, PL,
     $                   PR, SMLNUM
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   DIF( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zgeqrf, zggbak, zggbal, zgghrd,
     $                   zhgeqz,
     $                   zlacpy, zlascl, zlaset, ztgsen, zungqr, zunmqr
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      DOUBLE PRECISION   DLAMCH, ZLANGE
      EXTERNAL           lsame, ilaenv, dlamch, zlange
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Decode the input arguments
*
      IF( lsame( jobvsl, 'N' ) ) THEN
         ijobvl = 1
         ilvsl = .false.
      ELSE IF( lsame( jobvsl, 'V' ) ) THEN
         ijobvl = 2
         ilvsl = .true.
      ELSE
         ijobvl = -1
         ilvsl = .false.
      END IF
*
      IF( lsame( jobvsr, 'N' ) ) THEN
         ijobvr = 1
         ilvsr = .false.
      ELSE IF( lsame( jobvsr, 'V' ) ) THEN
         ijobvr = 2
         ilvsr = .true.
      ELSE
         ijobvr = -1
         ilvsr = .false.
      END IF
*
      wantst = lsame( sort, 'S' )
      wantsn = lsame( sense, 'N' )
      wantse = lsame( sense, 'E' )
      wantsv = lsame( sense, 'V' )
      wantsb = lsame( sense, 'B' )
      lquery = ( lwork.EQ.-1 .OR. liwork.EQ.-1 )
      IF( wantsn ) THEN
         ijob = 0
      ELSE IF( wantse ) THEN
         ijob = 1
      ELSE IF( wantsv ) THEN
         ijob = 2
      ELSE IF( wantsb ) THEN
         ijob = 4
      END IF
*
*     Test the input arguments
*
      info = 0
      IF( ijobvl.LE.0 ) THEN
         info = -1
      ELSE IF( ijobvr.LE.0 ) THEN
         info = -2
      ELSE IF( ( .NOT.wantst ) .AND.
     $         ( .NOT.lsame( sort, 'N' ) ) ) THEN
         info = -3
      ELSE IF( .NOT.( wantsn .OR. wantse .OR. wantsv .OR. wantsb ) .OR.
     $         ( .NOT.wantst .AND. .NOT.wantsn ) ) THEN
         info = -5
      ELSE IF( n.LT.0 ) THEN
         info = -6
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -10
      ELSE IF( ldvsl.LT.1 .OR. ( ilvsl .AND. ldvsl.LT.n ) ) THEN
         info = -15
      ELSE IF( ldvsr.LT.1 .OR. ( ilvsr .AND. ldvsr.LT.n ) ) THEN
         info = -17
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of workspace needed at that point in the code,
*       as well as the preferred amount for good performance.
*       NB refers to the optimal block size for the immediately
*       following subroutine, as returned by ILAENV.)
*
      IF( info.EQ.0 ) THEN
         IF( n.GT.0) THEN
            minwrk = 2*n
            maxwrk = n*(1 + ilaenv( 1, 'ZGEQRF', ' ', n, 1, n, 0 ) )
            maxwrk = max( maxwrk, n*( 1 +
     $                    ilaenv( 1, 'ZUNMQR', ' ', n, 1, n, -1 ) ) )
            IF( ilvsl ) THEN
               maxwrk = max( maxwrk, n*( 1 +
     $                       ilaenv( 1, 'ZUNGQR', ' ', n, 1, n,
     $                               -1 ) ) )
            END IF
            lwrk = maxwrk
            IF( ijob.GE.1 )
     $         lwrk = max( lwrk, n*n/2 )
         ELSE
            minwrk = 1
            maxwrk = 1
            lwrk   = 1
         END IF
         work( 1 ) = lwrk
         IF( wantsn .OR. n.EQ.0 ) THEN
            liwmin = 1
         ELSE
            liwmin = n + 2
         END IF
         iwork( 1 ) = liwmin
*
         IF( lwork.LT.minwrk .AND. .NOT.lquery ) THEN
            info = -21
         ELSE IF( liwork.LT.liwmin  .AND. .NOT.lquery) THEN
            info = -24
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGGESX', -info )
         RETURN
      ELSE IF (lquery) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         sdim = 0
         RETURN
      END IF
*
*     Get machine constants
*
      eps = dlamch( 'P' )
      smlnum = dlamch( 'S' )
      bignum = one / smlnum
      smlnum = sqrt( smlnum ) / eps
      bignum = one / smlnum
*
*     Scale A if max element outside range [SMLNUM,BIGNUM]
*
      anrm = zlange( 'M', n, n, a, lda, rwork )
      ilascl = .false.
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
         anrmto = smlnum
         ilascl = .true.
      ELSE IF( anrm.GT.bignum ) THEN
         anrmto = bignum
         ilascl = .true.
      END IF
      IF( ilascl )
     $   CALL zlascl( 'G', 0, 0, anrm, anrmto, n, n, a, lda, ierr )
*
*     Scale B if max element outside range [SMLNUM,BIGNUM]
*
      bnrm = zlange( 'M', n, n, b, ldb, rwork )
      ilbscl = .false.
      IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
         bnrmto = smlnum
         ilbscl = .true.
      ELSE IF( bnrm.GT.bignum ) THEN
         bnrmto = bignum
         ilbscl = .true.
      END IF
      IF( ilbscl )
     $   CALL zlascl( 'G', 0, 0, bnrm, bnrmto, n, n, b, ldb, ierr )
*
*     Permute the matrix to make it more nearly triangular
*     (Real Workspace: need 6*N)
*
      ileft = 1
      iright = n + 1
      irwrk = iright + n
      CALL zggbal( 'P', n, a, lda, b, ldb, ilo, ihi, rwork( ileft ),
     $             rwork( iright ), rwork( irwrk ), ierr )
*
*     Reduce B to triangular form (QR decomposition of B)
*     (Complex Workspace: need N, prefer N*NB)
*
      irows = ihi + 1 - ilo
      icols = n + 1 - ilo
      itau = 1
      iwrk = itau + irows
      CALL zgeqrf( irows, icols, b( ilo, ilo ), ldb, work( itau ),
     $             work( iwrk ), lwork+1-iwrk, ierr )
*
*     Apply the unitary transformation to matrix A
*     (Complex Workspace: need N, prefer N*NB)
*
      CALL zunmqr( 'L', 'C', irows, icols, irows, b( ilo, ilo ), ldb,
     $             work( itau ), a( ilo, ilo ), lda, work( iwrk ),
     $             lwork+1-iwrk, ierr )
*
*     Initialize VSL
*     (Complex Workspace: need N, prefer N*NB)
*
      IF( ilvsl ) THEN
         CALL zlaset( 'Full', n, n, czero, cone, vsl, ldvsl )
         IF( irows.GT.1 ) THEN
            CALL zlacpy( 'L', irows-1, irows-1, b( ilo+1, ilo ), ldb,
     $                   vsl( ilo+1, ilo ), ldvsl )
         END IF
         CALL zungqr( irows, irows, irows, vsl( ilo, ilo ), ldvsl,
     $                work( itau ), work( iwrk ), lwork+1-iwrk, ierr )
      END IF
*
*     Initialize VSR
*
      IF( ilvsr )
     $   CALL zlaset( 'Full', n, n, czero, cone, vsr, ldvsr )
*
*     Reduce to generalized Hessenberg form
*     (Workspace: none needed)
*
      CALL zgghrd( jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb, vsl,
     $             ldvsl, vsr, ldvsr, ierr )
*
      sdim = 0
*
*     Perform QZ algorithm, computing Schur vectors if desired
*     (Complex Workspace: need N)
*     (Real Workspace:    need N)
*
      iwrk = itau
      CALL zhgeqz( 'S', jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb,
     $             alpha, beta, vsl, ldvsl, vsr, ldvsr, work( iwrk ),
     $             lwork+1-iwrk, rwork( irwrk ), ierr )
      IF( ierr.NE.0 ) THEN
         IF( ierr.GT.0 .AND. ierr.LE.n ) THEN
            info = ierr
         ELSE IF( ierr.GT.n .AND. ierr.LE.2*n ) THEN
            info = ierr - n
         ELSE
            info = n + 1
         END IF
         GO TO 40
      END IF
*
*     Sort eigenvalues ALPHA/BETA and compute the reciprocal of
*     condition number(s)
*
      IF( wantst ) THEN
*
*        Undo scaling on eigenvalues before SELCTGing
*
         IF( ilascl )
     $      CALL zlascl( 'G', 0, 0, anrmto, anrm, n, 1, alpha, n,
     $                   ierr )
         IF( ilbscl )
     $      CALL zlascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n,
     $                   ierr )
*
*        Select eigenvalues
*
         DO 10 i = 1, n
            bwork( i ) = selctg( alpha( i ), beta( i ) )
   10    CONTINUE
*
*        Reorder eigenvalues, transform Generalized Schur vectors, and
*        compute reciprocal condition numbers
*        (Complex Workspace: If IJOB >= 1, need MAX(1, 2*SDIM*(N-SDIM))
*                            otherwise, need 1 )
*
         CALL ztgsen( ijob, ilvsl, ilvsr, bwork, n, a, lda, b, ldb,
     $                alpha, beta, vsl, ldvsl, vsr, ldvsr, sdim, pl, pr,
     $                dif, work( iwrk ), lwork-iwrk+1, iwork, liwork,
     $                ierr )
*
         IF( ijob.GE.1 )
     $      maxwrk = max( maxwrk, 2*sdim*( n-sdim ) )
         IF( ierr.EQ.-21 ) THEN
*
*            not enough complex workspace
*
            info = -21
         ELSE
            IF( ijob.EQ.1 .OR. ijob.EQ.4 ) THEN
               rconde( 1 ) = pl
               rconde( 2 ) = pr
            END IF
            IF( ijob.EQ.2 .OR. ijob.EQ.4 ) THEN
               rcondv( 1 ) = dif( 1 )
               rcondv( 2 ) = dif( 2 )
            END IF
            IF( ierr.EQ.1 )
     $         info = n + 3
         END IF
*
      END IF
*
*     Apply permutation to VSL and VSR
*     (Workspace: none needed)
*
      IF( ilvsl )
     $   CALL zggbak( 'P', 'L', n, ilo, ihi, rwork( ileft ),
     $                rwork( iright ), n, vsl, ldvsl, ierr )
*
      IF( ilvsr )
     $   CALL zggbak( 'P', 'R', n, ilo, ihi, rwork( ileft ),
     $                rwork( iright ), n, vsr, ldvsr, ierr )
*
*     Undo scaling
*
      IF( ilascl ) THEN
         CALL zlascl( 'U', 0, 0, anrmto, anrm, n, n, a, lda, ierr )
         CALL zlascl( 'G', 0, 0, anrmto, anrm, n, 1, alpha, n, ierr )
      END IF
*
      IF( ilbscl ) THEN
         CALL zlascl( 'U', 0, 0, bnrmto, bnrm, n, n, b, ldb, ierr )
         CALL zlascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
      END IF
*
      IF( wantst ) THEN
*
*        Check if reordering is correct
*
         lastsl = .true.
         sdim = 0
         DO 30 i = 1, n
            cursl = selctg( alpha( i ), beta( i ) )
            IF( cursl )
     $         sdim = sdim + 1
            IF( cursl .AND. .NOT.lastsl )
     $         info = n + 2
            lastsl = cursl
   30    CONTINUE
*
      END IF
*
   40 CONTINUE
*
      work( 1 ) = maxwrk
      iwork( 1 ) = liwmin
*
      RETURN
*
*     End of ZGGESX
*

Here is the call graph for this function:

Here is the caller graph for this function: