LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ cla_porfsx_extended()

subroutine cla_porfsx_extended ( integer prec_type,
character uplo,
integer n,
integer nrhs,
complex, dimension( lda, * ) a,
integer lda,
complex, dimension( ldaf, * ) af,
integer ldaf,
logical colequ,
real, dimension( * ) c,
complex, dimension( ldb, * ) b,
integer ldb,
complex, dimension( ldy, * ) y,
integer ldy,
real, dimension( * ) berr_out,
integer n_norms,
real, dimension( nrhs, * ) err_bnds_norm,
real, dimension( nrhs, * ) err_bnds_comp,
complex, dimension( * ) res,
real, dimension( * ) ayb,
complex, dimension( * ) dy,
complex, dimension( * ) y_tail,
real rcond,
integer ithresh,
real rthresh,
real dz_ub,
logical ignore_cwise,
integer info )

CLA_PORFSX_EXTENDED improves the computed solution to a system of linear equations for symmetric or Hermitian positive-definite matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.

Download CLA_PORFSX_EXTENDED + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> CLA_PORFSX_EXTENDED improves the computed solution to a system of
!> linear equations by performing extra-precise iterative refinement
!> and provides error bounds and backward error estimates for the solution.
!> This subroutine is called by CPORFSX to perform iterative refinement.
!> In addition to normwise error bound, the code provides maximum
!> componentwise error bound if possible. See comments for ERR_BNDS_NORM
!> and ERR_BNDS_COMP for details of the error bounds. Note that this
!> subroutine is only responsible for setting the second fields of
!> ERR_BNDS_NORM and ERR_BNDS_COMP.
!>
Parameters
[in]PREC_TYPE
!>          PREC_TYPE is INTEGER
!>     Specifies the intermediate precision to be used in refinement.
!>     The value is defined by ILAPREC(P) where P is a CHARACTER and P
!>          = 'S':  Single
!>          = 'D':  Double
!>          = 'I':  Indigenous
!>          = 'X' or 'E':  Extra
!>
[in]UPLO
!>          UPLO is CHARACTER*1
!>       = 'U':  Upper triangle of A is stored;
!>       = 'L':  Lower triangle of A is stored.
!>
[in]N
!>          N is INTEGER
!>     The number of linear equations, i.e., the order of the
!>     matrix A.  N >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>     The number of right-hand-sides, i.e., the number of columns of the
!>     matrix B.
!>
[in]A
!>          A is COMPLEX array, dimension (LDA,N)
!>     On entry, the N-by-N matrix A.
!>
[in]LDA
!>          LDA is INTEGER
!>     The leading dimension of the array A.  LDA >= max(1,N).
!>
[in]AF
!>          AF is COMPLEX array, dimension (LDAF,N)
!>     The triangular factor U or L from the Cholesky factorization
!>     A = U**T*U or A = L*L**T, as computed by CPOTRF.
!>
[in]LDAF
!>          LDAF is INTEGER
!>     The leading dimension of the array AF.  LDAF >= max(1,N).
!>
[in]COLEQU
!>          COLEQU is LOGICAL
!>     If .TRUE. then column equilibration was done to A before calling
!>     this routine. This is needed to compute the solution and error
!>     bounds correctly.
!>
[in]C
!>          C is REAL array, dimension (N)
!>     The column scale factors for A. If COLEQU = .FALSE., C
!>     is not accessed. If C is input, each element of C should be a power
!>     of the radix to ensure a reliable solution and error estimates.
!>     Scaling by powers of the radix does not cause rounding errors unless
!>     the result underflows or overflows. Rounding errors during scaling
!>     lead to refining with a matrix that is not equivalent to the
!>     input matrix, producing error estimates that may not be
!>     reliable.
!>
[in]B
!>          B is COMPLEX array, dimension (LDB,NRHS)
!>     The right-hand-side matrix B.
!>
[in]LDB
!>          LDB is INTEGER
!>     The leading dimension of the array B.  LDB >= max(1,N).
!>
[in,out]Y
!>          Y is COMPLEX array, dimension (LDY,NRHS)
!>     On entry, the solution matrix X, as computed by CPOTRS.
!>     On exit, the improved solution matrix Y.
!>
[in]LDY
!>          LDY is INTEGER
!>     The leading dimension of the array Y.  LDY >= max(1,N).
!>
[out]BERR_OUT
!>          BERR_OUT is REAL array, dimension (NRHS)
!>     On exit, BERR_OUT(j) contains the componentwise relative backward
!>     error for right-hand-side j from the formula
!>         max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
!>     where abs(Z) is the componentwise absolute value of the matrix
!>     or vector Z. This is computed by CLA_LIN_BERR.
!>
[in]N_NORMS
!>          N_NORMS is INTEGER
!>     Determines which error bounds to return (see ERR_BNDS_NORM
!>     and ERR_BNDS_COMP).
!>     If N_NORMS >= 1 return normwise error bounds.
!>     If N_NORMS >= 2 return componentwise error bounds.
!>
[in,out]ERR_BNDS_NORM
!>          ERR_BNDS_NORM is REAL array, dimension (NRHS, N_ERR_BNDS)
!>     For each right-hand side, this array contains information about
!>     various error bounds and condition numbers corresponding to the
!>     normwise relative error, which is defined as follows:
!>
!>     Normwise relative error in the ith solution vector:
!>             max_j (abs(XTRUE(j,i) - X(j,i)))
!>            ------------------------------
!>                  max_j abs(X(j,i))
!>
!>     The array is indexed by the type of error information as described
!>     below. There currently are up to three pieces of information
!>     returned.
!>
!>     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
!>     right-hand side.
!>
!>     The second index in ERR_BNDS_NORM(:,err) contains the following
!>     three fields:
!>     err = 1  boolean. Trust the answer if the
!>              reciprocal condition number is less than the threshold
!>              sqrt(n) * slamch('Epsilon').
!>
!>     err = 2  error bound: The estimated forward error,
!>              almost certainly within a factor of 10 of the true error
!>              so long as the next entry is greater than the threshold
!>              sqrt(n) * slamch('Epsilon'). This error bound should only
!>              be trusted if the previous boolean is true.
!>
!>     err = 3  Reciprocal condition number: Estimated normwise
!>              reciprocal condition number.  Compared with the threshold
!>              sqrt(n) * slamch('Epsilon') to determine if the error
!>              estimate is . These reciprocal condition
!>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
!>              appropriately scaled matrix Z.
!>              Let Z = S*A, where S scales each row by a power of the
!>              radix so all absolute row sums of Z are approximately 1.
!>
!>     This subroutine is only responsible for setting the second field
!>     above.
!>     See Lapack Working Note 165 for further details and extra
!>     cautions.
!>
[in,out]ERR_BNDS_COMP
!>          ERR_BNDS_COMP is REAL array, dimension (NRHS, N_ERR_BNDS)
!>     For each right-hand side, this array contains information about
!>     various error bounds and condition numbers corresponding to the
!>     componentwise relative error, which is defined as follows:
!>
!>     Componentwise relative error in the ith solution vector:
!>                    abs(XTRUE(j,i) - X(j,i))
!>             max_j ----------------------
!>                         abs(X(j,i))
!>
!>     The array is indexed by the right-hand side i (on which the
!>     componentwise relative error depends), and the type of error
!>     information as described below. There currently are up to three
!>     pieces of information returned for each right-hand side. If
!>     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
!>     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS < 3, then at most
!>     the first (:,N_ERR_BNDS) entries are returned.
!>
!>     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
!>     right-hand side.
!>
!>     The second index in ERR_BNDS_COMP(:,err) contains the following
!>     three fields:
!>     err = 1  boolean. Trust the answer if the
!>              reciprocal condition number is less than the threshold
!>              sqrt(n) * slamch('Epsilon').
!>
!>     err = 2  error bound: The estimated forward error,
!>              almost certainly within a factor of 10 of the true error
!>              so long as the next entry is greater than the threshold
!>              sqrt(n) * slamch('Epsilon'). This error bound should only
!>              be trusted if the previous boolean is true.
!>
!>     err = 3  Reciprocal condition number: Estimated componentwise
!>              reciprocal condition number.  Compared with the threshold
!>              sqrt(n) * slamch('Epsilon') to determine if the error
!>              estimate is . These reciprocal condition
!>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
!>              appropriately scaled matrix Z.
!>              Let Z = S*(A*diag(x)), where x is the solution for the
!>              current right-hand side and S scales each row of
!>              A*diag(x) by a power of the radix so all absolute row
!>              sums of Z are approximately 1.
!>
!>     This subroutine is only responsible for setting the second field
!>     above.
!>     See Lapack Working Note 165 for further details and extra
!>     cautions.
!>
[in]RES
!>          RES is COMPLEX array, dimension (N)
!>     Workspace to hold the intermediate residual.
!>
[in]AYB
!>          AYB is REAL array, dimension (N)
!>     Workspace.
!>
[in]DY
!>          DY is COMPLEX array, dimension (N)
!>     Workspace to hold the intermediate solution.
!>
[in]Y_TAIL
!>          Y_TAIL is COMPLEX array, dimension (N)
!>     Workspace to hold the trailing bits of the intermediate solution.
!>
[in]RCOND
!>          RCOND is REAL
!>     Reciprocal scaled condition number.  This is an estimate of the
!>     reciprocal Skeel condition number of the matrix A after
!>     equilibration (if done).  If this is less than the machine
!>     precision (in particular, if it is zero), the matrix is singular
!>     to working precision.  Note that the error may still be small even
!>     if this number is very small and the matrix appears ill-
!>     conditioned.
!>
[in]ITHRESH
!>          ITHRESH is INTEGER
!>     The maximum number of residual computations allowed for
!>     refinement. The default is 10. For 'aggressive' set to 100 to
!>     permit convergence using approximate factorizations or
!>     factorizations other than LU. If the factorization uses a
!>     technique other than Gaussian elimination, the guarantees in
!>     ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
!>
[in]RTHRESH
!>          RTHRESH is REAL
!>     Determines when to stop refinement if the error estimate stops
!>     decreasing. Refinement will stop when the next solution no longer
!>     satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
!>     the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
!>     default value is 0.5. For 'aggressive' set to 0.9 to permit
!>     convergence on extremely ill-conditioned matrices. See LAWN 165
!>     for more details.
!>
[in]DZ_UB
!>          DZ_UB is REAL
!>     Determines when to start considering componentwise convergence.
!>     Componentwise convergence is only considered after each component
!>     of the solution Y is stable, which we define as the relative
!>     change in each component being less than DZ_UB. The default value
!>     is 0.25, requiring the first bit to be stable. See LAWN 165 for
!>     more details.
!>
[in]IGNORE_CWISE
!>          IGNORE_CWISE is LOGICAL
!>     If .TRUE. then ignore componentwise convergence. Default value
!>     is .FALSE..
!>
[out]INFO
!>          INFO is INTEGER
!>       = 0:  Successful exit.
!>       < 0:  if INFO = -i, the ith argument to CPOTRS had an illegal
!>             value
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 378 of file cla_porfsx_extended.f.

386*
387* -- LAPACK computational routine --
388* -- LAPACK is a software package provided by Univ. of Tennessee, --
389* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
390*
391* .. Scalar Arguments ..
392 INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
393 $ N_NORMS, ITHRESH
394 CHARACTER UPLO
395 LOGICAL COLEQU, IGNORE_CWISE
396 REAL RTHRESH, DZ_UB
397* ..
398* .. Array Arguments ..
399 COMPLEX A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
400 $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
401 REAL C( * ), AYB( * ), RCOND, BERR_OUT( * ),
402 $ ERR_BNDS_NORM( NRHS, * ),
403 $ ERR_BNDS_COMP( NRHS, * )
404* ..
405*
406* =====================================================================
407*
408* .. Local Scalars ..
409 INTEGER UPLO2, CNT, I, J, X_STATE, Z_STATE,
410 $ Y_PREC_STATE
411 REAL YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
412 $ DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
413 $ DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
414 $ EPS, HUGEVAL, INCR_THRESH
415 LOGICAL INCR_PREC
416 COMPLEX ZDUM
417* ..
418* .. Parameters ..
419 INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
420 $ NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
421 $ EXTRA_Y
422 parameter( unstable_state = 0, working_state = 1,
423 $ conv_state = 2, noprog_state = 3 )
424 parameter( base_residual = 0, extra_residual = 1,
425 $ extra_y = 2 )
426 INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
427 INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
428 INTEGER CMP_ERR_I, PIV_GROWTH_I
429 parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
430 $ berr_i = 3 )
431 parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
432 parameter( cmp_rcond_i = 7, cmp_err_i = 8,
433 $ piv_growth_i = 9 )
434 INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
435 $ LA_LINRX_CWISE_I
436 parameter( la_linrx_itref_i = 1,
437 $ la_linrx_ithresh_i = 2 )
438 parameter( la_linrx_cwise_i = 3 )
439 INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
440 $ LA_LINRX_RCOND_I
441 parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
442 parameter( la_linrx_rcond_i = 3 )
443* ..
444* .. External Functions ..
445 LOGICAL LSAME
446 EXTERNAL ilauplo
447 INTEGER ILAUPLO
448* ..
449* .. External Subroutines ..
450 EXTERNAL caxpy, ccopy, cpotrs, chemv,
451 $ blas_chemv_x,
452 $ blas_chemv2_x, cla_heamv, cla_wwaddw,
453 $ cla_lin_berr, slamch
454 REAL SLAMCH
455* ..
456* .. Intrinsic Functions ..
457 INTRINSIC abs, real, aimag, max, min
458* ..
459* .. Statement Functions ..
460 REAL CABS1
461* ..
462* .. Statement Function Definitions ..
463 cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
464* ..
465* .. Executable Statements ..
466*
467 IF (info.NE.0) RETURN
468 eps = slamch( 'Epsilon' )
469 hugeval = slamch( 'Overflow' )
470* Force HUGEVAL to Inf
471 hugeval = hugeval * hugeval
472* Using HUGEVAL may lead to spurious underflows.
473 incr_thresh = real(n) * eps
474
475 IF (lsame(uplo, 'L')) THEN
476 uplo2 = ilauplo( 'L' )
477 ELSE
478 uplo2 = ilauplo( 'U' )
479 ENDIF
480
481 DO j = 1, nrhs
482 y_prec_state = extra_residual
483 IF (y_prec_state .EQ. extra_y) THEN
484 DO i = 1, n
485 y_tail( i ) = 0.0
486 END DO
487 END IF
488
489 dxrat = 0.0
490 dxratmax = 0.0
491 dzrat = 0.0
492 dzratmax = 0.0
493 final_dx_x = hugeval
494 final_dz_z = hugeval
495 prevnormdx = hugeval
496 prev_dz_z = hugeval
497 dz_z = hugeval
498 dx_x = hugeval
499
500 x_state = working_state
501 z_state = unstable_state
502 incr_prec = .false.
503
504 DO cnt = 1, ithresh
505*
506* Compute residual RES = B_s - op(A_s) * Y,
507* op(A) = A, A**T, or A**H depending on TRANS (and type).
508*
509 CALL ccopy( n, b( 1, j ), 1, res, 1 )
510 IF (y_prec_state .EQ. base_residual) THEN
511 CALL chemv(uplo, n, cmplx(-1.0), a, lda, y(1,j), 1,
512 $ cmplx(1.0), res, 1)
513 ELSE IF (y_prec_state .EQ. extra_residual) THEN
514 CALL blas_chemv_x(uplo2, n, cmplx(-1.0), a, lda,
515 $ y( 1, j ), 1, cmplx(1.0), res, 1, prec_type)
516 ELSE
517 CALL blas_chemv2_x(uplo2, n, cmplx(-1.0), a, lda,
518 $ y(1, j), y_tail, 1, cmplx(1.0), res, 1, prec_type)
519 END IF
520
521! XXX: RES is no longer needed.
522 CALL ccopy( n, res, 1, dy, 1 )
523 CALL cpotrs( uplo, n, 1, af, ldaf, dy, n, info)
524*
525* Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
526*
527 normx = 0.0
528 normy = 0.0
529 normdx = 0.0
530 dz_z = 0.0
531 ymin = hugeval
532
533 DO i = 1, n
534 yk = cabs1(y(i, j))
535 dyk = cabs1(dy(i))
536
537 IF (yk .NE. 0.0) THEN
538 dz_z = max( dz_z, dyk / yk )
539 ELSE IF (dyk .NE. 0.0) THEN
540 dz_z = hugeval
541 END IF
542
543 ymin = min( ymin, yk )
544
545 normy = max( normy, yk )
546
547 IF ( colequ ) THEN
548 normx = max(normx, yk * c(i))
549 normdx = max(normdx, dyk * c(i))
550 ELSE
551 normx = normy
552 normdx = max(normdx, dyk)
553 END IF
554 END DO
555
556 IF (normx .NE. 0.0) THEN
557 dx_x = normdx / normx
558 ELSE IF (normdx .EQ. 0.0) THEN
559 dx_x = 0.0
560 ELSE
561 dx_x = hugeval
562 END IF
563
564 dxrat = normdx / prevnormdx
565 dzrat = dz_z / prev_dz_z
566*
567* Check termination criteria.
568*
569 IF (ymin*rcond .LT. incr_thresh*normy
570 $ .AND. y_prec_state .LT. extra_y)
571 $ incr_prec = .true.
572
573 IF (x_state .EQ. noprog_state .AND. dxrat .LE. rthresh)
574 $ x_state = working_state
575 IF (x_state .EQ. working_state) THEN
576 IF (dx_x .LE. eps) THEN
577 x_state = conv_state
578 ELSE IF (dxrat .GT. rthresh) THEN
579 IF (y_prec_state .NE. extra_y) THEN
580 incr_prec = .true.
581 ELSE
582 x_state = noprog_state
583 END IF
584 ELSE
585 IF (dxrat .GT. dxratmax) dxratmax = dxrat
586 END IF
587 IF (x_state .GT. working_state) final_dx_x = dx_x
588 END IF
589
590 IF (z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub)
591 $ z_state = working_state
592 IF (z_state .EQ. noprog_state .AND. dzrat .LE. rthresh)
593 $ z_state = working_state
594 IF (z_state .EQ. working_state) THEN
595 IF (dz_z .LE. eps) THEN
596 z_state = conv_state
597 ELSE IF (dz_z .GT. dz_ub) THEN
598 z_state = unstable_state
599 dzratmax = 0.0
600 final_dz_z = hugeval
601 ELSE IF (dzrat .GT. rthresh) THEN
602 IF (y_prec_state .NE. extra_y) THEN
603 incr_prec = .true.
604 ELSE
605 z_state = noprog_state
606 END IF
607 ELSE
608 IF (dzrat .GT. dzratmax) dzratmax = dzrat
609 END IF
610 IF (z_state .GT. working_state) final_dz_z = dz_z
611 END IF
612
613 IF ( x_state.NE.working_state.AND.
614 $ (ignore_cwise.OR.z_state.NE.working_state) )
615 $ GOTO 666
616
617 IF (incr_prec) THEN
618 incr_prec = .false.
619 y_prec_state = y_prec_state + 1
620 DO i = 1, n
621 y_tail( i ) = 0.0
622 END DO
623 END IF
624
625 prevnormdx = normdx
626 prev_dz_z = dz_z
627*
628* Update solution.
629*
630 IF (y_prec_state .LT. extra_y) THEN
631 CALL caxpy( n, cmplx(1.0), dy, 1, y(1,j), 1 )
632 ELSE
633 CALL cla_wwaddw(n, y(1,j), y_tail, dy)
634 END IF
635
636 END DO
637* Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
638 666 CONTINUE
639*
640* Set final_* when cnt hits ithresh.
641*
642 IF (x_state .EQ. working_state) final_dx_x = dx_x
643 IF (z_state .EQ. working_state) final_dz_z = dz_z
644*
645* Compute error bounds.
646*
647 IF (n_norms .GE. 1) THEN
648 err_bnds_norm( j, la_linrx_err_i ) =
649 $ final_dx_x / (1 - dxratmax)
650 END IF
651 IF (n_norms .GE. 2) THEN
652 err_bnds_comp( j, la_linrx_err_i ) =
653 $ final_dz_z / (1 - dzratmax)
654 END IF
655*
656* Compute componentwise relative backward error from formula
657* max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
658* where abs(Z) is the componentwise absolute value of the matrix
659* or vector Z.
660*
661* Compute residual RES = B_s - op(A_s) * Y,
662* op(A) = A, A**T, or A**H depending on TRANS (and type).
663*
664 CALL ccopy( n, b( 1, j ), 1, res, 1 )
665 CALL chemv(uplo, n, cmplx(-1.0), a, lda, y(1,j), 1,
666 $ cmplx(1.0),
667 $ res, 1)
668
669 DO i = 1, n
670 ayb( i ) = cabs1( b( i, j ) )
671 END DO
672*
673* Compute abs(op(A_s))*abs(Y) + abs(B_s).
674*
675 CALL cla_heamv (uplo2, n, 1.0,
676 $ a, lda, y(1, j), 1, 1.0, ayb, 1)
677
678 CALL cla_lin_berr (n, n, 1, res, ayb, berr_out(j))
679*
680* End of loop for each RHS.
681*
682 END DO
683*
684 RETURN
685*
686* End of CLA_PORFSX_EXTENDED
687*
caxpy
subroutine caxpy(n, ca, cx, incx, cy, incy)
CAXPY
Definition caxpy.f:88
ccopy
subroutine ccopy(n, cx, incx, cy, incy)
CCOPY
Definition ccopy.f:81
chemv
subroutine chemv(uplo, n, alpha, a, lda, x, incx, beta, y, incy)
CHEMV
Definition chemv.f:154
ilauplo
integer function ilauplo(uplo)
ILAUPLO
Definition ilauplo.f:56
cla_heamv
subroutine cla_heamv(uplo, n, alpha, a, lda, x, incx, beta, y, incy)
CLA_HEAMV computes a matrix-vector product using a Hermitian indefinite matrix to calculate error bou...
Definition cla_heamv.f:176
cla_lin_berr
subroutine cla_lin_berr(n, nz, nrhs, res, ayb, berr)
CLA_LIN_BERR computes a component-wise relative backward error.
Definition cla_lin_berr.f:99
cla_wwaddw
subroutine cla_wwaddw(n, x, y, w)
CLA_WWADDW adds a vector into a doubled-single vector.
Definition cla_wwaddw.f:79
slamch
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
cpotrs
subroutine cpotrs(uplo, n, nrhs, a, lda, b, ldb, info)
CPOTRS
Definition cpotrs.f:108
Here is the call graph for this function:
Here is the caller graph for this function: