dlarrc()

subroutine dlarrc	(	character	jobt,
		integer	n,
		double precision	vl,
		double precision	vu,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		double precision	pivmin,
		integer	eigcnt,
		integer	lcnt,
		integer	rcnt,
		integer	info )

DLARRC computes the number of eigenvalues of the symmetric tridiagonal matrix.

Download DLARRC + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> Find the number of eigenvalues of the symmetric tridiagonal matrix T
!> that are in the interval (VL,VU] if JOBT = 'T', and of L D L^T
!> if JOBT = 'L'.
!> 

Parameters

[in]	JOBT	!> JOBT is CHARACTER*1 !> = 'T': Compute Sturm count for matrix T. !> = 'L': Compute Sturm count for matrix L D L^T. !>
[in]	N	!> N is INTEGER !> The order of the matrix. N > 0. !>
[in]	VL	!> VL is DOUBLE PRECISION !> The lower bound for the eigenvalues. !>
[in]	VU	!> VU is DOUBLE PRECISION !> The upper bound for the eigenvalues. !>
[in]	D	!> D is DOUBLE PRECISION array, dimension (N) !> JOBT = 'T': The N diagonal elements of the tridiagonal matrix T. !> JOBT = 'L': The N diagonal elements of the diagonal matrix D. !>
[in]	E	!> E is DOUBLE PRECISION array, dimension (N) !> JOBT = 'T': The N-1 offdiagonal elements of the matrix T. !> JOBT = 'L': The N-1 offdiagonal elements of the matrix L. !>
[in]	PIVMIN	!> PIVMIN is DOUBLE PRECISION !> The minimum pivot in the Sturm sequence for T. !>
[out]	EIGCNT	!> EIGCNT is INTEGER !> The number of eigenvalues of the symmetric tridiagonal matrix T !> that are in the interval (VL,VU] !>
[out]	LCNT	!> LCNT is INTEGER !>
[out]	RCNT	!> RCNT is INTEGER !> The left and right negcounts of the interval. !>
[out]	INFO	!> INFO is INTEGER !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Beresford Parlett, University of California, Berkeley, USA
Jim Demmel, University of California, Berkeley, USA
Inderjit Dhillon, University of Texas, Austin, USA
Osni Marques, LBNL/NERSC, USA
Christof Voemel, University of California, Berkeley, USA

Definition at line 133 of file dlarrc.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBT
      INTEGER            EIGCNT, INFO, LCNT, N, RCNT
      DOUBLE PRECISION   PIVMIN, VL, VU
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * ), E( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I
      LOGICAL            MATT
      DOUBLE PRECISION   LPIVOT, RPIVOT, SL, SU, TMP, TMP2
 
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
      info = 0
      lcnt = 0
      rcnt = 0
      eigcnt = 0
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         RETURN
      END IF
*
      matt = lsame( jobt, 'T' )
 
 
      IF (matt) THEN
*        Sturm sequence count on T
         lpivot = d( 1 ) - vl
         rpivot = d( 1 ) - vu
         IF( lpivot.LE.zero ) THEN
            lcnt = lcnt + 1
         ENDIF
         IF( rpivot.LE.zero ) THEN
            rcnt = rcnt + 1
         ENDIF
         DO 10 i = 1, n-1
            tmp = e(i)**2
            lpivot = ( d( i+1 )-vl ) - tmp/lpivot
            rpivot = ( d( i+1 )-vu ) - tmp/rpivot
            IF( lpivot.LE.zero ) THEN
               lcnt = lcnt + 1
            ENDIF
            IF( rpivot.LE.zero ) THEN
               rcnt = rcnt + 1
            ENDIF
 10      CONTINUE
      ELSE
*        Sturm sequence count on L D L^T
         sl = -vl
         su = -vu
         DO 20 i = 1, n - 1
            lpivot = d( i ) + sl
            rpivot = d( i ) + su
            IF( lpivot.LE.zero ) THEN
               lcnt = lcnt + 1
            ENDIF
            IF( rpivot.LE.zero ) THEN
               rcnt = rcnt + 1
            ENDIF
            tmp = e(i) * d(i) * e(i)
*
            tmp2 = tmp / lpivot
            IF( tmp2.EQ.zero ) THEN
               sl =  tmp - vl
            ELSE
               sl = sl*tmp2 - vl
            END IF
*
            tmp2 = tmp / rpivot
            IF( tmp2.EQ.zero ) THEN
               su =  tmp - vu
            ELSE
               su = su*tmp2 - vu
            END IF
 20      CONTINUE
         lpivot = d( n ) + sl
         rpivot = d( n ) + su
         IF( lpivot.LE.zero ) THEN
            lcnt = lcnt + 1
         ENDIF
         IF( rpivot.LE.zero ) THEN
            rcnt = rcnt + 1
         ENDIF
      ENDIF
      eigcnt = rcnt - lcnt
 
      RETURN
*
*     End of DLARRC
*

Here is the caller graph for this function: