LAPACK  3.10.0
LAPACK: Linear Algebra PACKage

◆ dlangb()

double precision function dlangb ( character  NORM,
integer  N,
integer  KL,
integer  KU,
double precision, dimension( ldab, * )  AB,
integer  LDAB,
double precision, dimension( * )  WORK 
)

DLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of general band matrix.

Download DLANGB + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLANGB  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the element of  largest absolute value  of an
 n by n band matrix  A,  with kl sub-diagonals and ku super-diagonals.
Returns
DLANGB
    DLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in DLANGB as described
          above.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, DLANGB is
          set to zero.
[in]KL
          KL is INTEGER
          The number of sub-diagonals of the matrix A.  KL >= 0.
[in]KU
          KU is INTEGER
          The number of super-diagonals of the matrix A.  KU >= 0.
[in]AB
          AB is DOUBLE PRECISION array, dimension (LDAB,N)
          The band matrix A, stored in rows 1 to KL+KU+1.  The j-th
          column of A is stored in the j-th column of the array AB as
          follows:
          AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
[in]LDAB
          LDAB is INTEGER
          The leading dimension of the array AB.  LDAB >= KL+KU+1.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I'; otherwise, WORK is not
          referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 122 of file dlangb.f.

124 *
125 * -- LAPACK auxiliary routine --
126 * -- LAPACK is a software package provided by Univ. of Tennessee, --
127 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
128 *
129  IMPLICIT NONE
130 * .. Scalar Arguments ..
131  CHARACTER NORM
132  INTEGER KL, KU, LDAB, N
133 * ..
134 * .. Array Arguments ..
135  DOUBLE PRECISION AB( LDAB, * ), WORK( * )
136 * ..
137 *
138 * =====================================================================
139 *
140 * .. Parameters ..
141  DOUBLE PRECISION ONE, ZERO
142  parameter( one = 1.0d+0, zero = 0.0d+0 )
143 * ..
144 * .. Local Scalars ..
145  INTEGER I, J, K, L
146  DOUBLE PRECISION SUM, VALUE, TEMP
147 * ..
148 * .. Local Arrays ..
149  DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
150 * ..
151 * .. External Functions ..
152  LOGICAL LSAME, DISNAN
153  EXTERNAL lsame, disnan
154 * ..
155 * .. External Subroutines ..
156  EXTERNAL dlassq, dcombssq
157 * ..
158 * .. Intrinsic Functions ..
159  INTRINSIC abs, max, min, sqrt
160 * ..
161 * .. Executable Statements ..
162 *
163  IF( n.EQ.0 ) THEN
164  VALUE = zero
165  ELSE IF( lsame( norm, 'M' ) ) THEN
166 *
167 * Find max(abs(A(i,j))).
168 *
169  VALUE = zero
170  DO 20 j = 1, n
171  DO 10 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
172  temp = abs( ab( i, j ) )
173  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
174  10 CONTINUE
175  20 CONTINUE
176  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
177 *
178 * Find norm1(A).
179 *
180  VALUE = zero
181  DO 40 j = 1, n
182  sum = zero
183  DO 30 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
184  sum = sum + abs( ab( i, j ) )
185  30 CONTINUE
186  IF( VALUE.LT.sum .OR. disnan( sum ) ) VALUE = sum
187  40 CONTINUE
188  ELSE IF( lsame( norm, 'I' ) ) THEN
189 *
190 * Find normI(A).
191 *
192  DO 50 i = 1, n
193  work( i ) = zero
194  50 CONTINUE
195  DO 70 j = 1, n
196  k = ku + 1 - j
197  DO 60 i = max( 1, j-ku ), min( n, j+kl )
198  work( i ) = work( i ) + abs( ab( k+i, j ) )
199  60 CONTINUE
200  70 CONTINUE
201  VALUE = zero
202  DO 80 i = 1, n
203  temp = work( i )
204  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
205  80 CONTINUE
206  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
207 *
208 * Find normF(A).
209 * SSQ(1) is scale
210 * SSQ(2) is sum-of-squares
211 * For better accuracy, sum each column separately.
212 *
213  ssq( 1 ) = zero
214  ssq( 2 ) = one
215  DO 90 j = 1, n
216  l = max( 1, j-ku )
217  k = ku + 1 - j + l
218  colssq( 1 ) = zero
219  colssq( 2 ) = one
220  CALL dlassq( min( n, j+kl )-l+1, ab( k, j ), 1,
221  $ colssq( 1 ), colssq( 2 ) )
222  CALL dcombssq( ssq, colssq )
223  90 CONTINUE
224  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
225  END IF
226 *
227  dlangb = VALUE
228  RETURN
229 *
230 * End of DLANGB
231 *
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine dlassq(n, x, incx, scl, sumsq)
DLASSQ updates a sum of squares represented in scaled form.
Definition: dlassq.f90:126
subroutine dcombssq(V1, V2)
DCOMBSSQ adds two scaled sum of squares quantities.
Definition: dcombssq.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function dlangb(NORM, N, KL, KU, AB, LDAB, WORK)
DLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: dlangb.f:124
Here is the call graph for this function:
Here is the caller graph for this function: