dsvdch()

subroutine dsvdch	(	integer	n,
		double precision, dimension( * )	s,
		double precision, dimension( * )	e,
		double precision, dimension( * )	svd,
		double precision	tol,
		integer	info )

DSVDCH

Purpose:

!>
!> DSVDCH checks to see if SVD(1) ,..., SVD(N) are accurate singular
!> values of the bidiagonal matrix B with diagonal entries
!> S(1) ,..., S(N) and superdiagonal entries E(1) ,..., E(N-1)).
!> It does this by expanding each SVD(I) into an interval
!> [SVD(I) * (1-EPS) , SVD(I) * (1+EPS)], merging overlapping intervals
!> if any, and using Sturm sequences to count and verify whether each
!> resulting interval has the correct number of singular values (using
!> DSVDCT). Here EPS=TOL*MAX(N/10,1)*MAZHEP, where MACHEP is the
!> machine precision. The routine assumes the singular values are sorted
!> with SVD(1) the largest and SVD(N) smallest.  If each interval
!> contains the correct number of singular values, INFO = 0 is returned,
!> otherwise INFO is the index of the first singular value in the first
!> bad interval.
!> 

Parameters

[in]	N	!> N is INTEGER !> The dimension of the bidiagonal matrix B. !>
[in]	S	!> S is DOUBLE PRECISION array, dimension (N) !> The diagonal entries of the bidiagonal matrix B. !>
[in]	E	!> E is DOUBLE PRECISION array, dimension (N-1) !> The superdiagonal entries of the bidiagonal matrix B. !>
[in]	SVD	!> SVD is DOUBLE PRECISION array, dimension (N) !> The computed singular values to be checked. !>
[in]	TOL	!> TOL is DOUBLE PRECISION !> Error tolerance for checking, a multiplier of the !> machine precision. !>
[out]	INFO	!> INFO is INTEGER !> =0 if the singular values are all correct (to within !> 1 +- TOL*MAZHEPS) !> >0 if the interval containing the INFO-th singular value !> contains the incorrect number of singular values. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 96 of file dsvdch.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, N
      DOUBLE PRECISION   TOL
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   E( * ), S( * ), SVD( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d0 )
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            BPNT, COUNT, NUML, NUMU, TPNT
      DOUBLE PRECISION   EPS, LOWER, OVFL, TUPPR, UNFL, UNFLEP, UPPER
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           dsvdct
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Get machine constants
*
      info = 0
      IF( n.LE.0 )
     $   RETURN
      unfl = dlamch( 'Safe minimum' )
      ovfl = dlamch( 'Overflow' )
      eps = dlamch( 'Epsilon' )*dlamch( 'Base' )
*
*     UNFLEP is chosen so that when an eigenvalue is multiplied by the
*     scale factor sqrt(OVFL)*sqrt(sqrt(UNFL))/MX in DSVDCT, it exceeds
*     sqrt(UNFL), which is the lower limit for DSVDCT.
*
      unflep = ( sqrt( sqrt( unfl ) ) / sqrt( ovfl ) )*svd( 1 ) +
     $         unfl / eps
*
*     The value of EPS works best when TOL .GE. 10.
*
      eps = tol*max( n / 10, 1 )*eps
*
*     TPNT points to singular value at right endpoint of interval
*     BPNT points to singular value at left  endpoint of interval
*
      tpnt = 1
      bpnt = 1
*
*     Begin loop over all intervals
*
   10 CONTINUE
      upper = ( one+eps )*svd( tpnt ) + unflep
      lower = ( one-eps )*svd( bpnt ) - unflep
      IF( lower.LE.unflep )
     $   lower = -upper
*
*     Begin loop merging overlapping intervals
*
   20 CONTINUE
      IF( bpnt.EQ.n )
     $   GO TO 30
      tuppr = ( one+eps )*svd( bpnt+1 ) + unflep
      IF( tuppr.LT.lower )
     $   GO TO 30
*
*     Merge
*
      bpnt = bpnt + 1
      lower = ( one-eps )*svd( bpnt ) - unflep
      IF( lower.LE.unflep )
     $   lower = -upper
      GO TO 20
   30 CONTINUE
*
*     Count singular values in interval [ LOWER, UPPER ]
*
      CALL dsvdct( n, s, e, lower, numl )
      CALL dsvdct( n, s, e, upper, numu )
      count = numu - numl
      IF( lower.LT.zero )
     $   count = count / 2
      IF( count.NE.bpnt-tpnt+1 ) THEN
*
*        Wrong number of singular values in interval
*
         info = tpnt
         GO TO 40
      END IF
      tpnt = bpnt + 1
      bpnt = tpnt
      IF( tpnt.LE.n )
     $   GO TO 10
   40 CONTINUE
      RETURN
*
*     End of DSVDCH
*

Here is the call graph for this function:

Here is the caller graph for this function: