schkec()

subroutine schkec	(	real	thresh,
		logical	tsterr,
		integer	nin,
		integer	nout )

SCHKEC

Purpose:

!>
!> SCHKEC tests eigen- condition estimation routines
!>        SLALN2, SLASY2, SLANV2, SLAQTR, SLAEXC,
!>        STRSYL, STREXC, STRSNA, STRSEN, STGEXC
!>
!> In all cases, the routine runs through a fixed set of numerical
!> examples, subjects them to various tests, and compares the test
!> results to a threshold THRESH. In addition, STREXC, STRSNA and STRSEN
!> are tested by reading in precomputed examples from a file (on input
!> unit NIN).  Output is written to output unit NOUT.
!> 

Parameters

[in]	THRESH	!> THRESH is REAL !> Threshold for residual tests. A computed test ratio passes !> the threshold if it is less than THRESH. !>
[in]	TSTERR	!> TSTERR is LOGICAL !> Flag that indicates whether error exits are to be tested. !>
[in]	NIN	!> NIN is INTEGER !> The logical unit number for input. !>
[in]	NOUT	!> NOUT is INTEGER !> The logical unit number for output. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 75 of file schkec.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NIN, NOUT
      REAL               THRESH
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            OK
      CHARACTER*3        PATH
      INTEGER            KLAEXC, KLALN2, KLANV2, KLAQTR, KLASY2, KTREXC,
     $                   KTRSEN, KTRSNA, KTRSYL, KTRSYL3, LLAEXC,
     $                   LLALN2, LLANV2, LLAQTR, LLASY2, LTREXC, LTRSYL,
     $                   NLANV2, NLAQTR, NLASY2, NTESTS, NTRSYL, KTGEXC,
     $                   LTGEXC
      REAL               EPS, RLAEXC, RLALN2, RLANV2, RLAQTR, RLASY2,
     $                   RTREXC, SFMIN, RTGEXC
*     ..
*     .. Local Arrays ..
      INTEGER            FTRSYL( 3 ), ITRSYL( 2 ), LTRSEN( 3 ),
     $                   LTRSNA( 3 ), NLAEXC( 2 ), NLALN2( 2 ),
     $                   NTGEXC( 2 ), NTREXC( 3 ), NTRSEN( 3 ),
     $                   NTRSNA( 3 )
      REAL               RTRSEN( 3 ), RTRSNA( 3 ), RTRSYL( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           serrec, sget31, sget32, sget33, sget34, sget35,
     $                   sget36, sget37, sget38, sget39, sget40, ssyl01
*     ..
*     .. External Functions ..
      REAL               SLAMCH
      EXTERNAL           slamch
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Single precision'
      path( 2: 3 ) = 'EC'
      eps = slamch( 'P' )
      sfmin = slamch( 'S' )
*
*     Print header information
*
      WRITE( nout, fmt = 9989 )
      WRITE( nout, fmt = 9988 )eps, sfmin
      WRITE( nout, fmt = 9987 )thresh
*
*     Test error exits if TSTERR is .TRUE.
*
      IF( tsterr )
     $   CALL serrec( path, nout )
*
      ok = .true.
      CALL sget31( rlaln2, llaln2, nlaln2, klaln2 )
      IF( rlaln2.GT.thresh .OR. nlaln2( 1 ).NE.0 ) THEN
         ok = .false.
         WRITE( nout, fmt = 9999 )rlaln2, llaln2, nlaln2, klaln2
      END IF
*
      CALL sget32( rlasy2, llasy2, nlasy2, klasy2 )
      IF( rlasy2.GT.thresh ) THEN
         ok = .false.
         WRITE( nout, fmt = 9998 )rlasy2, llasy2, nlasy2, klasy2
      END IF
*
      CALL sget33( rlanv2, llanv2, nlanv2, klanv2 )
      IF( rlanv2.GT.thresh .OR. nlanv2.NE.0 ) THEN
         ok = .false.
         WRITE( nout, fmt = 9997 )rlanv2, llanv2, nlanv2, klanv2
      END IF
*
      CALL sget34( rlaexc, llaexc, nlaexc, klaexc )
      IF( rlaexc.GT.thresh .OR. nlaexc( 2 ).NE.0 ) THEN
         ok = .false.
         WRITE( nout, fmt = 9996 )rlaexc, llaexc, nlaexc, klaexc
      END IF
*
      CALL sget35( rtrsyl( 1 ), ltrsyl, ntrsyl, ktrsyl )
      IF( rtrsyl( 1 ).GT.thresh ) THEN
         ok = .false.
         WRITE( nout, fmt = 9995 )rtrsyl( 1 ), ltrsyl, ntrsyl, ktrsyl
      END IF
*
      CALL ssyl01( thresh, ftrsyl, rtrsyl, itrsyl, ktrsyl3 )
      IF( ftrsyl( 1 ).GT.0 ) THEN
         ok = .false.
         WRITE( nout, fmt = 9970 )ftrsyl( 1 ), rtrsyl( 1 ), thresh
      END IF
      IF( ftrsyl( 2 ).GT.0 ) THEN
         ok = .false.
         WRITE( nout, fmt = 9971 )ftrsyl( 2 ), rtrsyl( 2 ), thresh
      END IF
      IF( ftrsyl( 3 ).GT.0 ) THEN
         ok = .false.
         WRITE( nout, fmt = 9972 )ftrsyl( 3 )
      END IF
*
      CALL sget36( rtrexc, ltrexc, ntrexc, ktrexc, nin )
      IF( rtrexc.GT.thresh .OR. ntrexc( 3 ).GT.0 ) THEN
         ok = .false.
         WRITE( nout, fmt = 9994 )rtrexc, ltrexc, ntrexc, ktrexc
      END IF
*
      CALL sget37( rtrsna, ltrsna, ntrsna, ktrsna, nin )
      IF( rtrsna( 1 ).GT.thresh .OR. rtrsna( 2 ).GT.thresh .OR.
     $    ntrsna( 1 ).NE.0 .OR. ntrsna( 2 ).NE.0 .OR. ntrsna( 3 ).NE.0 )
     $     THEN
         ok = .false.
         WRITE( nout, fmt = 9993 )rtrsna, ltrsna, ntrsna, ktrsna
      END IF
*
      CALL sget38( rtrsen, ltrsen, ntrsen, ktrsen, nin )
      IF( rtrsen( 1 ).GT.thresh .OR. rtrsen( 2 ).GT.thresh .OR.
     $    ntrsen( 1 ).NE.0 .OR. ntrsen( 2 ).NE.0 .OR. ntrsen( 3 ).NE.0 )
     $     THEN
         ok = .false.
         WRITE( nout, fmt = 9992 )rtrsen, ltrsen, ntrsen, ktrsen
      END IF
*
      CALL sget39( rlaqtr, llaqtr, nlaqtr, klaqtr )
      IF( rlaqtr.GT.thresh ) THEN
         ok = .false.
         WRITE( nout, fmt = 9991 )rlaqtr, llaqtr, nlaqtr, klaqtr
      END IF
*
      CALL sget40( rtgexc, ltgexc, ntgexc, ktgexc, nin )
      IF( rtgexc.GT.thresh ) THEN
         ok = .false.
         WRITE( nout, fmt = 9986 )rtgexc, ltgexc, ntgexc, ktgexc
      END IF
*
      ntests = klaln2 + klasy2 + klanv2 + klaexc + ktrsyl + ktrexc +
     $         ktrsna + ktrsen + klaqtr
      IF( ok )
     $   WRITE( nout, fmt = 9990 )path, ntests
*
      RETURN
 9999 FORMAT( ' Error in SLALN2: RMAX =', e12.3, / ' LMAX = ', i8, ' N',
     $      'INFO=', 2i8, ' KNT=', i8 )
 9998 FORMAT( ' Error in SLASY2: RMAX =', e12.3, / ' LMAX = ', i8, ' N',
     $      'INFO=', i8, ' KNT=', i8 )
 9997 FORMAT( ' Error in SLANV2: RMAX =', e12.3, / ' LMAX = ', i8, ' N',
     $      'INFO=', i8, ' KNT=', i8 )
 9996 FORMAT( ' Error in SLAEXC: RMAX =', e12.3, / ' LMAX = ', i8, ' N',
     $      'INFO=', 2i8, ' KNT=', i8 )
 9995 FORMAT( ' Error in STRSYL: RMAX =', e12.3, / ' LMAX = ', i8, ' N',
     $      'INFO=', i8, ' KNT=', i8 )
 9994 FORMAT( ' Error in STREXC: RMAX =', e12.3, / ' LMAX = ', i8, ' N',
     $      'INFO=', 3i8, ' KNT=', i8 )
 9993 FORMAT( ' Error in STRSNA: RMAX =', 3e12.3, / ' LMAX = ', 3i8,
     $      ' NINFO=', 3i8, ' KNT=', i8 )
 9992 FORMAT( ' Error in STRSEN: RMAX =', 3e12.3, / ' LMAX = ', 3i8,
     $      ' NINFO=', 3i8, ' KNT=', i8 )
 9991 FORMAT( ' Error in SLAQTR: RMAX =', e12.3, / ' LMAX = ', i8, ' N',
     $      'INFO=', i8, ' KNT=', i8 )
 9990 FORMAT( / 1x, 'All tests for ', a3, ' routines passed the thresh',
     $      'old ( ', i6, ' tests run)' )
 9989 FORMAT( ' Tests of the Nonsymmetric eigenproblem condition estim',
     $      'ation routines', / ' SLALN2, SLASY2, SLANV2, SLAEXC, STRS',
     $      'YL, STREXC, STRSNA, STRSEN, SLAQTR', / )
 9988 FORMAT( ' Relative machine precision (EPS) = ', e16.6, / ' Safe ',
     $      'minimum (SFMIN)             = ', e16.6, / )
 9987 FORMAT( ' Routines pass computational tests if test ratio is les',
     $      's than', f8.2, / / )
 9986 FORMAT( ' Error in STGEXC: RMAX =', e12.3, / ' LMAX = ', i8, ' N',
     $      'INFO=', 2i8, ' KNT=', i8 )
 9972 FORMAT( 'STRSYL and STRSYL3 compute an inconsistent result ',
     $      'factor in ', i8, ' tests.')
 9971 FORMAT( 'Error in STRSYL3: ', i8, ' tests fail the threshold.', /
     $      'Maximum test ratio =', d12.3, ' threshold =', d12.3 )
 9970 FORMAT( 'Error in STRSYL: ', i8, ' tests fail the threshold.', /
     $      'Maximum test ratio =', d12.3, ' threshold =', d12.3 )
*
*     End of SCHKEC
*

Here is the call graph for this function:

Here is the caller graph for this function: