zget08()

subroutine zget08	(	character	trans,
		integer	m,
		integer	n,
		integer	nrhs,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldx, * )	x,
		integer	ldx,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		double precision, dimension( * )	rwork,
		double precision	resid )

ZGET08

Purpose:

!>
!> ZGET08 computes the residual for a solution of a system of linear
!> equations  A*x = b  or  A'*x = b:
!>    RESID = norm(B - A*X) / ( norm(A) * norm(X) * EPS ),
!> where EPS is the machine epsilon.
!> 

Parameters

[in]	TRANS	!> TRANS is CHARACTER*1 !> Specifies the form of the system of equations: !> = 'N': A *x = b !> = 'T': A^T*x = b, where A^T is the transpose of A !> = 'C': A^H*x = b, where A^H is the conjugate transpose of A !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns of B, the matrix of right hand sides. !> NRHS >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> The original M x N matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[in]	X	!> X is COMPLEX*16 array, dimension (LDX,NRHS) !> The computed solution vectors for the system of linear !> equations. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. If TRANS = 'N', !> LDX >= max(1,N); if TRANS = 'T' or 'C', LDX >= max(1,M). !>
[in,out]	B	!> B is COMPLEX*16 array, dimension (LDB,NRHS) !> On entry, the right hand side vectors for the system of !> linear equations. !> On exit, B is overwritten with the difference B - A*X. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. IF TRANS = 'N', !> LDB >= max(1,M); if TRANS = 'T' or 'C', LDB >= max(1,N). !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (M) !>
[out]	RESID	!> RESID is DOUBLE PRECISION !> The maximum over the number of right hand sides of !> norm(B - A*X) / ( norm(A) * norm(X) * EPS ). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 131 of file zget08.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            LDA, LDB, LDX, M, N, NRHS
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( LDA, * ), B( LDB, * ), X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CONE
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            J, N1, N2
      DOUBLE PRECISION   ANORM, BNORM, EPS, XNORM
      COMPLEX*16         ZDUM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            IZAMAX
      DOUBLE PRECISION   DLAMCH, ZLANGE
      EXTERNAL           lsame, izamax, dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Quick exit if M = 0 or N = 0 or NRHS = 0
*
      IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.EQ.0 ) THEN
         resid = zero
         RETURN
      END IF
*
      IF( lsame( trans, 'T' ) .OR. lsame( trans, 'C' ) ) THEN
         n1 = n
         n2 = m
      ELSE
         n1 = m
         n2 = n
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = zlange( 'I', n1, n2, a, lda, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Compute  B - A*X  (or  B - A'*X ) and store in B.
*
      CALL zgemm( trans, 'No transpose', n1, nrhs, n2, -cone, a, lda, x,
     $            ldx, cone, b, ldb )
*
*     Compute the maximum over the number of right hand sides of
*        norm(B - A*X) / ( norm(A) * norm(X) * EPS ) .
*
      resid = zero
      DO 10 j = 1, nrhs
         bnorm = cabs1( b( izamax( n1, b( 1, j ), 1 ), j ) )
         xnorm = cabs1( x( izamax( n2, x( 1, j ), 1 ), j ) )
         IF( xnorm.LE.zero ) THEN
            resid = one / eps
         ELSE
            resid = max( resid, ( ( bnorm / anorm ) / xnorm ) / eps )
         END IF
   10 CONTINUE
*
      RETURN
*
*     End of ZGET08
*

Here is the call graph for this function:

Here is the caller graph for this function: